Merge branch 'nyov/samual/combined_updates' into nyov/combined_updates/effects
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / demolist.c
1 #ifdef INTERFACE
2 CLASS(XonoticDemoList) EXTENDS(XonoticListBox)
3         METHOD(XonoticDemoList, configureXonoticDemoList, void(entity))
4         ATTRIB(XonoticDemoList, rowsPerItem, float, 1)
5         METHOD(XonoticDemoList, resizeNotify, void(entity, vector, vector, vector, vector))
6         METHOD(XonoticDemoList, drawListBoxItem, void(entity, float, vector, float))
7         METHOD(XonoticDemoList, getDemos, void(entity))
8         METHOD(XonoticDemoList, startDemo, void(entity))
9         METHOD(XonoticDemoList, demoName, string(entity, float))
10         METHOD(XonoticDemoList, clickListBoxItem, void(entity, float, vector))
11         METHOD(XonoticDemoList, keyDown, float(entity, float, float, float))
12         METHOD(XonoticDemoList, destroy, void(entity))
13         METHOD(XonoticDemoList, showNotify, void(entity))
14
15         ATTRIB(XonoticDemoList, listDemo, float, -1)
16         ATTRIB(XonoticDemoList, realFontSize, vector, '0 0 0')
17         ATTRIB(XonoticDemoList, columnNameOrigin, float, 0)
18         ATTRIB(XonoticDemoList, columnNameSize, float, 0)
19         ATTRIB(XonoticDemoList, realUpperMargin, float, 0)
20         ATTRIB(XonoticDemoList, origin, vector, '0 0 0')
21         ATTRIB(XonoticDemoList, itemAbsSize, vector, '0 0 0')
22
23         ATTRIB(XonoticDemoList, lastClickedDemo, float, -1)
24         ATTRIB(XonoticDemoList, lastClickedTime, float, 0)
25         ATTRIB(XonoticDemoList, filterString, string, string_null)
26 ENDCLASS(XonoticDemoList)
27
28 entity makeXonoticDemoList();
29 void StartDemo_Click(entity btn, entity me);
30 void TimeDemo_Click(entity btn, entity me);
31 void DemoList_Filter_Change(entity box, entity me);
32 #endif
33
34 #ifdef IMPLEMENTATION
35
36 entity makeXonoticDemoList()
37 {
38         entity me;
39         me = spawnXonoticDemoList();
40         me.configureXonoticDemoList(me);
41         return me;
42 }
43
44 void XonoticDemoList_configureXonoticDemoList(entity me)
45 {
46         me.configureXonoticListBox(me);
47         me.getDemos(me);
48 }
49
50 string XonoticDemoList_demoName(entity me, float i )
51 {
52         string s;
53         s = search_getfilename(me.listDemo, i);
54         s = substring(s, 6, strlen(s) - 6 - 4);  // demos/, .dem
55         return s;
56 }
57
58
59 void XonoticDemoList_getDemos(entity me)
60 {
61         string s;
62
63         if(me.filterString)
64                 //subdirectory in filterString allowed
65                 s=strcat("demos/*", me.filterString, "*.dem");
66         else
67                 s="demos/*.dem";
68
69         //dprint("Search demos with the pattern ", s, "\n");
70         if(me.listDemo >= 0)
71                 search_end(me.listDemo);
72
73         me.listDemo = search_begin(s, FALSE, TRUE);
74
75         if(me.listDemo < 0)
76                 me.nItems=0;
77         else
78                 me.nItems=search_getsize(me.listDemo);
79 }
80
81 void XonoticDemoList_destroy(entity me)
82 {
83         search_end(me.listDemo);
84 }
85
86 void XonoticDemoList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
87 {
88         me.itemAbsSize = '0 0 0';
89         SUPER(XonoticDemoList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
90
91         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
92         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
93         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
94
95         me.columnNameOrigin = me.realFontSize_x;
96         me.columnNameSize = 1 - 2 * me.realFontSize_x;
97 }
98
99 void XonoticDemoList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
100 {
101         string s;
102         if(isSelected)
103                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
104
105         s = me.demoName(me,i);
106         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
107         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
108 }
109
110 void XonoticDemoList_showNotify(entity me)
111 {
112         me.getDemos(me);
113 }
114
115 void DemoList_Filter_Change(entity box, entity me)
116 {
117         if(me.filterString)
118                 strunzone(me.filterString);
119
120         if(box.text != "")
121                 me.filterString = strzone(box.text);
122         else
123                 me.filterString = string_null;
124
125         me.getDemos(me);
126 }
127
128 void XonoticDemoList_startDemo(entity me)
129 {
130         string s;
131         s = me.demoName(me,me.selectedItem);
132         localcmd("playdemo \"demos/", s, ".dem\" \nwait \ntogglemenu\n");
133 }
134
135 void StartDemo_Click(entity btn, entity me)
136 {
137         me.startDemo(me);
138 }
139
140 void TimeDemo_Click(entity btn, entity me)
141 {
142         string s;
143         s = me.demoName(me,me.selectedItem);
144         localcmd("timedemo \"demos/", s, ".dem\" \nwait \ntogglemenu\n");
145 }
146
147 void XonoticDemoList_clickListBoxItem(entity me, float i, vector where)
148 {
149         if(i == me.lastClickedDemo)
150                 if(time < me.lastClickedTime + 0.3)
151                 {
152                         // DOUBLE CLICK!
153                         me.setSelected(me, i);
154                         me.startDemo(me);
155                 }
156         me.lastClickedDemo = i;
157         me.lastClickedTime = time;
158 }
159
160 float XonoticDemoList_keyDown(entity me, float scan, float ascii, float shift)
161 {
162         if(scan == K_ENTER || scan == K_KP_ENTER) {
163                 me.startDemo(me);
164                 return 1;
165         }
166         else
167                 return SUPER(XonoticDemoList).keyDown(me, scan, ascii, shift);
168 }
169 #endif
170