qcsrc/menu/xonotic/cvarlist.qc

   1 #include "cvarlist.qh"
   2
   3 #include "inputbox.qh"
   4 #include "../item/container.qh"
   5 #include "../item/checkbox.qh"
   6
   7 entity makeXonoticCvarList()
   8 {
   9         entity me;
  10         me = NEW(XonoticCvarList);
  11         me.configureXonoticCvarList(me);
  12         return me;
  13 }
  14 void XonoticCvarList_configureXonoticCvarList(entity me)
  15 {
  16         me.configureXonoticListBox(me);
  17         me.handle = buf_create();
  18         me.nItems = 0;
  19 }
  20 void CvarList_Load(entity me, string filter)
  21 {
  22         if(me.handle < 0)
  23                 return;
  24
  25         buf_cvarlist(me.handle, filter, "_");
  26         me.nItems = buf_getsize(me.handle);
  27         if(autocvar_menu_cvarlist_onlymodified)
  28         {
  29                 float newbuf = buf_create();
  30                 for (int i = 0; i < me.nItems; ++i)
  31                 {
  32                         string k = bufstr_get(me.handle, i);
  33                         if(cvar_string(k) != cvar_defstring(k))
  34                                 bufstr_add(newbuf, k, false);
  35                 }
  36                 buf_del(me.handle);
  37                 me.handle = newbuf;
  38                 me.nItems = buf_getsize(me.handle);
  39         }
  40 }
  41 void XonoticCvarList_showNotify(entity me)
  42 {
  43         bool force_initial_selection = false;
  44         if(me.handle >= 0 && me.nItems <= 0) // me.handle not loaded yet?
  45                 force_initial_selection = true;
  46         CvarList_Load(me, me.controlledTextbox.text);
  47         if(force_initial_selection)
  48                 me.setSelected(me, 0);
  49 }
  50 void XonoticCvarList_hideNotify(entity me)
  51 {
  52         if(me.handle)
  53                 buf_del(me.handle);
  54         me.handle = buf_create();
  55         me.nItems = 0;
  56 }
  57 void XonoticCvarList_destroy(entity me)
  58 {
  59         if(me.handle)
  60                 buf_del(me.handle);
  61 }
  62 string autocvar_menu_forced_saved_cvars;
  63 string autocvar_menu_reverted_nonsaved_cvars;
  64 float XonoticCvarList_updateCvarType(entity me)
  65 {
  66         float t;
  67         t = cvar_type(me.cvarName);
  68         me.cvarType = "";
  69         float needsForcing;
  70         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
  71         {
  72                 me.cvarType = strcat(me.cvarType, ", ", _("forced to be saved to config.cfg"));
  73                 needsForcing = 0;
  74         }
  75         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, me.cvarName))
  76         {
  77                 // Currently claims to be saved, but won't be on next startup.
  78                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  79                 needsForcing = 1;
  80         }
  81         else if(t & CVAR_TYPEFLAG_SAVED)
  82         {
  83                 me.cvarType = strcat(me.cvarType, ", ", _("will be saved to config.cfg"));
  84                 needsForcing = 0;
  85         }
  86         else
  87         {
  88                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  89                 needsForcing = 1;
  90         }
  91         if(t & CVAR_TYPEFLAG_PRIVATE)
  92                 me.cvarType = strcat(me.cvarType, ", ", _("private"));
  93         if(t & CVAR_TYPEFLAG_ENGINE)
  94                 me.cvarType = strcat(me.cvarType, ", ", _("engine setting"));
  95         if(t & CVAR_TYPEFLAG_READONLY)
  96                 me.cvarType = strcat(me.cvarType, ", ", _("read only"));
  97         me.cvarType = strzone(substring(me.cvarType, 2, strlen(me.cvarType) - 2));
  98         me.cvarTypeBox.setText(me.cvarTypeBox, me.cvarType);
  99         return needsForcing;
 100 }
 101 void XonoticCvarList_setSelected(entity me, float i)
 102 {
 103         string s;
 104
 105         SUPER(XonoticCvarList).setSelected(me, i);
 106         if(me.nItems == 0)
 107                 return;
 108
 109         if(me.cvarName)
 110                 strunzone(me.cvarName);
 111         if(me.cvarDescription)
 112                 strunzone(me.cvarDescription);
 113         if(me.cvarType)
 114                 strunzone(me.cvarType);
 115         if(me.cvarDefault)
 116                 strunzone(me.cvarDefault);
 117         me.cvarName = strzone(bufstr_get(me.handle, me.selectedItem));
 118         me.cvarDescription = strzone(cvar_description(me.cvarName));
 119         me.cvarDefault = strzone(cvar_defstring(me.cvarName));
 120         me.cvarNameBox.setText(me.cvarNameBox, me.cvarName);
 121         me.cvarDescriptionBox.setText(me.cvarDescriptionBox, me.cvarDescription);
 122         float needsForcing = me.updateCvarType(me);
 123         me.cvarDefaultBox.setText(me.cvarDefaultBox, me.cvarDefault);
 124
 125         // this one can handle tempstrings
 126         s = cvar_string(me.cvarName);
 127         me.cvarNeedsForcing = 0;
 128         me.cvarValueBox.setText(me.cvarValueBox, s);
 129         me.cvarNeedsForcing = needsForcing;
 130         me.cvarValueBox.cursorPos = strlen(s);
 131 }
 132 void CvarList_Filter_Change(entity box, entity me)
 133 {
 134         CvarList_Load(me, box.text);
 135         me.setSelected(me, 0);
 136 }
 137 void CvarList_Filter_ModifiedCvars(entity box, entity me)
 138 {
 139         cvar_set("menu_cvarlist_onlymodified", ftos(!autocvar_menu_cvarlist_onlymodified));
 140         box.setChecked(box, autocvar_menu_cvarlist_onlymodified);
 141         CvarList_Load(me, me.controlledTextbox.text);
 142         me.setSelected(me, 0);
 143 }
 144 void XonoticCvarList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 145 {
 146         SUPER(XonoticCvarList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 147
 148         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 149         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 150         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 151
 152         me.columnNameOrigin = 0;
 153         me.columnValueSize = me.realFontSize.x * 20;
 154         me.columnNameSize = 1 - me.columnValueSize - me.realFontSize.x;
 155         me.columnValueOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 156 }
 157 void XonoticCvarList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 158 {
 159         string k, v, d;
 160         float t;
 161
 162         vector theColor;
 163         float theAlpha;
 164
 165         string s;
 166
 167         if(isSelected)
 168                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 169         else if(isFocused)
 170         {
 171                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 172                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 173         }
 174
 175         k = bufstr_get(me.handle, i);
 176
 177         v = cvar_string(k);
 178         d = cvar_defstring(k);
 179         t = cvar_type(k);
 180         if(strhasword(autocvar_menu_forced_saved_cvars, k))
 181                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 182         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, k))
 183                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 184         else if(t & CVAR_TYPEFLAG_SAVED)
 185                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 186         else
 187                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 188         if(v == d)
 189                 theColor = SKINCOLOR_CVARLIST_UNCHANGED;
 190         else
 191                 theColor = SKINCOLOR_CVARLIST_CHANGED;
 192
 193         s = draw_TextShortenToWidth(k, me.columnNameSize, 0, me.realFontSize);
 194         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 195         s = draw_TextShortenToWidth(v, me.columnValueSize, 0, me.realFontSize);
 196         draw_Text(me.realUpperMargin * eY + me.columnValueOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 197 }
 198
 199 float XonoticCvarList_keyDown(entity me, float scan, float ascii, float shift)
 200 {
 201         if (scan == K_MOUSE3 || ((shift & S_CTRL) && scan == K_SPACE))
 202         {
 203                 CvarList_Revert_Click(NULL, me);
 204                 return 1;
 205         }
 206         else if(scan == K_ENTER)
 207         {
 208                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 209                 return 1;
 210         }
 211         else if(SUPER(XonoticCvarList).keyDown(me, scan, ascii, shift))
 212                 return 1;
 213         else if(!me.controlledTextbox)
 214                 return 0;
 215         else
 216                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
 217 }
 218
 219 float XonoticCvarList_mouseRelease(entity me, vector pos)
 220 {
 221         if(me.pressed == 2)
 222                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 223         return SUPER(XonoticCvarList).mouseRelease(me, pos);
 224 }
 225
 226 void CvarList_Value_Change(entity box, entity me)
 227 {
 228         cvar_set(me.cvarNameBox.text, box.text);
 229         if(me.cvarNeedsForcing)
 230         {
 231                 localcmd(sprintf("\nseta %1$s \"$%1$s\"\n", me.cvarName));
 232                 cvar_set("menu_reverted_nonsaved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_reverted_nonsaved_cvars, " ")), 1, -2));
 233                 if (autocvar_menu_forced_saved_cvars == "")
 234                         cvar_set("menu_forced_saved_cvars", me.cvarName);
 235                 else
 236                         cvar_set("menu_forced_saved_cvars", strcat(autocvar_menu_forced_saved_cvars, " ", me.cvarName));
 237                 me.cvarNeedsForcing = 0;
 238                 me.updateCvarType(me);
 239         }
 240 }
 241
 242 void CvarList_Revert_Click(entity btn, entity me)
 243 {
 244         me.cvarValueBox.setText(me.cvarValueBox, me.cvarDefault);
 245         me.cvarValueBox.cursorPos = strlen(me.cvarDefault);
 246         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
 247         {
 248                 cvar_set("menu_forced_saved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_forced_saved_cvars, " ")), 1, -2));
 249                 if (autocvar_menu_reverted_nonsaved_cvars == "")
 250                         cvar_set("menu_reverted_nonsaved_cvars", me.cvarName);
 251                 else
 252                         cvar_set("menu_reverted_nonsaved_cvars", strcat(autocvar_menu_reverted_nonsaved_cvars, " ", me.cvarName));
 253         }
 254         me.cvarNeedsForcing = me.updateCvarType(me);
 255 }
 256
 257 void CvarList_End_Editing(entity box, entity me)
 258 {
 259         box.parent.setFocus(box.parent, me);
 260 }