qcsrc/menu/xonotic/dialog_multiplayer_playersetup.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayerSettingsTab) EXTENDS(XonoticTab)
   3         METHOD(XonoticPlayerSettingsTab, fill, void(entity))
   4         METHOD(XonoticPlayerSettingsTab, draw, void(entity))
   5         ATTRIB(XonoticPlayerSettingsTab, title, string, _("Player Setup"))
   6         ATTRIB(XonoticPlayerSettingsTab, intendedWidth, float, 0.9)
   7         ATTRIB(XonoticPlayerSettingsTab, rows, float, 22)
   8         ATTRIB(XonoticPlayerSettingsTab, columns, float, 6.5)
   9         ATTRIB(XonoticPlayerSettingsTab, playerNameLabel, entity, NULL)
  10         ATTRIB(XonoticPlayerSettingsTab, playerNameLabelAlpha, float, 0)
  11 ENDCLASS(XonoticPlayerSettingsTab)
  12 entity makeXonoticPlayerSettingsTab();
  13
  14 void HUDSetup_Join_Click(entity me, entity btn);
  15 #endif
  16
  17 #ifdef IMPLEMENTATION
  18
  19 entity makeXonoticPlayerSettingsTab()
  20 {
  21         entity me;
  22         me = spawnXonoticPlayerSettingsTab();
  23         me.configureDialog(me);
  24         return me;
  25 }
  26 void XonoticPlayerSettingsTab_draw(entity me)
  27 {
  28         if(cvar_string("_cl_name") == "Player")
  29                 me.playerNameLabel.alpha = ((mod(time * 2, 2) < 1) ? 1 : 0);
  30         else
  31                 me.playerNameLabel.alpha = me.playerNameLabelAlpha;
  32         SUPER(XonoticPlayerSettingsTab).draw(me);
  33 }
  34 void XonoticPlayerSettingsTab_fill(entity me)
  35 {
  36         entity e, pms, sl, label, e0, box;
  37         float i, r, m, n;
  38
  39         me.TR(me);
  40                 me.TD(me, 1, 0.5, me.playerNameLabel = makeXonoticTextLabel(0, _("Name:")));
  41                         me.playerNameLabelAlpha = me.playerNameLabel.alpha;
  42                 me.TD(me, 1, 2.5, label = makeXonoticTextLabel(0, string_null));
  43                         label.allowCut = 1;
  44                         label.allowColors = 1;
  45                         label.alpha = 1;
  46         me.TR(me);
  47                 me.TD(me, 1, 3.0, box = makeXonoticInputBox(1, "_cl_name"));
  48                         box.forbiddenCharacters = "\r\n\\\"$"; // don't care, isn't getting saved
  49                         box.maxLength = -127; // negative means encoded length in bytes
  50                         box.saveImmediately = 1;
  51                         label.textEntity = box;
  52         me.TR(me);
  53                 me.TD(me, 5, 1, e = makeXonoticColorpicker(box));
  54                 me.TD(me, 5, 2, e = makeXonoticCharmap(box));
  55         me.TR(me);
  56         me.TR(me);
  57         me.TR(me);
  58         me.TR(me);
  59         me.TR(me);
  60         me.TR(me);
  61         me.gotoRC(me, 8, 0.0);
  62                 pms = makeXonoticPlayerModelSelector();
  63                 me.TD(me, 1, 0.6, e = makeXonoticTextLabel(1, _("Model:")));
  64                 me.TD(me, 1, 0.3, e = makeXonoticButton("<<", '0 0 0'));
  65                         e.onClick = PlayerModelSelector_Prev_Click;
  66                         e.onClickEntity = pms;
  67                 me.TD(me, me.rows - me.currentRow - 1, 1.8, pms);
  68                 me.TD(me, 1, 0.3, e = makeXonoticButton(">>", '0 0 0'));
  69                         e.onClick = PlayerModelSelector_Next_Click;
  70                         e.onClickEntity = pms;
  71         me.TR(me);
  72                 r = me.currentRow;
  73                 m = me.rows - r - 2;
  74                 n = 16 - !cvar("developer");
  75                 m = m / (n - 1);
  76                 for(i = 0; i < n; ++i)
  77                 {
  78                         me.gotoRC(me, r + i * m, 0.1);
  79                         me.TDNoMargin(me, m, 0.2, e = makeXonoticColorButton(1, 0, i), '0 1 0');
  80                 }
  81                 for(i = 0; i < n; ++i)
  82                 {
  83                         me.gotoRC(me, r + i * m, 0.4);
  84                         me.TDNoMargin(me, m, 0.2, e = makeXonoticColorButton(2, 1, i), '0 1 0');
  85                 }
  86
  87         me.gotoRC(me, 0, 3.5); me.setFirstColumn(me, me.currentColumn);
  88                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Field of view:")));
  89                 me.TD(me, 1, 2, e = makeXonoticSlider(60, 130, 1, "fov"));
  90         me.TR(me);
  91                 sl = makeXonoticSlider(0.45, 0.75, 0.01, "cl_bobcycle");
  92                 me.TD(me, 1, 1, e = makeXonoticSliderCheckBox(0, 1, sl, _("View bobbing:")));
  93                 makeMulti(sl, "cl_bob2cycle");
  94                 me.TD(me, 1, 2, sl);
  95         me.TR(me);
  96                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Zoom factor:")));
  97                 me.TD(me, 1, 2, e = makeXonoticSlider(2, 16, 0.5, "cl_zoomfactor"));
  98         me.TR(me);
  99                 sl = makeXonoticSlider(1, 8, 0.5, "cl_zoomspeed");
 100                 me.TD(me, 1, 1, e = makeXonoticSliderCheckBox(-1, 1, sl, _("Zoom speed:")));
 101                 me.TD(me, 1, 2, sl);
 102         me.TR(me);
 103                 me.TD(me, 1, 1.5, e = makeXonoticButton(_("Weapon settings..."), '0 0 0'));
 104                         e.onClick = DialogOpenButton_Click;
 105                         e.onClickEntity = main.weaponsDialog;
 106                 me.TD(me, 1, 1.5, e0 = makeXonoticTextLabel(0, string_null));
 107                         e0.textEntity = main.weaponsDialog;
 108                         e0.allowCut = 1;
 109         me.TR(me);
 110                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair:")));
 111                 me.TD(me, 1, 2, e = makeXonoticCheckBox(0, "crosshair_per_weapon", _("Per weapon")));
 112         me.TR(me);
 113                 me.TDempty(me, 0.2);
 114                 for(i = 1; i <= 10; ++i) {
 115                         me.TDNoMargin(me, 1, 2 / 10, e = makeXonoticCrosshairButton(3, i), '1 1 0');
 116                         setDependent(e, "crosshair_per_weapon", 0, 0);
 117                 }
 118                 // show a larger preview of the selected crosshair
 119                 me.TDempty(me, 0.2);
 120                 me.TDNoMargin(me, 2, 2 / 5, e = makeXonoticCrosshairButton(4, -1), '1 1 0'); // crosshair -1 makes this a preview
 121                 setDependent(e, "crosshair_per_weapon", 0, 0);
 122         me.TR(me);
 123                 me.TDempty(me, 0.2);
 124                 for(i = 11; i <= 20; ++i) {
 125                         me.TDNoMargin(me, 1, 2 / 10, e = makeXonoticCrosshairButton(3, i), '1 1 0');
 126                         setDependent(e, "crosshair_per_weapon", 0, 0);
 127                 }
 128         me.TR(me);
 129                 me.TDempty(me, 0.2);
 130                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair size:")));
 131                 me.TD(me, 1, 1.8, e = makeXonoticSlider(0.10, 1.5, 0.05, "crosshair_size"));
 132         me.TR(me);
 133                 me.TDempty(me, 0.2);
 134                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair alpha:")));
 135                 me.TD(me, 1, 1.8, e = makeXonoticSlider(0, 1, 0.1, "crosshair_alpha"));
 136         me.TR(me);
 137                 me.TDempty(me, 0.2);
 138                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, "Crosshair color:"));
 139                 me.TD(me, 1, 0.9, e = makeXonoticRadioButton(4, "crosshair_color_per_weapon", string_null, _("Per weapon")));
 140                 me.TD(me, 1, 0.9, e = makeXonoticRadioButton(4, "crosshair_color_by_health", string_null, _("By health")));
 141         me.TR(me);
 142                 me.TDempty(me, 0.3);
 143                 me.TD(me, 1, 0.9, e = makeXonoticRadioButton(4, string_null, string_null, _("Custom")));
 144                 me.TD(me, 2, 1.8, e = makeXonoticColorpickerString("crosshair_color", "crosshair_color"));
 145                         setDependentAND(e, "crosshair_color_per_weapon", 0, 0, "crosshair_color_by_health", 0, 0);
 146         me.TR(me);
 147         me.TR(me);
 148                 me.TD(me, 1, 3, e = makeXonoticCheckBox(0, "crosshair_dot", _("Enable center dot")));
 149         me.TR(me);
 150                 me.TDempty(me, 0.2);
 151                 me.TD(me, 1, 0.5, e = makeXonoticTextLabel(0, _("Size:")));
 152                 me.TD(me, 1, 0.9, e = makeXonoticSlider(0.2, 2, 0.1, "crosshair_dot_size"));
 153                         setDependent(e, "crosshair_dot", 1, 1);
 154                 me.TD(me, 1, 0.5, e = makeXonoticTextLabel(0, _("Alpha:")));
 155                 me.TD(me, 1, 0.9, e = makeXonoticSlider(0.10, 1, 0.1, "crosshair_dot_alpha"));
 156                         setDependent(e, "crosshair_dot", 1, 1);
 157         me.TR(me);
 158                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Hit test:")));
 159                 me.TD(me, 1, 2/3, e = makeXonoticRadioButton(5, "crosshair_hittest", "0",    ZCTX(_("HTST^None"))));
 160                 me.TD(me, 1, 2/3, e = makeXonoticRadioButton(5, "crosshair_hittest", "1",    _("TrueAim")));
 161                 me.TD(me, 1, 2/3, e = makeXonoticRadioButton(5, "crosshair_hittest", "1.25", _("Enemies")));
 162         me.TR(me);
 163                 me.TDempty(me, 0.4);
 164                 me.TD(me, 1, 2.2, e = makeXonoticButton(_("Waypoints setup..."), '0 0 0'));
 165                         e.onClick = DialogOpenButton_Click;
 166                         e.onClickEntity = main.waypointDialog;
 167         me.TR(me);
 168                 me.TDempty(me, 0.4);
 169                 me.TD(me, 1, 2.2, e = makeXonoticButton(_("Enter HUD editor"), '0 0 0'));
 170                         e.onClick = HUDSetup_Join_Click;
 171                         e.onClickEntity = me;
 172         me.TR(me);
 173         #ifdef ALLOW_FORCEMODELS
 174                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Force models:")));
 175                 me.TD(me, 1, 2/3, e = makeXonoticRadioButton(6, string_null, string_null, ZCTX(_("MDL^None")));
 176                 me.TD(me, 1, 2/3, e = makeXonoticRadioButton(6, "cl_forceplayermodelsfromxonotic", string_null, ZCTX(_("MDL^Custom"))));
 177                 me.TD(me, 1, 2/3, e = makeXonoticRadioButton(6, "cl_forceplayermodels", string_null, ZCTX(_("MDL^All"))));
 178         #endif
 179                 me.TD(me, 1, 3, e = makeXonoticCheckBox(0, "cl_gentle", _("Disable gore effects")));
 180         me.TR(me);
 181                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Gibs:")));
 182                 me.TD(me, 1, 2, e = makeXonoticTextSlider("cl_nogibs"));
 183                         e.addValue(e, ZCTX(_("GIBS^None")), "1");
 184                         e.addValue(e, ZCTX(_("GIBS^Few")), "0.75");
 185                         e.addValue(e, ZCTX(_("GIBS^Many")), "0.5");
 186                         e.addValue(e, ZCTX(_("GIBS^Lots")), "0");
 187                         e.configureXonoticTextSliderValues(e);
 188                         setDependent(e, "cl_gentle", 0, 0);
 189         me.TR(me);
 190                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Damage splash:")));
 191                 me.TD(me, 1, 2, e = makeXonoticSlider(0, 1, 0.05, "hud_damage"));
 192
 193         me.gotoRC(me, me.rows - 1, 0);
 194                 me.TD(me, 1, me.columns, makeXonoticCommandButton(_("Apply immediately"), '0 0 0', "color -1 -1;name \"$_cl_name\";cl_cmd sendcvar cl_weaponpriority;sendcvar cl_zoomfactor;sendcvar cl_zoomspeed;sendcvar cl_autoswitch;sendcvar cl_shownames;sendcvar cl_forceplayermodelsfromxonotic;sendcvar cl_forceplayermodels;playermodel $_cl_playermodel;playerskin $_cl_playerskin", COMMANDBUTTON_APPLY));
 195 }
 196 void HUDSetup_Join_Click(entity me, entity btn)
 197 {
 198         if(! (gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 199         {
 200                 localcmd("map hudsetup/hudsetup", "\n");
 201         }
 202         else
 203                 localcmd("togglemenu 0\n");
 204         localcmd("_hud_configure 1", "\n");
 205 }
 206 #endif