qcsrc/menu/xonotic/dialog_settings_input_userbind.qc

   1 #ifndef DIALOG_SETTINGS_INPUT_USERBIND_H
   2 #define DIALOG_SETTINGS_INPUT_USERBIND_H
   3 #include "dialog.qc"
   4 CLASS(XonoticUserbindEditDialog, XonoticDialog)
   5         METHOD(XonoticUserbindEditDialog, loadUserBind, void(entity, string, string, string))
   6         METHOD(XonoticUserbindEditDialog, fill, void(entity))
   7         ATTRIB(XonoticUserbindEditDialog, title, string, _("User defined key bind"))
   8         ATTRIB(XonoticUserbindEditDialog, color, vector, SKINCOLOR_DIALOG_USERBIND)
   9         ATTRIB(XonoticUserbindEditDialog, intendedWidth, float, 0.7)
  10         ATTRIB(XonoticUserbindEditDialog, rows, float, 4)
  11         ATTRIB(XonoticUserbindEditDialog, columns, float, 3)
  12         ATTRIB(XonoticUserbindEditDialog, keybindBox, entity, NULL)
  13
  14         ATTRIB(XonoticUserbindEditDialog, nameBox, entity, NULL)
  15         ATTRIB(XonoticUserbindEditDialog, commandPressBox, entity, NULL)
  16         ATTRIB(XonoticUserbindEditDialog, commandReleaseBox, entity, NULL)
  17 ENDCLASS(XonoticUserbindEditDialog)
  18 #endif
  19
  20 #ifdef IMPLEMENTATION
  21 void XonoticUserbindEditDialog_Save(entity btn, entity me)
  22 {
  23         me.keybindBox.editUserbind(me.keybindBox, me.nameBox.text, me.commandPressBox.text, me.commandReleaseBox.text);
  24         Dialog_Close(btn, me);
  25 }
  26
  27 void XonoticUserbindEditDialog_loadUserBind(entity me, string theName, string theCommandPress, string theCommandRelease)
  28 {
  29         me.nameBox.setText(me.nameBox, theName);
  30                 me.nameBox.keyDown(me.nameBox, K_END, 0, 0);
  31         me.commandPressBox.setText(me.commandPressBox, theCommandPress);
  32                 me.nameBox.keyDown(me.commandPressBox, K_END, 0, 0);
  33         me.commandReleaseBox.setText(me.commandReleaseBox, theCommandRelease);
  34                 me.nameBox.keyDown(me.commandReleaseBox, K_END, 0, 0);
  35 }
  36
  37 void XonoticUserbindEditDialog_fill(entity me)
  38 {
  39         entity e;
  40         me.TR(me);
  41                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Name:")));
  42                 me.TD(me, 1, me.columns - 1, me.nameBox = makeXonoticInputBox(0, string_null));
  43         me.TR(me);
  44                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Command when pressed:")));
  45                 me.TD(me, 1, me.columns - 1, me.commandPressBox = makeXonoticInputBox(0, string_null));
  46         me.TR(me);
  47                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Command when released:")));
  48                 me.TD(me, 1, me.columns - 1, me.commandReleaseBox = makeXonoticInputBox(0, string_null));
  49         me.TR(me);
  50                 me.TD(me, 1, me.columns / 2, e = makeXonoticButton(_("Save"), '0 0 0'));
  51                         e.onClick = XonoticUserbindEditDialog_Save;
  52                         e.onClickEntity = me;
  53                 me.TD(me, 1, me.columns / 2, e = makeXonoticButton(_("Cancel"), '0 0 0'));
  54                         e.onClick = Dialog_Close;
  55                         e.onClickEntity = me;
  56 }
  57 #endif