qcsrc/menu/xonotic/gametypelist.qc

   1 #ifdef INTERFACE
   2 CLASS(XonoticGametypeList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticGametypeList, configureXonoticGametypeList, void(entity))
   4         ATTRIB(XonoticGametypeList, rowsPerItem, float, 2)
   5         METHOD(XonoticGametypeList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticGametypeList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticGametypeList, setSelected, void(entity, float))
   8         METHOD(XonoticGametypeList, loadCvars, void(entity))
   9         METHOD(XonoticGametypeList, saveCvars, void(entity))
  10         METHOD(XonoticGametypeList, keyDown, float(entity, float, float, float))
  11
  12         ATTRIB(XonoticGametypeList, realFontSize, vector, '0 0 0')
  13         ATTRIB(XonoticGametypeList, realUpperMargin, float, 0)
  14         ATTRIB(XonoticGametypeList, columnIconOrigin, float, 0)
  15         ATTRIB(XonoticGametypeList, columnIconSize, float, 0)
  16         ATTRIB(XonoticGametypeList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticGametypeList, columnNameSize, float, 0)
  18 ENDCLASS(XonoticGametypeList)
  19 entity makeXonoticGametypeList();
  20 #endif
  21
  22 #ifdef IMPLEMENTATION
  23
  24 entity makeXonoticGametypeList(void)
  25 {
  26         entity me;
  27         me = spawnXonoticGametypeList();
  28         me.configureXonoticGametypeList(me);
  29         return me;
  30 }
  31 void XonoticGametypeList_configureXonoticGametypeList(entity me)
  32 {
  33         float i;
  34         me.configureXonoticListBox(me);
  35         me.nItems = GameType_GetCount();
  36
  37         // we want the pics mipmapped
  38         for(i = 0; i < GameType_GetCount(); ++i)
  39                 draw_PreloadPictureWithFlags(GameType_GetIcon(i), PRECACHE_PIC_MIPMAP);
  40
  41         me.loadCvars(me);
  42 }
  43 void XonoticGametypeList_setSelected(entity me, float i)
  44 {
  45         SUPER(XonoticGametypeList).setSelected(me, i);
  46         me.saveCvars(me);
  47 }
  48
  49 void XonoticGametypeList_loadCvars(entity me)
  50 {
  51         float t;
  52         t = MapInfo_CurrentGametype();
  53         float i;
  54         for(i = 0; i < GameType_GetCount(); ++i)
  55                 if(t == GameType_GetID(i))
  56                         break;
  57         if(i >= GameType_GetCount())
  58         {
  59                 for(i = 0; i < GameType_GetCount(); ++i)
  60                         if(t == MAPINFO_TYPE_DEATHMATCH)
  61                                 break;
  62                 if(i >= GameType_GetCount())
  63                         i = 0;
  64         }
  65         me.setSelected(me, i);
  66         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
  67 }
  68 void XonoticGametypeList_saveCvars(entity me)
  69 {
  70         float t;
  71         t = GameType_GetID(me.selectedItem);
  72         if(t == MapInfo_CurrentGametype())
  73                 return;
  74         MapInfo_SwitchGameType(t);
  75         me.parent.gameTypeChangeNotify(me.parent);
  76 }
  77 void XonoticGametypeList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  78 {
  79         string s1, s2;
  80
  81         if(isSelected)
  82                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  83
  84         draw_Picture(me.columnIconOrigin * eX, GameType_GetIcon(i), me.columnIconSize * eX + eY, '1 1 1', SKINALPHA_LISTBOX_SELECTED);
  85         s1 = GameType_GetName(i);
  86
  87         if(_MapInfo_GetTeamPlayBool(GameType_GetID(i)))
  88                 s2 = _("teamplay");
  89         else
  90                 s2 = _("free for all");
  91
  92         vector save_fontscale = draw_fontscale;
  93         float f = draw_CondensedFontFactor(strcat(s1, " ", s2), FALSE, me.realFontSize, 1);
  94         draw_fontscale_x *= f;
  95         vector fs = me.realFontSize;
  96         fs_x *= f;
  97         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s1, fs, '1 1 1', SKINALPHA_TEXT, 0);
  98         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 1.0 * (me.columnNameSize - draw_TextWidth(s2, 0, fs))) * eX, s2, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  99         draw_fontscale = save_fontscale;
 100 }
 101 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 102 {
 103         me.itemAbsSize = '0 0 0';
 104         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 105
 106         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 107         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 108         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 109         me.columnIconOrigin = 0;
 110         me.columnIconSize = me.itemAbsSize_y / me.itemAbsSize_x;
 111         me.columnNameOrigin = me.columnIconOrigin + me.columnIconSize + (0.5 * me.realFontSize_x);
 112         me.columnNameSize = 1 - me.columnIconSize - (1.5 * me.realFontSize_x);
 113 }
 114
 115 float XonoticGametypeList_keyDown(entity me, float scan, float ascii, float shift)
 116 {
 117         if(scan == K_ENTER || scan == K_KP_ENTER)
 118         {
 119                 me.parent.gameTypeSelectNotify(me.parent);
 120                 return 1;
 121         }
 122
 123         return SUPER(XonoticGametypeList).keyDown(me, scan, ascii, shift);
 124 }
 125 #endif