qcsrc/menu/xonotic/cvarlist.qc

   1 #include "cvarlist.qh"
   2
   3 #include "inputbox.qh"
   4 #include "../item/container.qh"
   5
   6 entity makeXonoticCvarList()
   7 {
   8         entity me;
   9         me = NEW(XonoticCvarList);
  10         me.configureXonoticCvarList(me);
  11         return me;
  12 }
  13 void XonoticCvarList_configureXonoticCvarList(entity me)
  14 {
  15         me.configureXonoticListBox(me);
  16         me.handle = buf_create();
  17         me.nItems = 0;
  18 }
  19 void CvarList_Load(entity me, string filter)
  20 {
  21         if(me.handle < 0)
  22                 return;
  23
  24         buf_cvarlist(me.handle, filter, "_");
  25         me.nItems = buf_getsize(me.handle);
  26         if(autocvar_menu_cvarlist_onlymodified)
  27         {
  28                 float newbuf = buf_create();
  29                 for (int i = 0; i < me.nItems; ++i)
  30                 {
  31                         string k = bufstr_get(me.handle, i);
  32                         if(cvar_string(k) != cvar_defstring(k))
  33                                 bufstr_add(newbuf, k, false);
  34                 }
  35                 buf_del(me.handle);
  36                 me.handle = newbuf;
  37                 me.nItems = buf_getsize(me.handle);
  38         }
  39 }
  40 void XonoticCvarList_showNotify(entity me)
  41 {
  42         bool force_initial_selection = false;
  43         if(me.handle >= 0 && me.nItems <= 0) // me.handle not loaded yet?
  44                 force_initial_selection = true;
  45         CvarList_Load(me, me.controlledTextbox.text);
  46         if(force_initial_selection)
  47                 me.setSelected(me, 0);
  48 }
  49 void XonoticCvarList_hideNotify(entity me)
  50 {
  51         if(me.handle)
  52                 buf_del(me.handle);
  53         me.handle = buf_create();
  54         me.nItems = 0;
  55 }
  56 void XonoticCvarList_destroy(entity me)
  57 {
  58         if(me.handle)
  59                 buf_del(me.handle);
  60 }
  61 string autocvar_menu_forced_saved_cvars;
  62 string autocvar_menu_reverted_nonsaved_cvars;
  63 float XonoticCvarList_updateCvarType(entity me)
  64 {
  65         float t;
  66         t = cvar_type(me.cvarName);
  67         me.cvarType = "";
  68         float needsForcing;
  69         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
  70         {
  71                 me.cvarType = strcat(me.cvarType, ", ", _("forced to be saved to config.cfg"));
  72                 needsForcing = 0;
  73         }
  74         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, me.cvarName))
  75         {
  76                 // Currently claims to be saved, but won't be on next startup.
  77                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  78                 needsForcing = 1;
  79         }
  80         else if(t & CVAR_TYPEFLAG_SAVED)
  81         {
  82                 me.cvarType = strcat(me.cvarType, ", ", _("will be saved to config.cfg"));
  83                 needsForcing = 0;
  84         }
  85         else
  86         {
  87                 me.cvarType = strcat(me.cvarType, ", ", _("will not be saved"));
  88                 needsForcing = 1;
  89         }
  90         if(t & CVAR_TYPEFLAG_PRIVATE)
  91                 me.cvarType = strcat(me.cvarType, ", ", _("private"));
  92         if(t & CVAR_TYPEFLAG_ENGINE)
  93                 me.cvarType = strcat(me.cvarType, ", ", _("engine setting"));
  94         if(t & CVAR_TYPEFLAG_READONLY)
  95                 me.cvarType = strcat(me.cvarType, ", ", _("read only"));
  96         me.cvarType = strzone(substring(me.cvarType, 2, strlen(me.cvarType) - 2));
  97         me.cvarTypeBox.setText(me.cvarTypeBox, me.cvarType);
  98         return needsForcing;
  99 }
 100 void XonoticCvarList_setSelected(entity me, float i)
 101 {
 102         string s;
 103
 104         SUPER(XonoticCvarList).setSelected(me, i);
 105         if(me.nItems == 0)
 106                 return;
 107
 108         if(me.cvarName)
 109                 strunzone(me.cvarName);
 110         if(me.cvarDescription)
 111                 strunzone(me.cvarDescription);
 112         if(me.cvarType)
 113                 strunzone(me.cvarType);
 114         if(me.cvarDefault)
 115                 strunzone(me.cvarDefault);
 116         me.cvarName = strzone(bufstr_get(me.handle, me.selectedItem));
 117         me.cvarDescription = strzone(cvar_description(me.cvarName));
 118         me.cvarDefault = strzone(cvar_defstring(me.cvarName));
 119         me.cvarNameBox.setText(me.cvarNameBox, me.cvarName);
 120         me.cvarDescriptionBox.setText(me.cvarDescriptionBox, me.cvarDescription);
 121         float needsForcing = me.updateCvarType(me);
 122         me.cvarDefaultBox.setText(me.cvarDefaultBox, me.cvarDefault);
 123
 124         // this one can handle tempstrings
 125         s = cvar_string(me.cvarName);
 126         me.cvarNeedsForcing = 0;
 127         me.cvarValueBox.setText(me.cvarValueBox, s);
 128         me.cvarNeedsForcing = needsForcing;
 129         me.cvarValueBox.cursorPos = strlen(s);
 130 }
 131 void CvarList_Filter_Change(entity box, entity me)
 132 {
 133         CvarList_Load(me, box.text);
 134         me.setSelected(me, 0);
 135 }
 136 void CvarList_Filter_ModifiedCvars(entity box, entity me)
 137 {
 138         cvar_set("menu_cvarlist_onlymodified", ftos(!autocvar_menu_cvarlist_onlymodified));
 139         box.setChecked(box, autocvar_menu_cvarlist_onlymodified);
 140         CvarList_Load(me, me.controlledTextbox.text);
 141         me.setSelected(me, 0);
 142 }
 143 void XonoticCvarList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 144 {
 145         SUPER(XonoticCvarList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 146
 147         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 148         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 149         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 150
 151         me.columnNameOrigin = 0;
 152         me.columnValueSize = me.realFontSize.x * 20;
 153         me.columnNameSize = 1 - me.columnValueSize - me.realFontSize.x;
 154         me.columnValueOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 155 }
 156 void XonoticCvarList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 157 {
 158         string k, v, d;
 159         float t;
 160
 161         vector theColor;
 162         float theAlpha;
 163
 164         string s;
 165
 166         if(isSelected)
 167                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 168         else if(isFocused)
 169         {
 170                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 171                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 172         }
 173
 174         k = bufstr_get(me.handle, i);
 175
 176         v = cvar_string(k);
 177         d = cvar_defstring(k);
 178         t = cvar_type(k);
 179         if(strhasword(autocvar_menu_forced_saved_cvars, k))
 180                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 181         else if(strhasword(autocvar_menu_reverted_nonsaved_cvars, k))
 182                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 183         else if(t & CVAR_TYPEFLAG_SAVED)
 184                 theAlpha = SKINALPHA_CVARLIST_SAVED;
 185         else
 186                 theAlpha = SKINALPHA_CVARLIST_TEMPORARY;
 187         if(v == d)
 188                 theColor = SKINCOLOR_CVARLIST_UNCHANGED;
 189         else
 190                 theColor = SKINCOLOR_CVARLIST_CHANGED;
 191
 192         s = draw_TextShortenToWidth(k, me.columnNameSize, 0, me.realFontSize);
 193         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 194         s = draw_TextShortenToWidth(v, me.columnValueSize, 0, me.realFontSize);
 195         draw_Text(me.realUpperMargin * eY + me.columnValueOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 196 }
 197
 198 float XonoticCvarList_keyDown(entity me, float scan, float ascii, float shift)
 199 {
 200         if (scan == K_MOUSE3 || ((shift & S_CTRL) && scan == K_SPACE))
 201         {
 202                 CvarList_Revert_Click(NULL, me);
 203                 return 1;
 204         }
 205         else if(scan == K_ENTER)
 206         {
 207                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 208                 return 1;
 209         }
 210         else if(SUPER(XonoticCvarList).keyDown(me, scan, ascii, shift))
 211                 return 1;
 212         else if(!me.controlledTextbox)
 213                 return 0;
 214         else
 215                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
 216 }
 217
 218 float XonoticCvarList_mouseRelease(entity me, vector pos)
 219 {
 220         if(me.pressed == 2)
 221                 me.cvarValueBox.parent.setFocus(me.cvarValueBox.parent, me.cvarValueBox);
 222         return SUPER(XonoticCvarList).mouseRelease(me, pos);
 223 }
 224
 225 void CvarList_Value_Change(entity box, entity me)
 226 {
 227         cvar_set(me.cvarNameBox.text, box.text);
 228         if(me.cvarNeedsForcing)
 229         {
 230                 localcmd(sprintf("\nseta %1$s \"$%1$s\"\n", me.cvarName));
 231                 cvar_set("menu_reverted_nonsaved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_reverted_nonsaved_cvars, " ")), 1, -2));
 232                 if (autocvar_menu_forced_saved_cvars == "")
 233                         cvar_set("menu_forced_saved_cvars", me.cvarName);
 234                 else
 235                         cvar_set("menu_forced_saved_cvars", strcat(autocvar_menu_forced_saved_cvars, " ", me.cvarName));
 236                 me.cvarNeedsForcing = 0;
 237                 me.updateCvarType(me);
 238         }
 239 }
 240
 241 void CvarList_Revert_Click(entity btn, entity me)
 242 {
 243         me.cvarValueBox.setText(me.cvarValueBox, me.cvarDefault);
 244         me.cvarValueBox.cursorPos = strlen(me.cvarDefault);
 245         if(strhasword(autocvar_menu_forced_saved_cvars, me.cvarName))
 246         {
 247                 cvar_set("menu_forced_saved_cvars", substring(strreplace(strcat(" ", me.cvarName, " "), " ", strcat(" ", autocvar_menu_forced_saved_cvars, " ")), 1, -2));
 248                 if (autocvar_menu_reverted_nonsaved_cvars == "")
 249                         cvar_set("menu_reverted_nonsaved_cvars", me.cvarName);
 250                 else
 251                         cvar_set("menu_reverted_nonsaved_cvars", strcat(autocvar_menu_reverted_nonsaved_cvars, " ", me.cvarName));
 252         }
 253         me.cvarNeedsForcing = me.updateCvarType(me);
 254 }
 255
 256 void CvarList_End_Editing(entity box, entity me)
 257 {
 258         box.parent.setFocus(box.parent, me);
 259 }