Merge branch 'master' into terencehill/accelerometer_fix
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / credits.qc
1 #ifndef CREDITS_H
2 #define CREDITS_H
3 #include "listbox.qc"
4 CLASS(XonoticCreditsList, XonoticListBox)
5         METHOD(XonoticCreditsList, configureXonoticCreditsList, void(entity))
6         ATTRIB(XonoticCreditsList, rowsPerItem, float, 1)
7         METHOD(XonoticCreditsList, draw, void(entity))
8         METHOD(XonoticCreditsList, drawListBoxItem, void(entity, int, vector, bool, bool))
9         METHOD(XonoticCreditsList, resizeNotify, void(entity, vector, vector, vector, vector))
10         METHOD(XonoticCreditsList, keyDown, float(entity, float, float, float))
11         METHOD(XonoticCreditsList, destroy, void(entity))
12
13         ATTRIB(XonoticCreditsList, realFontSize, vector, '0 0 0')
14         ATTRIB(XonoticCreditsList, realUpperMargin, float, 0)
15         ATTRIB(XonoticCreditsList, bufferIndex, float, 0)
16         ATTRIB(XonoticCreditsList, scrolling, float, 0)
17
18         ATTRIB(XonoticCreditsList, alphaBG, float, 0)
19 ENDCLASS(XonoticCreditsList)
20 entity makeXonoticCreditsList();
21 #endif
22
23 #ifdef IMPLEMENTATION
24 entity makeXonoticCreditsList()
25 {
26         entity me;
27         me = NEW(XonoticCreditsList);
28         me.configureXonoticCreditsList(me);
29         return me;
30 }
31 void XonoticCreditsList_configureXonoticCreditsList(entity me)
32 {
33         me.configureXonoticListBox(me);
34         // load the file
35         me.bufferIndex = buf_load(language_filename("xonotic-credits.txt"));
36         me.nItems = buf_getsize(me.bufferIndex);
37 }
38 void XonoticCreditsList_destroy(entity me)
39 {
40         buf_del(me.bufferIndex);
41 }
42 void XonoticCreditsList_draw(entity me)
43 {
44         float i;
45         if(me.scrolling)
46         {
47                 me.scrollPos = bound(0, (time - me.scrolling) * me.itemHeight, me.nItems * me.itemHeight - 1);
48                 i = min(me.selectedItem, floor((me.scrollPos + 1) / me.itemHeight - 1));
49                 i = max(i, ceil(me.scrollPos / me.itemHeight));
50                 me.setSelected(me, i);
51         }
52         SUPER(XonoticCreditsList).draw(me);
53 }
54 void XonoticCreditsList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
55 {
56         SUPER(XonoticCreditsList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
57
58         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
59         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
60         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
61 }
62 void XonoticCreditsList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
63 {
64         // layout: Ping, Credits name, Map name, NP, TP, MP
65         string s;
66         float theAlpha;
67         vector theColor;
68
69         s = bufstr_get(me.bufferIndex, i);
70
71         if(substring(s, 0, 2) == "**")
72         {
73                 s = substring(s, 2, strlen(s) - 2);
74                 theColor = SKINCOLOR_CREDITS_TITLE;
75                 theAlpha = SKINALPHA_CREDITS_TITLE;
76         }
77         else if(substring(s, 0, 1) == "*")
78         {
79                 s = substring(s, 1, strlen(s) - 1);
80                 theColor = SKINCOLOR_CREDITS_FUNCTION;
81                 theAlpha = SKINALPHA_CREDITS_FUNCTION;
82         }
83         else
84         {
85                 theColor = SKINCOLOR_CREDITS_PERSON;
86                 theAlpha = SKINALPHA_CREDITS_PERSON;
87         }
88
89         draw_CenterText(me.realUpperMargin * eY + 0.5 * eX, s, me.realFontSize, theColor, theAlpha, 0);
90 }
91
92 float XonoticCreditsList_keyDown(entity me, float key, float ascii, float shift)
93 {
94         float i;
95         me.dragScrollTimer = time;
96         me.scrolling = 0;
97         if(key == K_PGUP || key == K_KP_PGUP)
98                 me.scrollPos = max(me.scrollPos - 0.5, 0);
99         else if(key == K_PGDN || key == K_KP_PGDN)
100                 me.scrollPos = min(me.scrollPos + 0.5, me.nItems * me.itemHeight - 1);
101         else if(key == K_UPARROW || key == K_KP_UPARROW)
102                 me.scrollPos = max(me.scrollPos - me.itemHeight, 0);
103         else if(key == K_DOWNARROW || key == K_KP_DOWNARROW)
104                 me.scrollPos = min(me.scrollPos + me.itemHeight, me.nItems * me.itemHeight - 1);
105         else
106                 return SUPER(XonoticCreditsList).keyDown(me, key, ascii, shift);
107
108         i = min(me.selectedItem, floor((me.scrollPos + 1) / me.itemHeight - 1));
109         i = max(i, ceil(me.scrollPos / me.itemHeight));
110         me.setSelected(me, i);
111
112         return 1;
113 }
114 #endif