qcsrc/menu/xonotic/dialog_multiplayer_create_mutators.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticMutatorsDialog) EXTENDS(XonoticDialog)
   3         METHOD(XonoticMutatorsDialog, toString, string(entity))
   4         METHOD(XonoticMutatorsDialog, fill, void(entity))
   5         METHOD(XonoticMutatorsDialog, showNotify, void(entity))
   6         METHOD(XonoticMutatorsDialog, close, void(entity))
   7         ATTRIB(XonoticMutatorsDialog, title, string, _("Mutators"))
   8         ATTRIB(XonoticMutatorsDialog, color, vector, SKINCOLOR_DIALOG_MUTATORS)
   9         ATTRIB(XonoticMutatorsDialog, intendedWidth, float, 0.9)
  10         ATTRIB(XonoticMutatorsDialog, rows, float, 19)
  11         ATTRIB(XonoticMutatorsDialog, columns, float, 6)
  12         ATTRIB(XonoticMutatorsDialog, refilterEntity, entity, NULL)
  13 ENDCLASS(XonoticMutatorsDialog)
  14 #endif
  15
  16 #ifdef IMPLEMENTATION
  17 void XonoticMutatorsDialog_showNotify(entity me)
  18 {
  19         loadAllCvars(me);
  20 }
  21
  22 string weaponarenastring;
  23 string weaponarenastring_cvar;
  24 string WeaponArenaString()
  25 {
  26         string s;
  27         float n, i, j;
  28         entity e;
  29         s = cvar_string("g_weaponarena");
  30         if(s == "0")
  31                 return "";
  32         if(s == "all")
  33                 return _("All Weapons Arena");
  34         if(s == "most")
  35                 return _("Most Weapons Arena");
  36         if(s == weaponarenastring_cvar)
  37                 return weaponarenastring;
  38         if(weaponarenastring)
  39                 strunzone(weaponarenastring);
  40         if(weaponarenastring_cvar)
  41                 strunzone(weaponarenastring_cvar);
  42
  43         weaponarenastring_cvar = strzone(s);
  44
  45         n = tokenize_console(s);
  46         s = "";
  47         for(i = 0; i < n; ++i)
  48         {
  49                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  50                 {
  51                         e = get_weaponinfo(j);
  52                         if(argv(i) == e.netname)
  53                                 s = strcat(s, " & ", e.message);
  54                 }
  55         }
  56         s = sprintf(_("%s Arena"), substring(s, 3, strlen(s) - 3));
  57
  58         weaponarenastring = strzone(s);
  59
  60         return weaponarenastring;
  61 }
  62
  63 string XonoticMutatorsDialog_toString(entity me)
  64 {
  65         string s;
  66         s = "";
  67         if(cvar("g_dodging"))
  68                 s = strcat(s, ", ", _("Dodging"));
  69         if(cvar("g_minstagib"))
  70                 s = strcat(s, ", ", _("MinstaGib"));
  71         if(cvar("g_new_toys"))
  72                 s = strcat(s, ", ", _("New Toys"));
  73         if(cvar("g_nix"))
  74                 s = strcat(s, ", ", _("NIX"));
  75         if(cvar("g_rocket_flying"))
  76                 s = strcat(s, ", ", _("Rocket Flying"));
  77         if(cvar("g_invincible_projectiles"))
  78                 s = strcat(s, ", ", _("Invincible Projectiles"));
  79         if(cvar_string("g_weaponarena") != "0")
  80                 s = strcat(s, ", ", WeaponArenaString());
  81         if(cvar("g_start_weapon_laser") == 0)
  82                 s = strcat(s, ", ", _("No start weapons"));
  83         if(cvar("sv_gravity") < 800)
  84                 s = strcat(s, ", ", _("Low gravity"));
  85         if(cvar("g_cloaked"))
  86                 s = strcat(s, ", ", _("Cloaked"));
  87         if(cvar("g_grappling_hook"))
  88                 s = strcat(s, ", ", _("Hook"));
  89         if(cvar("g_midair"))
  90                 s = strcat(s, ", ", _("Midair"));
  91         if(cvar("g_vampire"))
  92                 s = strcat(s, ", ", _("Vampire"));
  93         if(cvar("g_pinata"))
  94                 s = strcat(s, ", ", _("Piñata"));
  95         if(cvar("g_weapon_stay"))
  96                 s = strcat(s, ", ", _("Weapons stay"));
  97         if(cvar("g_bloodloss") > 0)
  98                 s = strcat(s, ", ", _("Blood loss"));
  99         if(cvar("g_jetpack"))
 100                 s = strcat(s, ", ", _("Jet pack"));
 101         if(cvar("g_powerups") == 0)
 102                 s = strcat(s, ", ", _("No powerups"));
 103         if(cvar("g_powerups") > 0)
 104                 s = strcat(s, ", ", _("Powerups"));
 105         if(s == "")
 106                 return ZCTX(_("MUT^None"));
 107         else
 108                 return substring(s, 2, strlen(s) - 2);
 109 }
 110
 111
 112
 113 // WARNING: dirty hack. TODO clean this up by putting this behaviour in extra classes.
 114 void loadCvarsLaserWeaponArenaWeaponButton(entity me)
 115 {
 116         tokenize_console(cvar_string("g_weaponarena"));
 117         me.checked = (argv(0) == me.cvarValue);
 118 }
 119
 120 void saveCvarsLaserWeaponArenaWeaponButton(entity me)
 121 {
 122         string suffix;
 123
 124         suffix = "";
 125         if(me.cvarValue != "laser" && me.cvarValue != "most")
 126                 if(cvar("menu_weaponarena_with_laser"))
 127                         suffix = " laser";
 128         if(me.checked)
 129                 cvar_set("g_weaponarena", strcat(me.cvarValue, suffix));
 130         else
 131                 cvar_set("g_weaponarena", me.cvarOffValue);
 132 }
 133
 134 .void(entity) draw_weaponarena;
 135 .void(entity) saveCvars_weaponarena;
 136 void saveCvarsLaserWeaponArenaLaserButton(entity me)
 137 {
 138         // run the old function
 139         me.saveCvars_weaponarena(me);
 140
 141         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser") || (cvar_string("g_weaponarena") == "most"));
 142
 143         if not(me.disabled)
 144         {
 145                 // check for the laser suffix
 146                 string s;
 147                 s = cvar_string("g_weaponarena");
 148                 if(me.checked && substring(s, strlen(s) - 6, 6) != " laser")
 149                         s = strcat(s, " laser");
 150                 else if(!me.checked && substring(s, strlen(s) - 6, 6) == " laser")
 151                         s = substring(s, 0, strlen(s) - 6);
 152                 cvar_set("g_weaponarena", s);
 153         }
 154 }
 155
 156 void preDrawLaserWeaponArenaLaserButton(entity me)
 157 {
 158         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser") || (cvar_string("g_weaponarena") == "most"));
 159         // run the old function
 160         me.draw_weaponarena(me);
 161 }
 162 // WARNING: end of dirty hack. Do not try this at home.
 163
 164 float checkCompatibility_pinata(entity me)
 165 {
 166         if(cvar("g_minstagib"))
 167                 return 0;
 168         if(cvar("g_nix"))
 169                 return 0;
 170         if(cvar_string("g_weaponarena") != "0")
 171                 return 0;
 172         return 1;
 173 }
 174 float checkCompatibility_weaponstay(entity me)
 175 {
 176         return checkCompatibility_pinata(me);
 177 }
 178 float checkCompatibility_newtoys(entity me)
 179 {
 180         if(cvar("g_minstagib"))
 181                 return 0;
 182         if(cvar_string("g_weaponarena") == "most")
 183                 return 1;
 184         if(cvar_string("g_weaponarena") == "all")
 185                 return 1;
 186         if(cvar_string("g_weaponarena") != "0")
 187                 return 0;
 188         return 1;
 189 }
 190
 191 void XonoticMutatorsDialog_fill(entity me)
 192 {
 193         entity e, s, w;
 194         float i, j;
 195         string str, hstr;
 196         me.TR(me);
 197                 me.TD(me, 1, 2, makeXonoticTextLabel(0, _("Gameplay mutators:")));
 198         me.TR(me);
 199                 me.TDempty(me, 0.2);
 200                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_dodging", _("Dodging")));
 201         me.TR(me);
 202                 me.TDempty(me, 0.2);
 203                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_cloaked", _("Cloaked")));
 204         me.TR(me);
 205                 me.TDempty(me, 0.2);
 206                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_midair", _("Midair")));
 207         me.TR(me);
 208                 me.TDempty(me, 0.2);
 209                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_vampire", _("Vampire")));
 210         me.TR(me);
 211                 me.TDempty(me, 0.2);
 212                 s = makeXonoticSlider(10, 50, 1, "g_bloodloss");
 213                 me.TD(me, 1, 1.8, e = makeXonoticSliderCheckBox(0, 1, s, _("Blood loss")));
 214                         setDependent(e, "g_minstagib", 0, 0);
 215         me.TR(me);
 216                 me.TDempty(me, 0.4);
 217                 me.TD(me, 1, 1.6, s);
 218         me.TR(me);
 219                 me.TDempty(me, 0.2);
 220                 s = makeXonoticSlider(80, 400, 8, "sv_gravity");
 221                         s.valueDigits = 0;
 222                         s.valueDisplayMultiplier = 0.125; // show gravity in percent
 223                 me.TD(me, 1, 1.8, e = makeXonoticSliderCheckBox(800, 1, s, _("Low gravity")));
 224                         e.savedValue = 200; // good on silvercity
 225         me.TR(me);
 226                 me.TDempty(me, 0.4);
 227                 me.TD(me, 1, 1.6, s);
 228         me.TR(me);
 229                 me.TD(me, 1, 2, makeXonoticTextLabel(0, _("Weapon & item mutators:")));
 230         me.TR(me);
 231                 me.TDempty(me, 0.2);
 232                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_grappling_hook", _("Grappling hook")));
 233         me.TR(me);
 234                 me.TDempty(me, 0.2);
 235                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_jetpack", _("Jet pack")));
 236         me.TR(me);
 237                 me.TDempty(me, 0.2);
 238                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_invincible_projectiles", _("Invincible Projectiles")));
 239         me.TR(me);
 240                 me.TDempty(me, 0.2);
 241                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_new_toys", _("New Toys")));
 242                         setDependentWeird(e, checkCompatibility_newtoys);
 243         me.TR(me);
 244                 me.TDempty(me, 0.2);
 245                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_rocket_flying", _("Rocket Flying")));
 246         me.TR(me);
 247                 me.TDempty(me, 0.2);
 248                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_pinata", _("Piñata")));
 249                         setDependentWeird(e, checkCompatibility_pinata);
 250         me.TR(me);
 251                 me.TDempty(me, 0.2);
 252                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "g_weapon_stay", _("Weapons stay")));
 253                         setDependentWeird(e, checkCompatibility_weaponstay);
 254         me.TR(me);
 255
 256         me.gotoRC(me, 0, 2); me.setFirstColumn(me, me.currentColumn);
 257                 me.TD(me, 1, 4, makeXonoticTextLabel(0, _("Weapon arenas:")));
 258         me.TR(me);
 259                 me.TDempty(me, 0.2);
 260                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, string_null, string_null, _("Regular (no arena)")));
 261         for(i = WEP_FIRST, j = 0; i <= WEP_LAST; ++i)
 262         {
 263                 w = get_weaponinfo(i);
 264                 if(w.spawnflags & WEP_FLAG_HIDDEN)
 265                         continue;
 266                 if(j & 1 == 0)
 267                         me.TR(me);
 268                 str = w.netname;
 269                 hstr = w.message;
 270                 me.TDempty(me, 0.2);
 271                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_weaponarena", strzone(str), strzone(hstr)));
 272                         e.cvarOffValue = "0";
 273                         // custom load/save logic that ignores a " laser" suffix, or adds it
 274                         e.loadCvars = loadCvarsLaserWeaponArenaWeaponButton;
 275                         e.saveCvars = saveCvarsLaserWeaponArenaWeaponButton;
 276                         e.loadCvars(e);
 277                 ++j;
 278         }
 279         me.TR(me);
 280                 me.TDempty(me, 0.2);
 281                 me.TD(me, 1, 1.8, e = makeXonoticCheckBox(0, "menu_weaponarena_with_laser", _("with laser")));
 282                         // hook the draw function to gray it out
 283                         e.draw_weaponarena = e.draw;
 284                         e.draw = preDrawLaserWeaponArenaLaserButton;
 285                         // hook the save function to notify about the cvar
 286                         e.saveCvars_weaponarena = e.saveCvars;
 287                         e.saveCvars = saveCvarsLaserWeaponArenaLaserButton;
 288         me.TR(me);
 289                 me.TD(me, 1, 4, makeXonoticTextLabel(0, _("Special arenas:")));
 290         me.TR(me);
 291                 me.TDempty(me, 0.2);
 292                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_minstagib", string_null, _("MinstaGib")));
 293         me.TR(me);
 294                 me.TDempty(me, 0.2);
 295                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_nix", string_null, _("NIX")));
 296         me.TR(me);
 297                 me.TDempty(me, 0.4);
 298                 me.TD(me, 1, 1.6, e = makeXonoticCheckBox(0, "g_nix_with_laser", _("with laser")));
 299                         setDependent(e, "g_nix", 1, 1);
 300         me.TR(me);
 301                 me.TDempty(me, 0.2);
 302                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_weaponarena", "most", _("Most weapons")));
 303                         e.cvarOffValue = "0";
 304         me.TR(me);
 305                 me.TDempty(me, 0.2);
 306                 me.TD(me, 1, 1.8, e = makeXonoticRadioButton(1, "g_start_weapon_laser", "0", _("No start weapons")));
 307                         e.cvarOffValue = "-1";
 308                         makeMulti(e, "g_start_weapon_shotgun g_start_weapon_uzi g_start_weapon_grenadelauncher g_start_weapon_minelayer g_start_weapon_electro g_start_weapon_crylink g_start_weapon_nex g_start_weapon_hagar g_start_weapon_rocketlauncher g_start_weapon_rifle g_start_weapon_hlac g_start_weapon_seeker g_start_weapon_minstanex g_start_weapon_hook g_start_weapon_porto g_start_weapon_tuba g_start_weapon_minelayer");
 309
 310         me.gotoRC(me, me.rows - 1, 0);
 311                 me.TD(me, 1, me.columns, e = makeXonoticButton(_("OK"), '0 0 0'));
 312                         e.onClick = Dialog_Close;
 313                         e.onClickEntity = me;
 314 }
 315
 316 void XonoticMutatorsDialog_close(entity me)
 317 {
 318         if(me.refilterEntity)
 319                 me.refilterEntity.refilter(me.refilterEntity);
 320         SUPER(XonoticMutatorsDialog).close(me);
 321 }
 322 #endif