qcsrc/menu/xonotic/colorbutton.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticColorButton) EXTENDS(RadioButton)
   3         METHOD(XonoticColorButton, configureXonoticColorButton, void(entity, float, float, float))
   4         METHOD(XonoticColorButton, setChecked, void(entity, float))
   5         METHOD(XonoticColorButton, draw, void(entity))
   6         ATTRIB(XonoticColorButton, fontSize, float, 0)
   7         ATTRIB(XonoticColorButton, image, string, SKINGFX_COLORBUTTON)
   8
   9         ATTRIB(XonoticColorButton, useDownAsChecked, float, 1)
  10
  11         ATTRIB(XonoticColorButton, cvarPart, float, 0)
  12         ATTRIB(XonoticColorButton, cvarName, string, string_null)
  13         ATTRIB(XonoticColorButton, cvarValueFloat, float, 0)
  14         METHOD(XonoticColorButton, loadCvars, void(entity))
  15         METHOD(XonoticColorButton, saveCvars, void(entity))
  16 ENDCLASS(XonoticColorButton)
  17 entity makeXonoticColorButton(float, float, float);
  18 #endif
  19
  20 #ifdef IMPLEMENTATION
  21 entity makeXonoticColorButton(float theGroup, float theColor, float theValue)
  22 {
  23         entity me;
  24         me = spawnXonoticColorButton();
  25         me.configureXonoticColorButton(me, theGroup, theColor, theValue);
  26         return me;
  27 }
  28 void XonoticColorButton_configureXonoticColorButton(entity me, float theGroup, float theColor, float theValue)
  29 {
  30         switch(theValue)
  31         {
  32                 // rearrange 1..14 for rainbow order
  33                 case  1: theValue = 10; break;
  34                 case  2: theValue =  4; break;
  35                 case  3: theValue =  1; break;
  36                 case  4: theValue = 14; break;
  37                 case  5: theValue = 12; break;
  38                 case  6: theValue =  7; break;
  39                 case  7: theValue =  3; break;
  40                 case  8: theValue =  2; break;
  41                 case  9: theValue =  6; break;
  42                 case 10: theValue =  5; break;
  43                 case 11: theValue = 13; break;
  44                 case 12: theValue = 11; break;
  45                 case 13: theValue =  8; break;
  46                 case 14: theValue =  9; break;
  47                 default:
  48                         // no change
  49                         break;
  50         }
  51         me.cvarName = "_cl_color";
  52         me.cvarValueFloat = theValue;
  53         me.cvarPart = theColor;
  54         me.loadCvars(me);
  55         me.configureRadioButton(me, string_null, me.fontSize, me.image, theGroup, 0);
  56 }
  57 void XonoticColorButton_setChecked(entity me, float val)
  58 {
  59         if(val != me.checked)
  60         {
  61                 me.checked = val;
  62                 me.saveCvars(me);
  63         }
  64 }
  65 void XonoticColorButton_loadCvars(entity me)
  66 {
  67         if (!me.cvarName)
  68                 return;
  69
  70         if(cvar_string(me.cvarName) == cvar_defstring(me.cvarName))
  71                 cvar_set(me.cvarName, ftos(16 * floor(random() * 15) + floor(random() * 15)));
  72
  73         if(me.cvarPart == 1)
  74                 me.checked = (cvar(me.cvarName) & 240) == me.cvarValueFloat * 16;
  75         else
  76                 me.checked = (cvar(me.cvarName) & 15) == me.cvarValueFloat;
  77 }
  78 void XonoticColorButton_saveCvars(entity me)
  79 {
  80         if (!me.cvarName)
  81                 return;
  82
  83         if(me.checked)
  84         {
  85                 if(me.cvarPart == 1)
  86                         cvar_set(me.cvarName, ftos((cvar(me.cvarName) & 15) + me.cvarValueFloat * 16));
  87                 else
  88                         cvar_set(me.cvarName, ftos((cvar(me.cvarName) & 240) + me.cvarValueFloat));
  89         }
  90         // TODO on an apply button, read _cl_color and execute the color command for it
  91 }
  92 void XonoticColorButton_draw(entity me)
  93 {
  94         me.color  = colormapPaletteColor(me.cvarValueFloat, me.cvarPart);
  95         me.colorC = me.color;
  96         me.colorF = me.color;
  97         me.colorD = me.color;
  98         SUPER(XonoticColorButton).draw(me);
  99 }
 100 #endif