qcsrc/menu/xonotic/dialog_singleplayer.qc

   1 #include "dialog_singleplayer.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include "bigbutton.qh"
   5 #include "radiobutton.qh"
   6 #include "textlabel.qh"
   7 #include "campaign.qh"
   8
   9 void InstantAction_LoadMap(entity btn, entity dummy)
  10 {
  11         float pmin = 2, pmax = 16, pstep = 1;
  12
  13         cvar_set("timelimit_override", "10");
  14         cvar_set("g_lms_lives_override", "9");
  15
  16         if(random() < 0.4) // 40% are DM
  17         {
  18                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
  19                 pmin = 2;
  20                 pmax = 8;
  21                 pstep = 1;
  22         }
  23         else if(random() < 0.5) // half of the remaining 60%, i.e. 30%, are CTF
  24         {
  25                 MapInfo_SwitchGameType(MAPINFO_TYPE_CTF);
  26                 pmin = 4;
  27                 pmax = 12;
  28                 pstep = 2;
  29         }
  30         else if(random() < 0.5) // half of the remaining 30%, i.e. 15%, are TDM
  31         {
  32                 MapInfo_SwitchGameType(MAPINFO_TYPE_TEAM_DEATHMATCH);
  33                 pmin = 4;
  34                 pmax = 8;
  35                 pstep = 2;
  36         }
  37         else if(random() < 0.666) // 2/3 of the remaining 15%, i.e. 10%, are KH
  38         {
  39                 MapInfo_SwitchGameType(MAPINFO_TYPE_KEYHUNT);
  40                 pmin = 6;
  41                 pmax = 6;
  42                 pstep = 6; // works both for 2 and 3 teams
  43                 // TODO find team count of map, set pstep=2 or 3, and use 2v2(v2) games at least
  44         }
  45         else // somehow distribute the remaining 5%
  46         {
  47                 float r;
  48                 r = floor(random() * 4);
  49                 switch(r)
  50                 {
  51                         default:
  52                         case 0:
  53                                 MapInfo_SwitchGameType(MAPINFO_TYPE_LMS);
  54                                 pmin = 2;
  55                                 pmax = 6;
  56                                 pstep = 1;
  57                                 cvar_set("timelimit_override", "-1");
  58                                 break;
  59                         case 1:
  60                                 MapInfo_SwitchGameType(MAPINFO_TYPE_DOMINATION);
  61                                 pmin = 2;
  62                                 pmax = 8;
  63                                 pstep = 2;
  64                                 break;
  65                         case 2:
  66                                 MapInfo_SwitchGameType(MAPINFO_TYPE_ONSLAUGHT);
  67                                 pmin = 6;
  68                                 pmax = 16;
  69                                 pstep = 2;
  70                                 break;
  71                         case 3:
  72                                 MapInfo_SwitchGameType(MAPINFO_TYPE_ASSAULT);
  73                                 pmin = 4;
  74                                 pmax = 16;
  75                                 pstep = 2;
  76                                 break;
  77                         // CA, Freezetag: bot AI does not work, add them once it does
  78                 }
  79         }
  80
  81         // find random map
  82         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  83         string s;
  84         do
  85         {
  86                 float m;
  87                 m = floor(random() * MapInfo_count);
  88                 s = MapInfo_BSPName_ByID(m);
  89         }
  90         while(!fexists(sprintf("maps/%s.waypoints", s)));
  91         MapInfo_LoadMap(s, 1);
  92
  93         // configure bots
  94         float p;
  95         pmin = pstep * ceil(pmin / pstep);
  96         pmax = pstep * floor(pmax / pstep);
  97         p = pmin + pstep * floor(random() * ((pmax - pmin) / pstep + 1));
  98         cvar_set("bot_number", ftos(p - 1));
  99
 100         // make sure we go back to menu
 101         cvar_set("lastlevel", "1");
 102 }
 103
 104 void XonoticSingleplayerDialog_fill(entity me)
 105 {
 106         entity e, btnPrev, btnNext, lblTitle;
 107
 108         me.TR(me);
 109                 me.TDempty(me, (me.columns - 3) / 2);
 110                 me.TD(me, 2, 3, e = makeXonoticBigButton(_("Instant action! (random map with bots)"), '0 0 0'));
 111                         e.onClick = InstantAction_LoadMap;
 112                         e.onClickEntity = NULL;
 113         me.TR(me);
 114         me.TR(me);
 115         me.TR(me);
 116                 me.TD(me, 1, 1, btnPrev = makeXonoticButton("<<", '0 0 0'));
 117                 me.TD(me, 1, me.columns - 2, lblTitle = makeXonoticTextLabel(0.5, _("???")));
 118                 me.TD(me, 1, 1, btnNext = makeXonoticButton(">>", '0 0 0'));
 119         me.TR(me);
 120                 me.TD(me, me.rows - 6, me.columns, me.campaignBox = makeXonoticCampaignList());
 121                         btnPrev.onClick = MultiCampaign_Prev;
 122                         btnPrev.onClickEntity = me.campaignBox;
 123                         btnNext.onClick = MultiCampaign_Next;
 124                         btnNext.onClickEntity = me.campaignBox;
 125                         me.campaignBox.buttonNext = btnNext;
 126                         me.campaignBox.buttonPrev = btnPrev;
 127                         me.campaignBox.labelTitle = lblTitle;
 128
 129         me.gotoRC(me, me.rows - 2, 0);
 130                 me.TD(me, 1, 2, e = makeXonoticTextLabel(0.5, _("Campaign Difficulty:")));
 131                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "-2", ZCTX(_("CSKL^Easy"))));
 132                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "-1", ZCTX(_("CSKL^Medium"))));
 133                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "0", ZCTX(_("CSKL^Hard"))));
 134                 me.TR(me);
 135                 me.TD(me, 1, me.columns, e = makeXonoticButton(_("Start Singleplayer!"), '0 0 0'));
 136                         e.onClick = CampaignList_LoadMap;
 137                         e.onClickEntity = me.campaignBox;
 138 }