qcsrc/menu/xonotic/keybinder.qc

   1 #include "keybinder.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 .int flags;
   5
   6 #include "button.qh"
   7 #include "dialog_settings_input_userbind.qh"
   8
   9 const string KEY_NOT_BOUND_CMD = "// not bound";
  10
  11 const int MAX_KEYS_PER_FUNCTION = 2;
  12 const int MAX_KEYBINDS = 256;
  13 string Xonotic_KeyBinds_Functions[MAX_KEYBINDS];
  14 string Xonotic_KeyBinds_Descriptions[MAX_KEYBINDS];
  15 int Xonotic_KeyBinds_Count = -1;
  16
  17 void Xonotic_KeyBinds_Read()
  18 {
  19         Xonotic_KeyBinds_Count = 0;
  20
  21         #define KEYBIND_DEF(func, desc) MACRO_BEGIN { \
  22                 if((Xonotic_KeyBinds_Count < MAX_KEYBINDS)) { \
  23                         Xonotic_KeyBinds_Functions[Xonotic_KeyBinds_Count] = strzone(func); \
  24                         Xonotic_KeyBinds_Descriptions[Xonotic_KeyBinds_Count] = strzone(desc); \
  25                         ++Xonotic_KeyBinds_Count; \
  26                 } \
  27         } MACRO_END
  28
  29         KEYBIND_DEF(""                                      , _("Moving"));
  30         KEYBIND_DEF("+forward"                              , _("forward"));
  31         KEYBIND_DEF("+back"                                 , _("backpedal"));
  32         KEYBIND_DEF("+moveleft"                             , _("strafe left"));
  33         KEYBIND_DEF("+moveright"                            , _("strafe right"));
  34         KEYBIND_DEF("+jump"                                 , _("jump / swim"));
  35         KEYBIND_DEF("+crouch"                               , _("crouch / sink"));
  36         KEYBIND_DEF("+hook"                                 , _("off-hand hook"));
  37         KEYBIND_DEF("+jetpack"                              , _("jet pack"));
  38         KEYBIND_DEF(""                                      , "");
  39         KEYBIND_DEF(""                                      , _("Attacking"));
  40         KEYBIND_DEF("+fire"                                 , _("primary fire"));
  41         KEYBIND_DEF("+fire2"                                , _("secondary fire"));
  42         KEYBIND_DEF(""                                      , "");
  43         KEYBIND_DEF(""                                      , _("Weapons"));
  44         KEYBIND_DEF("weapprev"                              , CTX(_("WEAPON^previous")));
  45         KEYBIND_DEF("weapnext"                              , CTX(_("WEAPON^next")));
  46         KEYBIND_DEF("weaplast"                              , CTX(_("WEAPON^previously used")));
  47         KEYBIND_DEF("weapbest"                              , CTX(_("WEAPON^best")));
  48         KEYBIND_DEF("reload"                                , _("reload"));
  49         KEYBIND_DEF("dropweapon"                            , _("drop weapon / throw nade"));
  50
  51         int i;
  52
  53         #define ADD_TO_W_LIST(pred) \
  54                 FOREACH(Weapons, it != WEP_Null, { \
  55                         if (it.impulse != imp) continue; \
  56                         if (!(pred)) continue; \
  57                         w_list = strcat(w_list, it.m_name, " / "); \
  58                 })
  59
  60         for(int imp = 1; imp <= 9; ++imp)
  61         {
  62         string w_list = "";
  63                 ADD_TO_W_LIST(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED) && !(it.spawnflags & WEP_FLAG_HIDDEN) && !(it.spawnflags & WEP_FLAG_SUPERWEAPON));
  64                 ADD_TO_W_LIST((it.spawnflags & WEP_FLAG_SUPERWEAPON) && !(it.spawnflags & WEP_FLAG_HIDDEN));
  65                 ADD_TO_W_LIST((it.spawnflags & WEP_FLAG_MUTATORBLOCKED) && !(it.spawnflags & WEP_FLAG_HIDDEN));
  66                 if(w_list)
  67                         KEYBIND_DEF(strcat("weapon_group_", itos(imp)), substring(w_list, 0, -4));
  68                 if(imp == 0)
  69                         break;
  70                 if(imp == 9)
  71                         imp = -1;
  72         }
  73         #undef ADD_TO_W_LIST
  74
  75         KEYBIND_DEF(""                                      , "");
  76         KEYBIND_DEF(""                                      , _("View"));
  77         KEYBIND_DEF("+zoom"                                 , _("hold zoom"));
  78         KEYBIND_DEF("togglezoom"                            , _("toggle zoom"));
  79         KEYBIND_DEF("+showscores"                           , _("show scores"));
  80         KEYBIND_DEF("screenshot"                            , _("screen shot"));
  81         KEYBIND_DEF("+hud_panel_radar_maximized"            , _("maximize radar"));
  82         KEYBIND_DEF("toggle chase_active"                   , _("3rd person view"));
  83         KEYBIND_DEF("spec"                                  , _("enter spectator mode"));
  84         KEYBIND_DEF(""                                      , "");
  85         KEYBIND_DEF(""                                      , _("Communicate"));
  86         KEYBIND_DEF("messagemode"                           , _("public chat"));
  87         KEYBIND_DEF("messagemode2"                          , _("team chat"));
  88         KEYBIND_DEF("+con_chat_maximize"                    , _("show chat history"));
  89         KEYBIND_DEF("vyes"                                  , _("vote YES"));
  90         KEYBIND_DEF("vno"                                   , _("vote NO"));
  91         KEYBIND_DEF("ready"                                 , _("ready"));
  92         KEYBIND_DEF(""                                      , "");
  93         KEYBIND_DEF(""                                      , _("Client"));
  94         KEYBIND_DEF("+show_info"                            , _("server info"));
  95         KEYBIND_DEF("toggleconsole"                         , _("enter console"));
  96         KEYBIND_DEF("disconnect"                            , _("disconnect"));
  97         KEYBIND_DEF("menu_showquitdialog"                   , _("quit"));
  98         KEYBIND_DEF(""                                      , "");
  99         KEYBIND_DEF(""                                      , _("Teamplay"));
 100         KEYBIND_DEF("messagemode2"                          , _("team chat"));
 101         KEYBIND_DEF("team_auto"                             , _("auto-join team"));
 102         KEYBIND_DEF("menu_showteamselect"                   , _("team menu"));
 103         KEYBIND_DEF("+use"                                  , _("drop key / drop flag"));
 104         KEYBIND_DEF(""                                      , "");
 105         KEYBIND_DEF(""                                      , _("Misc"));
 106         KEYBIND_DEF("quickmenu"                             , _("quick menu"));
 107         KEYBIND_DEF("menu_showsandboxtools"                 , _("sandbox menu"));
 108         KEYBIND_DEF("+button8"                              , _("drag object"));
 109         KEYBIND_DEF(""                                      , "");
 110         KEYBIND_DEF(""                                      , _("User defined"));
 111
 112         for(i = 1; i <= 32; ++i)
 113                 KEYBIND_DEF(strcat("+userbind ", itos(i)), strcat("$userbind", itos(i)));
 114
 115         #undef KEYBIND_DEF
 116 }
 117
 118 entity makeXonoticKeyBinder()
 119 {
 120         entity me;
 121         me = NEW(XonoticKeyBinder);
 122         me.configureXonoticKeyBinder(me);
 123         return me;
 124 }
 125 void replace_bind(string from, string to)
 126 {
 127         int n, j;
 128         float k; // not sure if float or int
 129         n = tokenize(findkeysforcommand(from, 0)); // uses '...' strings
 130         for(j = 0; j < n; ++j)
 131         {
 132                 k = stof(argv(j));
 133                 if(k != -1)
 134                         localcmd("\nbind \"", keynumtostring(k), "\" \"", to, "\"\n");
 135         }
 136         if(n)
 137                 cvar_set("_hud_showbinds_reload", "1");
 138 }
 139 void XonoticKeyBinder_configureXonoticKeyBinder(entity me)
 140 {
 141         me.configureXonoticListBox(me);
 142         me.nItems = 0;
 143
 144         // TEMP: Xonotic 0.1 to later
 145         replace_bind("impulse 1", "weapon_group_1");
 146         replace_bind("impulse 2", "weapon_group_2");
 147         replace_bind("impulse 3", "weapon_group_3");
 148         replace_bind("impulse 4", "weapon_group_4");
 149         replace_bind("impulse 5", "weapon_group_5");
 150         replace_bind("impulse 6", "weapon_group_6");
 151         replace_bind("impulse 7", "weapon_group_7");
 152         replace_bind("impulse 8", "weapon_group_8");
 153         replace_bind("impulse 9", "weapon_group_9");
 154         replace_bind("impulse 14", "weapon_group_0");
 155 }
 156 void XonoticKeyBinder_loadKeyBinds(entity me)
 157 {
 158         bool force_initial_selection = false;
 159         if(Xonotic_KeyBinds_Count < 0) // me.handle not loaded yet?
 160                 force_initial_selection = true;
 161         Xonotic_KeyBinds_Read();
 162         me.nItems = Xonotic_KeyBinds_Count;
 163         if(force_initial_selection)
 164                 me.setSelected(me, 0);
 165 }
 166 void XonoticKeyBinder_showNotify(entity me)
 167 {
 168         me.destroy(me);
 169         me.loadKeyBinds(me);
 170 }
 171 void XonoticKeyBinder_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 172 {
 173         SUPER(XonoticKeyBinder).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 174
 175         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 176         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 177         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 178
 179         me.columnFunctionOrigin = 0;
 180         me.columnKeysSize = me.realFontSize.x * 12;
 181         me.columnFunctionSize = 1 - me.columnKeysSize - 2 * me.realFontSize.x;
 182         me.columnKeysOrigin = me.columnFunctionOrigin + me.columnFunctionSize + me.realFontSize.x;
 183 }
 184 void KeyBinder_Bind_Change(entity btn, entity me)
 185 {
 186         string func;
 187
 188         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 189         if(func == "")
 190                 return;
 191
 192         me.keyGrabButton.forcePressed = 1;
 193         me.clearButton.disabled = 1;
 194         keyGrabber = me;
 195 }
 196 void XonoticKeyBinder_keyGrabbed(entity me, int key, bool ascii)
 197 {
 198         int n, j, nvalid;
 199         float k;
 200         string func;
 201
 202         me.keyGrabButton.forcePressed = 0;
 203         me.clearButton.disabled = 0;
 204
 205         if(key == K_ESCAPE)
 206                 return;
 207
 208         // forbid these keys from being bound in the menu
 209         if(key == K_CAPSLOCK || key == K_NUMLOCK)
 210         {
 211                 KeyBinder_Bind_Change(me, me);
 212                 return;
 213         }
 214
 215         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 216         if(func == "")
 217                 return;
 218
 219         n = tokenize(findkeysforcommand(func, 0)); // uses '...' strings
 220         nvalid = 0;
 221         for(j = 0; j < n; ++j)
 222         {
 223                 k = stof(argv(j));
 224                 if(k != -1)
 225                         ++nvalid;
 226         }
 227         if(nvalid >= MAX_KEYS_PER_FUNCTION)
 228         {
 229                 for(j = 0; j < n; ++j)
 230                 {
 231                         k = stof(argv(j));
 232                         if(k != -1)
 233                                 //localcmd("\nunbind \"", keynumtostring(k), "\"\n");
 234                                 localcmd("\nbind \"", keynumtostring(k), "\" \"", KEY_NOT_BOUND_CMD, "\"\n");
 235                 }
 236         }
 237         m_play_click_sound(MENU_SOUND_SELECT);
 238         localcmd("\nbind \"", keynumtostring(key), "\" \"", func, "\"\n");
 239         localcmd("-zoom\n"); // to make sure we aren't in togglezoom'd state
 240         cvar_set("_hud_showbinds_reload", "1");
 241 }
 242 void XonoticKeyBinder_destroy(entity me)
 243 {
 244         if(Xonotic_KeyBinds_Count < 0)
 245                 return;
 246
 247         for(int i = 0; i < MAX_KEYBINDS; ++i)
 248         {
 249                 strfree(Xonotic_KeyBinds_Functions[i]);
 250                 strfree(Xonotic_KeyBinds_Descriptions[i]);
 251         }
 252         Xonotic_KeyBinds_Count = 0;
 253 }
 254 void XonoticKeyBinder_editUserbind(entity me, string theName, string theCommandPress, string theCommandRelease)
 255 {
 256         string func, descr;
 257
 258         if(!me.userbindEditDialog)
 259                 return;
 260
 261         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 262         if(func == "")
 263                 return;
 264
 265         descr = Xonotic_KeyBinds_Descriptions[me.selectedItem];
 266         if(substring(descr, 0, 1) != "$")
 267                 return;
 268         descr = substring(descr, 1, strlen(descr) - 1);
 269
 270         // Hooray! It IS a user bind!
 271         cvar_set(strcat(descr, "_description"), theName);
 272         cvar_set(strcat(descr, "_press"), theCommandPress);
 273         cvar_set(strcat(descr, "_release"), theCommandRelease);
 274 }
 275 void KeyBinder_Bind_Edit(entity btn, entity me)
 276 {
 277         string func, descr;
 278
 279         if(!me.userbindEditDialog)
 280                 return;
 281
 282         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 283         if(func == "")
 284                 return;
 285
 286         descr = Xonotic_KeyBinds_Descriptions[me.selectedItem];
 287         if(substring(descr, 0, 1) != "$")
 288                 return;
 289         descr = substring(descr, 1, strlen(descr) - 1);
 290
 291         // Hooray! It IS a user bind!
 292         me.userbindEditDialog.loadUserBind(me.userbindEditDialog, cvar_string(strcat(descr, "_description")), cvar_string(strcat(descr, "_press")), cvar_string(strcat(descr, "_release")));
 293
 294         DialogOpenButton_Click(btn, me.userbindEditDialog);
 295 }
 296 void KeyBinder_Bind_Clear(entity btn, entity me)
 297 {
 298         float n, j, k;
 299         string func;
 300
 301         func = Xonotic_KeyBinds_Functions[me.selectedItem];
 302         if(func == "")
 303                 return;
 304
 305         n = tokenize(findkeysforcommand(func, 0)); // uses '...' strings
 306         for(j = 0; j < n; ++j)
 307         {
 308                 k = stof(argv(j));
 309                 if(k != -1)
 310                         //localcmd("\nunbind \"", keynumtostring(k), "\"\n");
 311                         localcmd("\nbind \"", keynumtostring(k), "\" \"", KEY_NOT_BOUND_CMD, "\"\n");
 312         }
 313         m_play_click_sound(MENU_SOUND_CLEAR);
 314         localcmd("-zoom\n"); // to make sure we aren't in togglezoom'd state
 315         cvar_set("_hud_showbinds_reload", "1");
 316 }
 317 void KeyBinder_Bind_Reset_All(entity btn, entity me)
 318 {
 319         localcmd("unbindall\n");
 320         localcmd("exec binds-xonotic.cfg\n");
 321         localcmd("-zoom\n"); // to make sure we aren't in togglezoom'd state
 322         cvar_set("_hud_showbinds_reload", "1");
 323 }
 324 void XonoticKeyBinder_doubleClickListBoxItem(entity me, float i, vector where)
 325 {
 326         KeyBinder_Bind_Change(NULL, me);
 327 }
 328 void XonoticKeyBinder_setSelected(entity me, int i)
 329 {
 330         // handling of "unselectable" items
 331         i = floor(0.5 + bound(0, i, me.nItems - 1));
 332         if(me.pressed == 0 || me.pressed == 1) // keyboard or scrolling - skip unselectable items
 333         {
 334                 if(i > me.previouslySelected)
 335                 {
 336                         while((i < me.nItems - 1) && (Xonotic_KeyBinds_Functions[i] == ""))
 337                                 ++i;
 338                 }
 339                 while((i > 0) && (Xonotic_KeyBinds_Functions[i] == ""))
 340                         --i;
 341                 while((i < me.nItems - 1) && (Xonotic_KeyBinds_Functions[i] == ""))
 342                         ++i;
 343         }
 344         if(me.pressed == 3) // released the mouse - fall back to last valid item
 345         {
 346                 if(Xonotic_KeyBinds_Functions[i] == "")
 347                         i = me.previouslySelected;
 348         }
 349         if(Xonotic_KeyBinds_Functions[i] != "")
 350                 me.previouslySelected = i;
 351         if(me.userbindEditButton)
 352                 me.userbindEditButton.disabled = (substring(Xonotic_KeyBinds_Descriptions[i], 0, 1) != "$");
 353         SUPER(XonoticKeyBinder).setSelected(me, i);
 354 }
 355 float XonoticKeyBinder_keyDown(entity me, int key, bool ascii, float shift)
 356 {
 357         bool r = true;
 358         switch(key)
 359         {
 360                 case K_ENTER:
 361                 case K_KP_ENTER:
 362                 case K_SPACE:
 363                         KeyBinder_Bind_Change(me, me);
 364                         break;
 365                 case K_DEL:
 366                 case K_KP_DEL:
 367                 case K_BACKSPACE:
 368                         KeyBinder_Bind_Clear(me, me);
 369                         break;
 370                 default:
 371                         r = SUPER(XonoticKeyBinder).keyDown(me, key, ascii, shift);
 372                         break;
 373         }
 374         return r;
 375 }
 376 void XonoticKeyBinder_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 377 {
 378         string s;
 379         int j, n;
 380         float k;
 381         vector theColor;
 382         float theAlpha;
 383         string func, descr;
 384         float extraMargin;
 385
 386         descr = Xonotic_KeyBinds_Descriptions[i];
 387         func = Xonotic_KeyBinds_Functions[i];
 388
 389         if(func == "")
 390         {
 391                 theAlpha = 1;
 392                 theColor = SKINCOLOR_KEYGRABBER_TITLES;
 393                 theAlpha = SKINALPHA_KEYGRABBER_TITLES;
 394                 extraMargin = 0;
 395         }
 396         else
 397         {
 398                 if(isSelected)
 399                 {
 400                         if(keyGrabber == me)
 401                                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_WAITING, SKINALPHA_LISTBOX_WAITING);
 402                         else
 403                                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 404                 }
 405                 else if(isFocused)
 406                 {
 407                         me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 408                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 409                 }
 410
 411                 theAlpha = SKINALPHA_KEYGRABBER_KEYS;
 412                 theColor = SKINCOLOR_KEYGRABBER_KEYS;
 413                 extraMargin = me.realFontSize.x * 0.5;
 414         }
 415
 416         if(substring(descr, 0, 1) == "$")
 417         {
 418                 s = substring(descr, 1, strlen(descr) - 1);
 419                 descr = cvar_string(strcat(s, "_description"));
 420                 if(descr == "")
 421                         descr = s;
 422                 if(cvar_string(strcat(s, "_press")) == "")
 423                         if(cvar_string(strcat(s, "_release")) == "")
 424                                 theAlpha *= SKINALPHA_DISABLED;
 425         }
 426
 427         s = draw_TextShortenToWidth(descr, me.columnFunctionSize, 0, me.realFontSize);
 428         draw_Text(me.realUpperMargin * eY + extraMargin * eX, s, me.realFontSize, theColor, theAlpha, 0);
 429         if(func != "")
 430         {
 431                 n = tokenize(findkeysforcommand(func, 0)); // uses '...' strings
 432                 s = "";
 433                 for(j = 0; j < n; ++j)
 434                 {
 435                         k = stof(argv(j));
 436                         if(k != -1)
 437                         {
 438                                 if(s != "")
 439                                         s = strcat(s, ", ");
 440                                 s = strcat(s, keynumtostring(k));
 441                         }
 442                 }
 443                 s = draw_TextShortenToWidth(s, me.columnKeysSize, 0, me.realFontSize);
 444                 draw_CenterText(me.realUpperMargin * eY + (me.columnKeysOrigin + 0.5 * me.columnKeysSize) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 445         }
 446 }