qcsrc/menu/xonotic/gametypelist.qc

   1 #ifndef GAMETYPELIST_H
   2 #define GAMETYPELIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticGametypeList, XonoticListBox)
   5         METHOD(XonoticGametypeList, configureXonoticGametypeList, void(entity));
   6         ATTRIB(XonoticGametypeList, rowsPerItem, float, 2)
   7         METHOD(XonoticGametypeList, drawListBoxItem, void(entity, int, vector, bool, bool));
   8         METHOD(XonoticGametypeList, resizeNotify, void(entity, vector, vector, vector, vector));
   9         METHOD(XonoticGametypeList, setSelected, void(entity, float));
  10         METHOD(XonoticGametypeList, loadCvars, void(entity));
  11         METHOD(XonoticGametypeList, saveCvars, void(entity));
  12         METHOD(XonoticGametypeList, keyDown, float(entity, float, float, float));
  13         METHOD(XonoticGametypeList, clickListBoxItem, void(entity, float, vector));
  14         METHOD(XonoticGametypeList, focusedItemChangeNotify, void(entity));
  15
  16         ATTRIB(XonoticGametypeList, realFontSize, vector, '0 0 0')
  17         ATTRIB(XonoticGametypeList, realUpperMargin, float, 0)
  18         ATTRIB(XonoticGametypeList, columnIconOrigin, float, 0)
  19         ATTRIB(XonoticGametypeList, columnIconSize, float, 0)
  20         ATTRIB(XonoticGametypeList, columnNameOrigin, float, 0)
  21         ATTRIB(XonoticGametypeList, columnNameSize, float, 0)
  22 ENDCLASS(XonoticGametypeList)
  23 entity makeXonoticGametypeList();
  24 #endif
  25
  26 #ifdef IMPLEMENTATION
  27
  28 entity makeXonoticGametypeList(void)
  29 {
  30         entity me;
  31         me = NEW(XonoticGametypeList);
  32         me.configureXonoticGametypeList(me);
  33         return me;
  34 }
  35 void XonoticGametypeList_configureXonoticGametypeList(entity me)
  36 {
  37         me.configureXonoticListBox(me);
  38         me.nItems = GameType_GetCount();
  39
  40         if(SKINBOOL_GAMETYPELIST_ICON_BLUR)
  41         {
  42                 for(int i = 0; i < GameType_GetCount(); ++i)
  43                         draw_PreloadPictureWithFlags(GameType_GetIcon(i), PRECACHE_PIC_MIPMAP);
  44         }
  45
  46         me.loadCvars(me);
  47 }
  48 void XonoticGametypeList_setSelected(entity me, float i)
  49 {
  50         SUPER(XonoticGametypeList).setSelected(me, i);
  51         me.saveCvars(me);
  52 }
  53 void XonoticGametypeList_loadCvars(entity me)
  54 {
  55         float t;
  56         t = MapInfo_CurrentGametype();
  57         float i;
  58         for(i = 0; i < GameType_GetCount(); ++i)
  59                 if(t == GameType_GetID(i))
  60                         break;
  61         if(i >= GameType_GetCount())
  62         {
  63                 for(i = 0; i < GameType_GetCount(); ++i)
  64                         if(t == MAPINFO_TYPE_DEATHMATCH)
  65                                 break;
  66                 if(i >= GameType_GetCount())
  67                         i = 0;
  68         }
  69         me.setSelected(me, i);
  70         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
  71 }
  72 void XonoticGametypeList_saveCvars(entity me)
  73 {
  74         int t = GameType_GetID(me.selectedItem);
  75         if (t == MapInfo_CurrentGametype()) {
  76                 return;
  77         }
  78         MapInfo_SwitchGameType(t);
  79         entity owner = me.parent;
  80         if (owner) { // not set immediately
  81                 owner.gameTypeChangeNotify(owner);
  82         }
  83 }
  84 void XonoticGametypeList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
  85 {
  86         string s1, s2;
  87
  88         if(isSelected)
  89                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  90         else if(isFocused)
  91         {
  92                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
  93                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
  94         }
  95
  96         draw_Picture(me.columnIconOrigin * eX, GameType_GetIcon(i), me.columnIconSize * eX + eY, '1 1 1', SKINALPHA_LISTBOX_SELECTED);
  97         s1 = GameType_GetName(i);
  98
  99         if(_MapInfo_GetTeamPlayBool(GameType_GetID(i)))
 100                 s2 = _("teamplay");
 101         else
 102                 s2 = _("free for all");
 103
 104         vector save_fontscale = draw_fontscale;
 105         float f = draw_CondensedFontFactor(strcat(s1, " ", s2), false, me.realFontSize, 1);
 106         draw_fontscale.x *= f;
 107         vector fs = me.realFontSize;
 108         fs.x *= f;
 109         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s1, fs, '1 1 1', SKINALPHA_TEXT, 0);
 110         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 1.0 * (me.columnNameSize - draw_TextWidth(s2, 0, fs))) * eX, s2, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
 111         draw_fontscale = save_fontscale;
 112 }
 113 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 114 {
 115         me.itemAbsSize = '0 0 0';
 116         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 117
 118         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 119         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 120         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 121         me.columnIconOrigin = 0;
 122         me.columnIconSize = me.itemAbsSize.y / me.itemAbsSize.x;
 123         me.columnNameOrigin = me.columnIconOrigin + me.columnIconSize + (0.5 * me.realFontSize.x);
 124         me.columnNameSize = 1 - me.columnIconSize - (1.5 * me.realFontSize.x);
 125 }
 126 float XonoticGametypeList_keyDown(entity me, float scan, float ascii, float shift)
 127 {
 128         if(scan == K_ENTER || scan == K_KP_ENTER)
 129         {
 130                 m_play_click_sound(MENU_SOUND_EXECUTE);
 131                 me.parent.gameTypeSelectNotify(me.parent);
 132                 return 1;
 133         }
 134
 135         return SUPER(XonoticGametypeList).keyDown(me, scan, ascii, shift);
 136 }
 137 void XonoticGametypeList_clickListBoxItem(entity me, float i, vector where)
 138 {
 139         m_play_click_sound(MENU_SOUND_SELECT);
 140 }
 141 void XonoticGametypeList_focusedItemChangeNotify(entity me)
 142 {
 143         if(me.focusedItem >= 0)
 144                 setZonedTooltip(me, MapInfo_Type_Description(GameType_GetID(me.focusedItem)), string_null);
 145         else
 146                 clearTooltip(me);
 147 }
 148 #endif