qcsrc/menu/xonotic/gametypelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticGametypeList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticGametypeList, configureXonoticGametypeList, void(entity))
   4         ATTRIB(XonoticGametypeList, rowsPerItem, float, 2)
   5         METHOD(XonoticGametypeList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticGametypeList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticGametypeList, setSelected, void(entity, float))
   8         METHOD(XonoticGametypeList, loadCvars, void(entity))
   9         METHOD(XonoticGametypeList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticGametypeList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticGametypeList, realUpperMargin1, float, 0)
  13         ATTRIB(XonoticGametypeList, realUpperMargin2, float, 0)
  14         ATTRIB(XonoticGametypeList, columnIconOrigin, float, 0)
  15         ATTRIB(XonoticGametypeList, columnIconSize, float, 0)
  16         ATTRIB(XonoticGametypeList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticGametypeList, columnNameSize, float, 0)
  18 ENDCLASS(XonoticGametypeList)
  19 entity makeXonoticGametypeList();
  20 #endif
  21
  22 #ifdef IMPLEMENTATION
  23
  24 entity makeXonoticGametypeList(void)
  25 {
  26         entity me;
  27         me = spawnXonoticGametypeList();
  28         me.configureXonoticGametypeList(me);
  29         return me;
  30 }
  31 void XonoticGametypeList_configureXonoticGametypeList(entity me)
  32 {
  33         me.loadCvars(me);
  34         me.configureXonoticListBox(me);
  35         me.nItems = GameType_GetCount();
  36 }
  37 void XonoticGametypeList_setSelected(entity me, float i)
  38 {
  39         SUPER(XonoticGametypeList).setSelected(me, i);
  40         me.saveCvars(me);
  41 }
  42
  43 void XonoticGametypeList_loadCvars(entity me)
  44 {
  45         float t;
  46         t = MapInfo_CurrentGametype();
  47         float i;
  48         for(i = 0; i < GameType_GetCount(); ++i)
  49                 if(t == GameType_GetID(i))
  50                         break;
  51         if(i >= GameType_GetCount())
  52         {
  53                 for(i = 0; i < GameType_GetCount(); ++i)
  54                         if(t == MAPINFO_TYPE_DEATHMATCH)
  55                                 break;
  56                 if(i >= GameType_GetCount())
  57                         i = 0;
  58         }
  59         me.setSelected(me, i);
  60         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
  61 }
  62 void XonoticGametypeList_saveCvars(entity me)
  63 {
  64         float t;
  65         t = GameType_GetID(me.selectedItem);
  66         if(t == MapInfo_CurrentGametype())
  67                 return;
  68         MapInfo_SwitchGameType(t);
  69         me.parent.gameTypeChangeNotify(me.parent);
  70 }
  71 void XonoticGametypeList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  72 {
  73         string s;
  74         if(isSelected)
  75                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  76
  77         draw_Picture(me.columnIconOrigin * eX, strcat("gametype-icon-", GameType_GetIcon(i)), me.columnIconSize * eX + eY, '1 1 1', SKINALPHA_LISTBOX_SELECTED);
  78         s = GameType_GetName(i);
  79         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  80         s = GameType_GetTeams(i);
  81         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  82 }
  83 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  84 {
  85         me.itemAbsSize = '0 0 0';
  86         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  87
  88         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  89         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  90         me.realUpperMargin1 = 0.5 * (1 - me.realFontSize_y);
  91         me.realUpperMargin2 = me.realUpperMargin1 + me.realFontSize_y;
  92         me.columnIconOrigin = 0;
  93         me.columnIconSize = me.itemAbsSize_y / me.itemAbsSize_x;
  94         me.columnNameOrigin = me.columnIconOrigin + me.columnIconSize;
  95         me.columnNameSize = 1 - me.columnIconSize - 2 * me.realFontSize_x;
  96 }
  97 #endif