qcsrc/menu/xonotic/dialog_firstrun.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticFirstRunDialog) EXTENDS(XonoticRootDialog)
   3         METHOD(XonoticFirstRunDialog, fill, void(entity)) // to be overridden by user to fill the dialog with controls
   4         ATTRIB(XonoticFirstRunDialog, title, string, _("Welcome"))
   5         ATTRIB(XonoticFirstRunDialog, color, vector, SKINCOLOR_DIALOG_FIRSTRUN)
   6         ATTRIB(XonoticFirstRunDialog, intendedWidth, float, 0.7)
   7         ATTRIB(XonoticFirstRunDialog, rows, float, 16)
   8         ATTRIB(XonoticFirstRunDialog, columns, float, 6)
   9         ATTRIB(XonoticFirstRunDialog, name, string, "FirstRun")
  10         ATTRIB(XonoticFirstRunDialog, playerNameLabel, entity, NULL)
  11         ATTRIB(XonoticFirstRunDialog, playerNameLabelAlpha, float, 0)
  12
  13         ATTRIB(XonoticFirstRunDialog, closable, float, 0)
  14 ENDCLASS(XonoticFirstRunDialog)
  15 #endif
  16
  17 #ifdef IMPLEMENTATION
  18 float CheckFirstRunButton(entity me)
  19 {
  20         if(cvar_string("_cl_name") != "Player")
  21                 return 1;
  22
  23         if(cvar_string("_menu_prvm_language") != prvm_language)
  24                 return 1; // OK will then reopen the dialog in another language
  25
  26         if(cvar_string("cl_allow_uid2name") != "-1")
  27                 return 1;
  28
  29         return 0;
  30 }
  31
  32 void firstRun_setLanguage(entity me)
  33 {
  34         if(prvm_language != cvar_string("_menu_prvm_language"))
  35                 localcmd("\nprvm_language \"$_menu_prvm_language\"; saveconfig; menu_restart\n");
  36 }
  37
  38 void XonoticFirstRunDialog_fill(entity me)
  39 {
  40         entity e;
  41         entity label, box;
  42
  43         me.TR(me);
  44         me.TR(me);
  45                 me.TDempty(me, 1);
  46                 me.TD(me, 2, 4, e = makeXonoticTextLabel(0, _("Welcome to Xonotic, please select your language preference and enter your player name to get started.  You can change these options later through the menu system.")));
  47                 e.allowWrap = 1;
  48         me.TR(me);
  49
  50         me.TR(me);
  51         me.TR(me);
  52                 me.TD(me, 1, 0.5, me.playerNameLabel = makeXonoticTextLabel(0, _("Name:")));
  53                         me.playerNameLabelAlpha = me.playerNameLabel.alpha;
  54                 me.TD(me, 1, 3.25, label = makeXonoticTextLabel(0, string_null));
  55                         label.allowCut = 1;
  56                         label.allowColors = 1;
  57                         label.alpha = 1;
  58         me.TR(me);
  59                 me.TD(me, 1, 3.75, box = makeXonoticInputBox(1, "_cl_name"));
  60                         box.forbiddenCharacters = "\r\n\\\"$"; // don't care, isn't getting saved
  61                         box.maxLength = -127; // negative means encoded length in bytes
  62                         box.saveImmediately = 1;
  63                         label.textEntity = box;
  64         me.TR(me);
  65                 me.TD(me, 5, 1.25, e = makeXonoticColorpicker(box));
  66                 me.TD(me, 5, 2.5, e = makeXonoticCharmap(box));
  67         me.TR(me);
  68         me.TR(me);
  69         me.TR(me);
  70         me.TR(me);
  71
  72         me.gotoRC(me, 3, 4); me.setFirstColumn(me, me.currentColumn);
  73         me.TR(me);
  74                 me.TD(me, 1, 2, e = makeXonoticTextLabel(0, _("Text language:")));
  75         me.TR(me);
  76                 me.TD(me, 6, 2, e = makeXonoticLanguageList());
  77                         e.name = "languageselector_firstrun";
  78                         e.setLanguage = firstRun_setLanguage;
  79         me.TR(me);
  80         me.TR(me);
  81
  82         me.gotoRC(me, me.rows - 4, 0);
  83         me.TD(me, 1, me.columns, e = makeXonoticTextLabel(0.5, _("Allow player statistics to use your nickname at stats.xonotic.org?")));
  84
  85         me.gotoRC(me, me.rows - 3, 0);
  86         me.TDempty(me, 1.5);
  87         me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "cl_allow_uid2name", "1", ZCTX(_("ALWU2N^Yes"))));
  88         me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "cl_allow_uid2name", "0", ZCTX(_("ALWU2N^No"))));
  89         me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "cl_allow_uid2name", "-1", ZCTX(_("ALWU2N^Undecided"))));
  90
  91         // because of the language selector, this is a menu_restart!
  92         me.gotoRC(me, me.rows - 1, 0);
  93         me.TD(me, 1, me.columns, e = makeXonoticCommandButton(_("Save settings"), '0 0 0', "prvm_language \"$_menu_prvm_language\"; saveconfig; menu_restart", COMMANDBUTTON_APPLY));
  94                 setDependentWeird(e, CheckFirstRunButton);
  95 }
  96 #endif