qcsrc/menu/xonotic/dialog_settings_misc.qc

   1 #include "dialog_settings_misc.qh"
   2
   3 #include "textlabel.qh"
   4 #include "inputbox.qh"
   5 #include "textslider.qh"
   6 #include "slider.qh"
   7 #include "checkbox.qh"
   8 #include "button.qh"
   9 #include "mainwindow.qh"
  10
  11 #define ADDVALUE_FPS(i) e.addValue(e, strzone(sprintf(_("%d fps"), i)), #i)
  12 #define ADDVALUE_SPEED_KB(i) e.addValue(e, strzone(sprintf(_("%d KB/s"), i)), #i)
  13 #define ADDVALUE_SPEED_MB(i, j) e.addValue(e, strzone(sprintf(_("%d MB/s"), i)), #j)
  14 entity makeXonoticMiscSettingsTab()
  15 {
  16         entity me;
  17         me = NEW(XonoticMiscSettingsTab);
  18         me.configureDialog(me);
  19         return me;
  20 }
  21 void XonoticMiscSettingsTab_fill(entity me)
  22 {
  23         entity e;
  24         //entity sk;
  25
  26         me.TR(me);
  27                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Network")));
  28         me.TR(me);
  29                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Client UDP port:")));
  30                 me.TD(me, 1, 1.5, e = makeXonoticInputBox_T(0, "cl_port",
  31                         _("Force client to use chosen port unless it is set to 0")));
  32         me.TR(me);
  33         me.TR(me);
  34                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Bandwidth:")));
  35                 me.TD(me, 1, 2, e = makeXonoticTextSlider_T("_cl_rate",
  36                         _("Specify your network speed")));
  37                         e.addValue(e, _("56k"), "4000");
  38                         e.addValue(e, _("ISDN"), "7000");
  39                         e.addValue(e, _("Slow ADSL"), "20000");
  40                         e.addValue(e, _("Fast ADSL"), "40000");
  41                         e.addValue(e, _("Broadband"), "66666");
  42                         e.configureXonoticTextSliderValues(e);
  43         me.TR(me);
  44                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Input packets/s:")));
  45                 me.TD(me, 1, 2, e = makeXonoticSlider_T(30, 180, 5, "cl_netfps",
  46                         _("How many input packets to send to the server each second")));
  47         me.TR(me);
  48                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Server queries/s:")));
  49                 me.TD(me, 1, 2, e = makeXonoticSlider(20, 100, 10, "net_slist_queriespersecond"));
  50         me.TR(me);
  51         me.TR(me);
  52                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Downloads:")));
  53                 me.TD(me, 1, 2, e = makeXonoticSlider_T(1, 5, 1, "cl_curl_maxdownloads",
  54                         _("Maximum number of concurrent HTTP/FTP downloads")));
  55         me.TR(me);
  56                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Download speed:")));
  57                 me.TD(me, 1, 2, e = makeXonoticTextSlider("cl_curl_maxspeed"));
  58                 ADDVALUE_SPEED_KB(50);
  59                 ADDVALUE_SPEED_KB(100);
  60                 ADDVALUE_SPEED_KB(300);
  61                 ADDVALUE_SPEED_KB(500);
  62                 ADDVALUE_SPEED_MB(1, 1000);
  63                 ADDVALUE_SPEED_MB(2, 2000);
  64                 e.addValue(e, strzone(_("Unlimited")), "0");
  65                 e.configureXonoticTextSliderValues(e);
  66         me.TR(me);
  67                 if(cvar("developer"))
  68                 {
  69                         me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Local latency:")));
  70                         me.TD(me, 1, 2, e = makeXonoticSlider(0, 1000, 25, "cl_netlocalping"));
  71                 }
  72         me.TR(me);
  73                 me.TD(me, 1, 3, e = makeXonoticCheckBox_T(0, "shownetgraph", _("Show netgraph"),
  74                         _("Show a graph of packet sizes and other information")));
  75         me.TR(me);
  76                 me.TD(me, 1, 3, e = makeXonoticCheckBox(0, "cl_movement", _("Client-side movement prediction")));
  77         me.TR(me);
  78                 me.TD(me, 1, 3, e = makeXonoticCheckBox(0, "cl_movement_errorcompensation", _("Movement error compensation")));
  79                 setDependent(e, "cl_movement", 1, 1);
  80         me.TR(me);
  81                 if(cvar_type("crypto_aeslevel") & CVAR_TYPEFLAG_ENGINE)
  82                         me.TD(me, 1, 3, e = makeXonoticCheckBoxEx(2, 1, "crypto_aeslevel", _("Use encryption (AES) when available"))); // TODO: move up
  83
  84         me.gotoRC(me, 0, 3.2); me.setFirstColumn(me, me.currentColumn);
  85                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Framerate")));
  86         me.TR(me);
  87                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Maximum:")));
  88                 me.TD(me, 1, 2, e = makeXonoticTextSlider("cl_maxfps"));
  89                         ADDVALUE_FPS(30);
  90                         ADDVALUE_FPS(60);
  91                         ADDVALUE_FPS(100);
  92                         ADDVALUE_FPS(125);
  93                         ADDVALUE_FPS(150);
  94                         ADDVALUE_FPS(200);
  95                         ADDVALUE_FPS(250);
  96                         ADDVALUE_FPS(400);
  97                         e.addValue(e, ZCTX(_("MAXFPS^Unlimited")), "0");
  98                         e.configureXonoticTextSliderValues(e);
  99         me.TR(me);
 100                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Target:")));
 101                 me.TD(me, 1, 2, e = makeXonoticTextSlider("cl_minfps"));
 102                         e.addValue(e, ZCTX(_("TRGT^Disabled")), "0");
 103                         ADDVALUE_FPS(30);
 104                         ADDVALUE_FPS(60);
 105                         ADDVALUE_FPS(100);
 106                         ADDVALUE_FPS(125);
 107                         ADDVALUE_FPS(150);
 108                         ADDVALUE_FPS(200);
 109                         ADDVALUE_FPS(250);
 110                         ADDVALUE_FPS(400);
 111                         e.configureXonoticTextSliderValues(e);
 112         me.TR(me);
 113                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Idle limit:")));
 114                 me.TD(me, 1, 2, e = makeXonoticTextSlider("cl_maxidlefps"));
 115                         ADDVALUE_FPS(10);
 116                         ADDVALUE_FPS(20);
 117                         ADDVALUE_FPS(30);
 118                         ADDVALUE_FPS(60);
 119                         e.addValue(e, ZCTX(_("IDLFPS^Unlimited")), "0");
 120                         e.configureXonoticTextSliderValues(e);
 121         me.TR(me);
 122         me.TR(me);
 123                 me.TD(me, 1, 3, e = makeXonoticCheckBox(0, "cl_maxfps_alwayssleep", _("Save processing time for other apps")));
 124                 setDependent(e, "cl_maxfps", 1, 1000);
 125         me.TR(me);
 126                 me.TD(me, 1, 3, e = makeXonoticCheckBox_T(0, "showfps", _("Show frames per second"),
 127                         _("Show your rendered frames per second")));
 128         me.TR(me);
 129         me.TR(me);
 130                 me.TD(me, 1, 3, e = makeXonoticHeaderLabel(_("Other")));
 131         me.TR(me);
 132                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Menu tooltips:")));
 133                 me.TD(me, 1, 2, e = makeXonoticTextSlider_T("menu_tooltips",
 134                         _("Menu tooltips: disabled, standard or advanced (also shows cvar or console command bound to the menu item)")));
 135                         e.addValue(e, ZCTX(_("TLTIP^Disabled")), "0");
 136                         e.addValue(e, ZCTX(_("TLTIP^Standard")), "1");
 137                         e.addValue(e, ZCTX(_("TLTIP^Advanced")), "2");
 138                         e.configureXonoticTextSliderValues(e);
 139         me.TR(me);
 140                 me.TD(me, 1, 3, e = makeXonoticCheckBox_T(0, "showtime", _("Show current date and time"),
 141                         _("Show current date and time of day, useful on screenshots")));
 142                         makeMulti(e, "showdate");
 143         me.TR(me);
 144                 me.TD(me, 1, 3, e = makeXonoticCheckBox(0, "developer", _("Enable developer mode")));
 145
 146         me.TR(me);
 147                 me.TDempty(me, 0.5);
 148                 me.TD(me, 1, 2, e = makeXonoticButton_T(_("Advanced settings..."), '0 0 0',
 149                         _("Advanced settings where you can tweak every single variable of the game")));
 150                         e.onClick = DialogOpenButton_Click;
 151                         e.onClickEntity = main.cvarsDialog;
 152         me.TR(me);
 153                 me.TDempty(me, 0.5);
 154                 me.TD(me, 1, 2, e = makeXonoticButton(_("Factory reset"), '0 0 0'));
 155                         e.onClick = DialogOpenButton_Click;
 156                         e.onClickEntity = main.resetDialog;
 157 }
 158 #undef ADDVALUE_FPS