Listbox / Picker: Implement item fading in a different way so that it gets influenced...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / gametypelist.qc
1 #ifdef INTERFACE
2 CLASS(XonoticGametypeList) EXTENDS(XonoticListBox)
3         METHOD(XonoticGametypeList, configureXonoticGametypeList, void(entity))
4         ATTRIB(XonoticGametypeList, rowsPerItem, float, 2)
5         METHOD(XonoticGametypeList, drawListBoxItem, void(entity, int, vector, bool, bool))
6         METHOD(XonoticGametypeList, resizeNotify, void(entity, vector, vector, vector, vector))
7         METHOD(XonoticGametypeList, setSelected, void(entity, float))
8         METHOD(XonoticGametypeList, loadCvars, void(entity))
9         METHOD(XonoticGametypeList, saveCvars, void(entity))
10         METHOD(XonoticGametypeList, keyDown, float(entity, float, float, float))
11         METHOD(XonoticGametypeList, clickListBoxItem, void(entity, float, vector))
12
13         ATTRIB(XonoticGametypeList, realFontSize, vector, '0 0 0')
14         ATTRIB(XonoticGametypeList, realUpperMargin, float, 0)
15         ATTRIB(XonoticGametypeList, columnIconOrigin, float, 0)
16         ATTRIB(XonoticGametypeList, columnIconSize, float, 0)
17         ATTRIB(XonoticGametypeList, columnNameOrigin, float, 0)
18         ATTRIB(XonoticGametypeList, columnNameSize, float, 0)
19 ENDCLASS(XonoticGametypeList)
20 entity makeXonoticGametypeList();
21 #endif
22
23 #ifdef IMPLEMENTATION
24
25 entity makeXonoticGametypeList(void)
26 {
27         entity me;
28         me = spawnXonoticGametypeList();
29         me.configureXonoticGametypeList(me);
30         return me;
31 }
32 void XonoticGametypeList_configureXonoticGametypeList(entity me)
33 {
34         me.configureXonoticListBox(me);
35         me.nItems = GameType_GetCount();
36
37         // we want the pics mipmapped
38         for(int i = 0; i < GameType_GetCount(); ++i)
39                 draw_PreloadPictureWithFlags(GameType_GetIcon(i), PRECACHE_PIC_MIPMAP);
40
41         me.loadCvars(me);
42 }
43 void XonoticGametypeList_setSelected(entity me, float i)
44 {
45         SUPER(XonoticGametypeList).setSelected(me, i);
46         me.saveCvars(me);
47 }
48 void XonoticGametypeList_loadCvars(entity me)
49 {
50         float t;
51         t = MapInfo_CurrentGametype();
52         float i;
53         for(i = 0; i < GameType_GetCount(); ++i)
54                 if(t == GameType_GetID(i))
55                         break;
56         if(i >= GameType_GetCount())
57         {
58                 for(i = 0; i < GameType_GetCount(); ++i)
59                         if(t == MAPINFO_TYPE_DEATHMATCH)
60                                 break;
61                 if(i >= GameType_GetCount())
62                         i = 0;
63         }
64         me.setSelected(me, i);
65         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
66 }
67 void XonoticGametypeList_saveCvars(entity me)
68 {
69         int t = GameType_GetID(me.selectedItem);
70         if (t == MapInfo_CurrentGametype()) {
71                 return;
72         }
73         MapInfo_SwitchGameType(t);
74         entity owner = me.parent;
75         if (owner) { // not set immediately
76                 owner.gameTypeChangeNotify(owner);
77         }
78 }
79 void XonoticGametypeList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
80 {
81         string s1, s2;
82
83         if(isSelected)
84                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
85         else if(isFocused)
86         {
87                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
88                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
89         }
90
91         draw_Picture(me.columnIconOrigin * eX, GameType_GetIcon(i), me.columnIconSize * eX + eY, '1 1 1', SKINALPHA_LISTBOX_SELECTED);
92         s1 = GameType_GetName(i);
93
94         if(_MapInfo_GetTeamPlayBool(GameType_GetID(i)))
95                 s2 = _("teamplay");
96         else
97                 s2 = _("free for all");
98
99         vector save_fontscale = draw_fontscale;
100         float f = draw_CondensedFontFactor(strcat(s1, " ", s2), false, me.realFontSize, 1);
101         draw_fontscale.x *= f;
102         vector fs = me.realFontSize;
103         fs.x *= f;
104         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s1, fs, '1 1 1', SKINALPHA_TEXT, 0);
105         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 1.0 * (me.columnNameSize - draw_TextWidth(s2, 0, fs))) * eX, s2, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
106         draw_fontscale = save_fontscale;
107 }
108 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
109 {
110         me.itemAbsSize = '0 0 0';
111         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
112
113         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
114         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
115         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
116         me.columnIconOrigin = 0;
117         me.columnIconSize = me.itemAbsSize.y / me.itemAbsSize.x;
118         me.columnNameOrigin = me.columnIconOrigin + me.columnIconSize + (0.5 * me.realFontSize.x);
119         me.columnNameSize = 1 - me.columnIconSize - (1.5 * me.realFontSize.x);
120 }
121 float XonoticGametypeList_keyDown(entity me, float scan, float ascii, float shift)
122 {
123         if(scan == K_ENTER || scan == K_KP_ENTER)
124         {
125                 m_play_click_sound(MENU_SOUND_EXECUTE);
126                 me.parent.gameTypeSelectNotify(me.parent);
127                 return 1;
128         }
129
130         return SUPER(XonoticGametypeList).keyDown(me, scan, ascii, shift);
131 }
132 void XonoticGametypeList_clickListBoxItem(entity me, float i, vector where)
133 {
134         m_play_click_sound(MENU_SOUND_SELECT);
135 }
136 #endif