qcsrc/menu/xonotic/languagelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
   4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
   8         METHOD(XonoticLanguageList, loadCvars, void(entity))
   9         METHOD(XonoticLanguageList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  15
  16         METHOD(XonoticLanguageList, clickListBoxItem, void(entity, float, vector)) // double click handling
  17         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
  18         ATTRIB(XonoticLanguageList, lastClickedLanguage, float, -1)
  19         ATTRIB(XonoticLanguageList, lastClickedTime, float, 0)
  20
  21         METHOD(XonoticLanguageList, destroy, void(entity))
  22
  23         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  24         METHOD(XonoticLanguageList, getLanguages, void(entity))
  25         METHOD(XonoticLanguageList, setLanguage, void(entity))
  26         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
  27
  28         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  29 ENDCLASS(XonoticLanguageList)
  30
  31 entity makeXonoticLanguageList();
  32 void SetLanguage_Click(entity btn, entity me);
  33 #endif
  34
  35 #ifdef IMPLEMENTATION
  36
  37 #define LANGPARM_ID 0
  38 #define LANGPARM_NAME 1
  39 #define LANGPARM_NAME_LOCALIZED 2
  40 #define LANGPARM_COUNT 3
  41
  42 entity makeXonoticLanguageList()
  43 {
  44         entity me;
  45         me = spawnXonoticLanguageList();
  46         me.configureXonoticLanguageList(me);
  47         return me;
  48 }
  49
  50 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  51 {
  52         me.configureXonoticListBox(me);
  53         me.getLanguages(me);
  54         me.loadCvars(me);
  55 }
  56
  57 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  58 {
  59         string s;
  60         if(isSelected)
  61                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  62         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  63         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  64 }
  65
  66 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  67 {
  68         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  69         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
  70         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
  71         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  72         me.columnNameOrigin = 0;
  73         me.columnNameSize = 1;
  74 }
  75
  76 void XonoticLanguageList_setSelected(entity me, float i)
  77 {
  78         SUPER(XonoticLanguageList).setSelected(me, i);
  79         me.saveCvars(me);
  80 }
  81
  82 void XonoticLanguageList_loadCvars(entity me)
  83 {
  84         string s;
  85         float i, n;
  86         s = cvar_string("_menu_prvm_language");
  87         n = me.nItems;
  88
  89         // default to English
  90         for(i = 0; i < n; ++i)
  91         {
  92                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
  93                 {
  94                         me.selectedItem = i;
  95                         break;
  96                 }
  97         }
  98
  99         // otherwise, find the language
 100         for(i = 0; i < n; ++i)
 101         {
 102                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 103                 {
 104                         me.selectedItem = i;
 105                         break;
 106                 }
 107         }
 108
 109         // save it off (turning anything unknown into "en")
 110         me.saveCvars(me);
 111 }
 112
 113 void XonoticLanguageList_saveCvars(entity me)
 114 {
 115         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 116 }
 117
 118 void XonoticLanguageList_clickListBoxItem(entity me, float i, vector where)
 119 {
 120         if(i == me.lastClickedLanguage)
 121                 if(time < me.lastClickedTime + 0.3)
 122                 {
 123                         // DOUBLE CLICK!
 124                         me.setSelected(me, i);
 125                         me.setLanguage(me);
 126                 }
 127         me.lastClickedLanguage = i;
 128         me.lastClickedTime = time;
 129 }
 130
 131 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 132 {
 133         if(scan == K_ENTER || scan == K_KP_ENTER) {
 134                 me.setLanguage(me);
 135                 return 1;
 136         }
 137         else
 138                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 139 }
 140
 141 void XonoticLanguageList_destroy(entity me)
 142 {
 143         buf_del(me.languagelist);
 144 }
 145
 146 void XonoticLanguageList_getLanguages(entity me)
 147 {
 148         float buf, i, n, fh;
 149         string s;
 150
 151         buf = buf_create();
 152
 153         fh = fopen("languages.txt", FILE_READ);
 154         i = 0;
 155         while((s = fgets(fh)))
 156         {
 157                 n = tokenize_console(s);
 158                 if(n < 3)
 159                         continue;
 160                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 161                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 162                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, argv(2));
 163                 ++i;
 164         }
 165         fclose(fh);
 166
 167         me.languagelist = buf;
 168         me.nItems = i;
 169 }
 170
 171 void XonoticLanguageList_setLanguage(entity me)
 172 {
 173         if(prvm_language != cvar_string("_menu_prvm_language"))
 174         {
 175                 if(!(gamestatus & GAME_CONNECTED))
 176                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 177                 else
 178                         DialogOpenButton_Click(me, main.languageWarningDialog);
 179         }
 180 }
 181
 182 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 183 {
 184         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 185 }
 186
 187 void SetLanguage_Click(entity btn, entity me)
 188 {
 189         me.setLanguage(me);
 190 }
 191
 192 #endif