qcsrc/menu/xonotic/keybinder.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticKeyBinder) EXTENDS(XonoticListBox)
   3         METHOD(XonoticKeyBinder, configureXonoticKeyBinder, void(entity))
   4         ATTRIB(XonoticKeyBinder, rowsPerItem, float, 1)
   5         METHOD(XonoticKeyBinder, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticKeyBinder, clickListBoxItem, void(entity, float, vector))
   7         METHOD(XonoticKeyBinder, resizeNotify, void(entity, vector, vector, vector, vector))
   8         METHOD(XonoticKeyBinder, setSelected, void(entity, float))
   9         METHOD(XonoticKeyBinder, keyDown, float(entity, float, float, float))
  10         METHOD(XonoticKeyBinder, keyGrabbed, void(entity, float, float))
  11
  12         ATTRIB(XonoticKeyBinder, realFontSize, vector, '0 0 0')
  13         ATTRIB(XonoticKeyBinder, realUpperMargin, float, 0)
  14         ATTRIB(XonoticKeyBinder, columnFunctionOrigin, float, 0)
  15         ATTRIB(XonoticKeyBinder, columnFunctionSize, float, 0)
  16         ATTRIB(XonoticKeyBinder, columnKeysOrigin, float, 0)
  17         ATTRIB(XonoticKeyBinder, columnKeysSize, float, 0)
  18
  19         ATTRIB(XonoticKeyBinder, lastClickedKey, float, -1)
  20         ATTRIB(XonoticKeyBinder, lastClickedTime, float, 0)
  21         ATTRIB(XonoticKeyBinder, previouslySelected, float, -1)
  22         ATTRIB(XonoticKeyBinder, inMouseHandler, float, 0)
  23         ATTRIB(XonoticKeyBinder, userbindEditButton, entity, NULL)
  24         ATTRIB(XonoticKeyBinder, keyGrabButton, entity, NULL)
  25         ATTRIB(XonoticKeyBinder, clearButton, entity, NULL)
  26         ATTRIB(XonoticKeyBinder, userbindEditDialog, entity, NULL)
  27         METHOD(XonoticKeyBinder, editUserbind, void(entity, string, string, string))
  28 ENDCLASS(XonoticKeyBinder)
  29 entity makeXonoticKeyBinder();
  30 void KeyBinder_Bind_Change(entity btn, entity me);
  31 void KeyBinder_Bind_Clear(entity btn, entity me);
  32 void KeyBinder_Bind_Edit(entity btn, entity me);
  33 #endif
  34
  35 #ifdef IMPLEMENTATION
  36
  37 const string KEY_NOT_BOUND_CMD = "// not bound";
  38
  39 #define MAX_KEYS_PER_FUNCTION 2
  40 #define MAX_KEYBINDS 256
  41 string Xonotic_KeyBinds_Functions[MAX_KEYBINDS];
  42 string Xonotic_KeyBinds_Descriptions[MAX_KEYBINDS];
  43 var float Xonotic_KeyBinds_Count = -1;
  44
  45 void Xonotic_KeyBinds_Read()
  46 {
  47         float fh;
  48         string s;
  49
  50         Xonotic_KeyBinds_Count = 0;
  51         fh = fopen(language_filename("keybinds.txt"), FILE_READ);
  52         if(fh < 0)
  53                 return;
  54         while((s = fgets(fh)))
  55         {
  56                 if(tokenize_console(s) != 2)
  57                         continue;
  58                 Xonotic_KeyBinds_Functions[Xonotic_KeyBinds_Count] = strzone(argv(0));
  59                 Xonotic_KeyBinds_Descriptions[Xonotic_KeyBinds_Count] = strzone(argv(1));
  60                 ++Xonotic_KeyBinds_Count;
  61                 if(Xonotic_KeyBinds_Count >= MAX_KEYBINDS)
  62                         break;
  63         }
  64         fclose(fh);
  65 }
  66
  67 entity makeXonoticKeyBinder()
  68 {
  69         entity me;
  70         me = spawnXonoticKeyBinder();
  71         me.configureXonoticKeyBinder(me);
  72         return me;
  73 }
  74 void replace_bind(string from, string to)
  75 {
  76         float n, j, k;
  77         n = tokenize(findkeysforcommand(from, 0)); // uses '...' strings
  78         for(j = 0; j < n; ++j)
  79         {
  80                 k = stof(argv(j));
  81                 if(k != -1)
  82                         localcmd("\nbind \"", keynumtostring(k), "\" \"", to, "\"\n");
  83         }
  84         if(n)
  85                 cvar_set("_hud_showbinds_reload", "1");
  86 }
  87 void XonoticKeyBinder_configureXonoticKeyBinder(entity me)
  88 {
  89         me.configureXonoticListBox(me);
  90         if(Xonotic_KeyBinds_Count < 0)
  91                 Xonotic_KeyBinds_Read();
  92         me.nItems = Xonotic_KeyBinds_Count;
  93         me.setSelected(me, 0);
  94
  95         // TEMP: Xonotic 0.1 to later
  96         replace_bind("impulse 1", "weapon_group_1");
  97         replace_bind("impulse 2", "weapon_group_2");
  98         replace_bind("impulse 3", "weapon_group_3");
  99         replace_bind("impulse 4", "weapon_group_4");
 100         replace_bind("impulse 5", "weapon_group_5");
 101         replace_bind("impulse 6", "weapon_group_6");
 102         replace_bind("impulse 7", "weapon_group_7");
 103         replace_bind("impulse 8", "weapon_group_8");
 104         replace_bind("impulse 9", "weapon_group_9");
 105         replace_bind("impulse 14", "weapon_group_0");
 106 }
 107 void XonoticKeyBinder_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 108 {
 109         SUPER(XonoticKeyBinder).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 110
 111         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
 112         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
 113         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 114
 115         me.columnFunctionOrigin = 0;
 116         me.columnKeysSize = me.realFontSize_x * 12;
 117         me.columnFunctionSize = 1 - me.columnKeysSize - 2 * me.realFontSize_x;
 118         me.columnKeysOrigin = me.columnFunctionOrigin + me.columnFunctionSize + me.realFontSize_x;
 119
 120         if(me.userbindEditButton)
 121                 me.userbindEditButton.disabled = (substring(Xonotic_KeyBinds_Descriptions[me.selectedItem], 0, 1) != "$");
 122 }
 123 void KeyBinder_Bind_Change(entity btn, entity me)
 124 {
 125         string func;
 126
 127         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 128         if(func == "")
 129                 return;
 130
 131         me.keyGrabButton.forcePressed = 1;
 132         me.clearButton.disabled = 1;
 133         keyGrabber = me;
 134 }
 135 void XonoticKeyBinder_keyGrabbed(entity me, float key, float ascii)
 136 {
 137         float n, j, k, nvalid;
 138         string func;
 139
 140         me.keyGrabButton.forcePressed = 0;
 141         me.clearButton.disabled = 0;
 142
 143         if(key == K_ESCAPE)
 144                 return;
 145
 146         // forbid these keys from being bound in the menu
 147         if(key == K_CAPSLOCK || key == K_NUMLOCK)
 148         {
 149                 KeyBinder_Bind_Change(me, me);
 150                 return;
 151         }
 152
 153         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 154         if(func == "")
 155                 return;
 156
 157         n = tokenize(findkeysforcommand(func, 0)); // uses '...' strings
 158         nvalid = 0;
 159         for(j = 0; j < n; ++j)
 160         {
 161                 k = stof(argv(j));
 162                 if(k != -1)
 163                         ++nvalid;
 164         }
 165         if(nvalid >= MAX_KEYS_PER_FUNCTION)
 166         {
 167                 for(j = 0; j < n; ++j)
 168                 {
 169                         k = stof(argv(j));
 170                         if(k != -1)
 171                                 //localcmd("\nunbind \"", keynumtostring(k), "\"\n");
 172                                 localcmd("\nbind \"", keynumtostring(k), "\" \"", KEY_NOT_BOUND_CMD, "\"\n");
 173                 }
 174         }
 175         localcmd("\nbind \"", keynumtostring(key), "\" \"", func, "\"\n");
 176         localcmd("-zoom\n"); // to make sure we aren't in togglezoom'd state
 177         cvar_set("_hud_showbinds_reload", "1");
 178 }
 179 void XonoticKeyBinder_editUserbind(entity me, string theName, string theCommandPress, string theCommandRelease)
 180 {
 181         string func, descr;
 182
 183         if(!me.userbindEditDialog)
 184                 return;
 185
 186         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 187         if(func == "")
 188                 return;
 189
 190         descr = Xonotic_KeyBinds_Descriptions[me.selectedItem];
 191         if(substring(descr, 0, 1) != "$")
 192                 return;
 193         descr = substring(descr, 1, strlen(descr) - 1);
 194
 195         // Hooray! It IS a user bind!
 196         cvar_set(strcat(descr, "_description"), theName);
 197         cvar_set(strcat(descr, "_press"), theCommandPress);
 198         cvar_set(strcat(descr, "_release"), theCommandRelease);
 199 }
 200 void KeyBinder_Bind_Edit(entity btn, entity me)
 201 {
 202         string func, descr;
 203
 204         if(!me.userbindEditDialog)
 205                 return;
 206
 207         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 208         if(func == "")
 209                 return;
 210
 211         descr = Xonotic_KeyBinds_Descriptions[me.selectedItem];
 212         if(substring(descr, 0, 1) != "$")
 213                 return;
 214         descr = substring(descr, 1, strlen(descr) - 1);
 215
 216         // Hooray! It IS a user bind!
 217         me.userbindEditDialog.loadUserBind(me.userbindEditDialog, cvar_string(strcat(descr, "_description")), cvar_string(strcat(descr, "_press")), cvar_string(strcat(descr, "_release")));
 218
 219         DialogOpenButton_Click(btn, me.userbindEditDialog);
 220 }
 221 void KeyBinder_Bind_Clear(entity btn, entity me)
 222 {
 223         float n, j, k;
 224         string func;
 225
 226         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 227         if(func == "")
 228                 return;
 229
 230         n = tokenize(findkeysforcommand(func, 0)); // uses '...' strings
 231         for(j = 0; j < n; ++j)
 232         {
 233                 k = stof(argv(j));
 234                 if(k != -1)
 235                         //localcmd("\nunbind \"", keynumtostring(k), "\"\n");
 236                         localcmd("\nbind \"", keynumtostring(k), "\" \"", KEY_NOT_BOUND_CMD, "\"\n");
 237         }
 238         localcmd("-zoom\n"); // to make sure we aren't in togglezoom'd state
 239         cvar_set("_hud_showbinds_reload", "1");
 240 }
 241 void KeyBinder_Bind_Reset_All(entity btn, entity me)
 242 {
 243         localcmd("unbindall\n");
 244         localcmd("exec binds-default.cfg\n");
 245         localcmd("-zoom\n"); // to make sure we aren't in togglezoom'd state
 246         cvar_set("_hud_showbinds_reload", "1");
 247 }
 248 void XonoticKeyBinder_clickListBoxItem(entity me, float i, vector where)
 249 {
 250         if(i == me.lastClickedKey)
 251                 if(time < me.lastClickedTime + 0.3)
 252                 {
 253                         // DOUBLE CLICK!
 254                         KeyBinder_Bind_Change(NULL, me);
 255                 }
 256         me.lastClickedKey = i;
 257         me.lastClickedTime = time;
 258 }
 259 void XonoticKeyBinder_setSelected(entity me, float i)
 260 {
 261         // handling of "unselectable" items
 262         i = floor(0.5 + bound(0, i, me.nItems - 1));
 263         if(me.pressed == 0 || me.pressed == 1) // keyboard or scrolling - skip unselectable items
 264         {
 265                 if(i > me.previouslySelected)
 266                 {
 267                         while((i < me.nItems - 1) && (Xonotic_KeyBinds_Functions[i] == ""))
 268                                 ++i;
 269                 }
 270                 while((i > 0) && (Xonotic_KeyBinds_Functions[i] == ""))
 271                         --i;
 272                 while((i < me.nItems - 1) && (Xonotic_KeyBinds_Functions[i] == ""))
 273                         ++i;
 274         }
 275         if(me.pressed == 3) // released the mouse - fall back to last valid item
 276         {
 277                 if(Xonotic_KeyBinds_Functions[i] == "")
 278                         i = me.previouslySelected;
 279         }
 280         if(Xonotic_KeyBinds_Functions[i] != "")
 281                 me.previouslySelected = i;
 282         if(me.userbindEditButton)
 283                 me.userbindEditButton.disabled = (substring(Xonotic_KeyBinds_Descriptions[i], 0, 1) != "$");
 284         SUPER(XonoticKeyBinder).setSelected(me, i);
 285 }
 286 float XonoticKeyBinder_keyDown(entity me, float key, float ascii, float shift)
 287 {
 288         float r;
 289         r = 1;
 290         switch(key)
 291         {
 292                 case K_ENTER:
 293                 case K_KP_ENTER:
 294                 case K_SPACE:
 295                         KeyBinder_Bind_Change(me, me);
 296                         break;
 297                 case K_DEL:
 298                 case K_KP_DEL:
 299                 case K_BACKSPACE:
 300                         KeyBinder_Bind_Clear(me, me);
 301                         break;
 302                 default:
 303                         r = SUPER(XonoticKeyBinder).keyDown(me, key, ascii, shift);
 304                         break;
 305         }
 306         return r;
 307 }
 308 void XonoticKeyBinder_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 309 {
 310         string s;
 311         float j, k, n;
 312         vector theColor;
 313         float theAlpha;
 314         string func, descr;
 315         float extraMargin;
 316
 317         descr = Xonotic_KeyBinds_Descriptions[i];
 318         func = Xonotic_KeyBinds_Functions[i];
 319
 320         if(func == "")
 321         {
 322                 theAlpha = 1;
 323                 theColor = SKINCOLOR_KEYGRABBER_TITLES;
 324                 theAlpha = SKINALPHA_KEYGRABBER_TITLES;
 325                 extraMargin = 0;
 326         }
 327         else
 328         {
 329                 if(isSelected)
 330                 {
 331                         if(keyGrabber == me)
 332                                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_WAITING, SKINALPHA_LISTBOX_WAITING);
 333                         else
 334                                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 335                 }
 336                 theAlpha = SKINALPHA_KEYGRABBER_KEYS;
 337                 theColor = SKINCOLOR_KEYGRABBER_KEYS;
 338                 extraMargin = me.realFontSize_x * 0.5;
 339         }
 340
 341         if(substring(descr, 0, 1) == "$")
 342         {
 343                 s = substring(descr, 1, strlen(descr) - 1);
 344                 descr = cvar_string(strcat(s, "_description"));
 345                 if(descr == "")
 346                         descr = s;
 347                 if(cvar_string(strcat(s, "_press")) == "")
 348                         if(cvar_string(strcat(s, "_release")) == "")
 349                                 theAlpha *= SKINALPHA_DISABLED;
 350         }
 351
 352         s = draw_TextShortenToWidth(descr, me.columnFunctionSize, 0, me.realFontSize);
 353         draw_Text(me.realUpperMargin * eY + extraMargin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 354         if(func != "")
 355         {
 356                 n = tokenize(findkeysforcommand(func, 0)); // uses '...' strings
 357                 s = "";
 358                 for(j = 0; j < n; ++j)
 359                 {
 360                         k = stof(argv(j));
 361                         if(k != -1)
 362                         {
 363                                 if(s != "")
 364                                         s = strcat(s, ", ");
 365                                 s = strcat(s, keynumtostring(k));
 366                         }
 367                 }
 368                 s = draw_TextShortenToWidth(s, me.columnKeysSize, 0, me.realFontSize);
 369                 draw_CenterText(me.realUpperMargin * eY + (me.columnKeysOrigin + 0.5 * me.columnKeysSize) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 370         }
 371 }
 372 #endif