qcsrc/menu/xonotic/gametypelist.qc

   1 #ifdef INTERFACE
   2 CLASS(XonoticGametypeList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticGametypeList, configureXonoticGametypeList, void(entity))
   4         ATTRIB(XonoticGametypeList, rowsPerItem, float, 2)
   5         METHOD(XonoticGametypeList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticGametypeList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticGametypeList, setSelected, void(entity, float))
   8         METHOD(XonoticGametypeList, loadCvars, void(entity))
   9         METHOD(XonoticGametypeList, saveCvars, void(entity))
  10         METHOD(XonoticGametypeList, keyDown, float(entity, float, float, float))
  11         METHOD(XonoticGametypeList, clickListBoxItem, void(entity, float, vector))
  12
  13         ATTRIB(XonoticGametypeList, realFontSize, vector, '0 0 0')
  14         ATTRIB(XonoticGametypeList, realUpperMargin, float, 0)
  15         ATTRIB(XonoticGametypeList, columnIconOrigin, float, 0)
  16         ATTRIB(XonoticGametypeList, columnIconSize, float, 0)
  17         ATTRIB(XonoticGametypeList, columnNameOrigin, float, 0)
  18         ATTRIB(XonoticGametypeList, columnNameSize, float, 0)
  19 ENDCLASS(XonoticGametypeList)
  20 entity makeXonoticGametypeList();
  21 #endif
  22
  23 #ifdef IMPLEMENTATION
  24
  25 entity makeXonoticGametypeList(void)
  26 {
  27         entity me;
  28         me = spawnXonoticGametypeList();
  29         me.configureXonoticGametypeList(me);
  30         return me;
  31 }
  32 void XonoticGametypeList_configureXonoticGametypeList(entity me)
  33 {
  34         me.configureXonoticListBox(me);
  35         me.nItems = GameType_GetCount();
  36
  37         // we want the pics mipmapped
  38         for(int i = 0; i < GameType_GetCount(); ++i)
  39                 draw_PreloadPictureWithFlags(GameType_GetIcon(i), PRECACHE_PIC_MIPMAP);
  40
  41         me.loadCvars(me);
  42 }
  43 void XonoticGametypeList_setSelected(entity me, float i)
  44 {
  45         SUPER(XonoticGametypeList).setSelected(me, i);
  46         me.saveCvars(me);
  47 }
  48 void XonoticGametypeList_loadCvars(entity me)
  49 {
  50         float t;
  51         t = MapInfo_CurrentGametype();
  52         float i;
  53         for(i = 0; i < GameType_GetCount(); ++i)
  54                 if(t == GameType_GetID(i))
  55                         break;
  56         if(i >= GameType_GetCount())
  57         {
  58                 for(i = 0; i < GameType_GetCount(); ++i)
  59                         if(t == MAPINFO_TYPE_DEATHMATCH)
  60                                 break;
  61                 if(i >= GameType_GetCount())
  62                         i = 0;
  63         }
  64         me.setSelected(me, i);
  65         // do we need this: me.parent.gameTypeChangeNotify(me.parent); // to make sure
  66 }
  67 void XonoticGametypeList_saveCvars(entity me)
  68 {
  69         int t = GameType_GetID(me.selectedItem);
  70         if (t == MapInfo_CurrentGametype()) {
  71                 return;
  72         }
  73         MapInfo_SwitchGameType(t);
  74         entity owner = me.parent;
  75         if (owner) { // not set immediately
  76                 owner.gameTypeChangeNotify(owner);
  77         }
  78 }
  79 void XonoticGametypeList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  80 {
  81         string s1, s2;
  82
  83         if(isSelected)
  84                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  85
  86         draw_Picture(me.columnIconOrigin * eX, GameType_GetIcon(i), me.columnIconSize * eX + eY, '1 1 1', SKINALPHA_LISTBOX_SELECTED);
  87         s1 = GameType_GetName(i);
  88
  89         if(_MapInfo_GetTeamPlayBool(GameType_GetID(i)))
  90                 s2 = _("teamplay");
  91         else
  92                 s2 = _("free for all");
  93
  94         vector save_fontscale = draw_fontscale;
  95         float f = draw_CondensedFontFactor(strcat(s1, " ", s2), false, me.realFontSize, 1);
  96         draw_fontscale.x *= f;
  97         vector fs = me.realFontSize;
  98         fs.x *= f;
  99         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s1, fs, '1 1 1', SKINALPHA_TEXT, 0);
 100         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 1.0 * (me.columnNameSize - draw_TextWidth(s2, 0, fs))) * eX, s2, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
 101         draw_fontscale = save_fontscale;
 102 }
 103 void XonoticGametypeList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 104 {
 105         me.itemAbsSize = '0 0 0';
 106         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 107
 108         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 109         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 110         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 111         me.columnIconOrigin = 0;
 112         me.columnIconSize = me.itemAbsSize.y / me.itemAbsSize.x;
 113         me.columnNameOrigin = me.columnIconOrigin + me.columnIconSize + (0.5 * me.realFontSize.x);
 114         me.columnNameSize = 1 - me.columnIconSize - (1.5 * me.realFontSize.x);
 115 }
 116 float XonoticGametypeList_keyDown(entity me, float scan, float ascii, float shift)
 117 {
 118         if(scan == K_ENTER || scan == K_KP_ENTER)
 119         {
 120                 m_play_click_sound(MENU_SOUND_EXECUTE);
 121                 me.parent.gameTypeSelectNotify(me.parent);
 122                 return 1;
 123         }
 124
 125         return SUPER(XonoticGametypeList).keyDown(me, scan, ascii, shift);
 126 }
 127 void XonoticGametypeList_clickListBoxItem(entity me, float i, vector where)
 128 {
 129         m_play_click_sound(MENU_SOUND_SELECT);
 130 }
 131 #endif