qcsrc/menu/xonotic/gametypelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticGametypeList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticGametypeList, configureXonoticGametypeList, void(entity))
   4         ATTRIB(XonoticGametypeList, rowsPerItem, float, 2)
   5         METHOD(XonoticGametypeList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticGametypeList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticGametypeList, setSelected, void(entity, float))
   8         METHOD(XonoticGametypeList, loadCvars, void(entity))
   9         METHOD(XonoticGametypeList, saveCvars, void(entity))
  10         METHOD(XonoticGametypeList, keyDown, float(entity, float, float, float))
  11
  12         ATTRIB(XonoticGametypeList, realFontSize, vector, '0 0 0')
  13         ATTRIB(XonoticGametypeList, realUpperMargin1, float, 0)
  14         ATTRIB(XonoticGametypeList, realUpperMargin2, float, 0)
  15         ATTRIB(XonoticGametypeList, columnIconOrigin, float, 0)
  16         ATTRIB(XonoticGametypeList, columnIconSize, float, 0)
  17         ATTRIB(XonoticGametypeList, columnNameOrigin, float, 0)
  18         ATTRIB(XonoticGametypeList, columnNameSize, float, 0)
  19 ENDCLASS(XonoticGametypeList)
  20 entity makeXonoticGametypeList();
  21 #endif
  22
  23 #ifdef IMPLEMENTATION
  24
  25 entity makeXonoticGametypeList(void)
  26 {
  27         entity me;
  28         me = spawnXonoticGametypeList();
  29         me.configureXonoticGametypeList(me);
  30         return me;
  31 }
  32 void XonoticGametypeList_configureXonoticGametypeList(entity me)
  33 {
  34         float i;
  35         me.configureXonoticListBox(me);
  36         me.nItems = GameType_GetCount();
  37
  38         // we want the pics mipmapped
  39         for(i = 0; i < GameType_GetCount(); ++i)
  40                 draw_PreloadPictureWithFlags(GameType_GetIcon(i), PRECACHE_PIC_MIPMAP);
  41
  42         me.loadCvars(me);
  43 }
  44 void XonoticGametypeList_setSelected(entity me, float i)
  45 {
  46         SUPER(XonoticGametypeList).setSelected(me, i);
  47         me.saveCvars(me);
  48 }
  49
  50 void XonoticGametypeList_loadCvars(entity me)
  51 {
  52         float t;
  53         t = MapInfo_CurrentGametype();
  54         float i;
  55         for(i = 0; i < GameType_GetCount(); ++i)
  56                 if(t == GameType_GetID(i))
  57                         break;
  58         if(i >= GameType_GetCount())
  59         {
  60                 for(i = 0; i < GameType_GetCount(); ++i)
  61                         if(t == MAPINFO_TYPE_DEATHMATCH)
  62                                 break;
  63                 if(i >= GameType_GetCount())
  64                         i = 0;
  65         }
  66         me.setSelected(me, i);
  67         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
  68 }
  69 void XonoticGametypeList_saveCvars(entity me)
  70 {
  71         float t;
  72         t = GameType_GetID(me.selectedItem);
  73         if(t == MapInfo_CurrentGametype())
  74                 return;
  75         MapInfo_SwitchGameType(t);
  76         me.parent.gameTypeChangeNotify(me.parent);
  77 }
  78 void XonoticGametypeList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  79 {
  80         string s;
  81
  82         if(isSelected)
  83                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  84
  85         draw_Picture(me.columnIconOrigin * eX, GameType_GetIcon(i), me.columnIconSize * eX + eY, '1 1 1', SKINALPHA_LISTBOX_SELECTED);
  86         s = GameType_GetName(i);
  87         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.5 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  88         //s = GameType_GetTeams(i);
  89         //draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  90 }
  91 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  92 {
  93         me.itemAbsSize = '0 0 0';
  94         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  95
  96         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  97         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  98         me.realUpperMargin1 = 0.5 * (1 - me.realFontSize_y);
  99         me.realUpperMargin2 = me.realUpperMargin1 + me.realFontSize_y;
 100         me.columnIconOrigin = 0;
 101         me.columnIconSize = me.itemAbsSize_y / me.itemAbsSize_x;
 102         me.columnNameOrigin = me.columnIconOrigin + me.columnIconSize;
 103         me.columnNameSize = 1 - me.columnIconSize - 2 * me.realFontSize_x;
 104 }
 105
 106 float XonoticGametypeList_keyDown(entity me, float scan, float ascii, float shift)
 107 {
 108         if(scan == K_ENTER || scan == K_KP_ENTER)
 109         {
 110                 me.parent.gameTypeSelectNotify(me.parent);
 111                 return 1;
 112         }
 113
 114         return SUPER(XonoticGametypeList).keyDown(me, scan, ascii, shift);
 115 }
 116 #endif