97bbfed46ba7d2ef08708ccb2b0a47246f12950d
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / languagelist.c
1 #ifdef INTERFACE
2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
8         METHOD(XonoticLanguageList, loadCvars, void(entity))
9         METHOD(XonoticLanguageList, saveCvars, void(entity))
10
11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
15
16         METHOD(XonoticLanguageList, clickListBoxItem, void(entity, float, vector)) // double click handling
17         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
18         ATTRIB(XonoticLanguageList, lastClickedLanguage, float, -1)
19         ATTRIB(XonoticLanguageList, lastClickedTime, float, 0)
20
21         METHOD(XonoticLanguageList, destroy, void(entity))
22
23         ATTRIB(XonoticLanguageList, languagelist, float, -1)
24         METHOD(XonoticLanguageList, getLanguages, void(entity))
25         METHOD(XonoticLanguageList, setLanguage, void(entity))
26         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
27
28         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
29         ATTRIB(XonoticLanguageList, doubleClickCommand, string, "menu_restart\ntogglemenu\ndefer 0.1 \"menu_cmd languageselect\"")
30 ENDCLASS(XonoticLanguageList)
31
32 entity makeXonoticLanguageList();
33 void SetLanguage_Click(entity btn, entity me);
34 #endif
35
36 #ifdef IMPLEMENTATION
37
38 #define LANGPARM_ID 0
39 #define LANGPARM_NAME 1
40 #define LANGPARM_NAME_LOCALIZED 2
41 #define LANGPARM_COUNT 3
42
43 entity makeXonoticLanguageList()
44 {
45         entity me;
46         me = spawnXonoticLanguageList();
47         me.configureXonoticLanguageList(me);
48         return me;
49 }
50
51 void XonoticLanguageList_configureXonoticLanguageList(entity me)
52 {
53         me.configureXonoticListBox(me);
54         me.getLanguages(me);
55         me.loadCvars(me);
56 }
57
58 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
59 {
60         string s;
61         if(isSelected)
62                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
63         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
64         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
65 }
66
67 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
68 {
69         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
70         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
71         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
72         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
73         me.columnNameOrigin = 0;
74         me.columnNameSize = 1;
75 }
76
77 void XonoticLanguageList_setSelected(entity me, float i)
78 {
79         SUPER(XonoticLanguageList).setSelected(me, i);
80         me.saveCvars(me);
81 }
82
83 void XonoticLanguageList_loadCvars(entity me)
84 {
85         string s;
86         float i, n;
87         s = cvar_string("prvm_language");
88         n = me.nItems;
89
90         // default to English
91         for(i = 0; i < n; ++i)
92         {
93                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
94                 {
95                         me.selectedItem = i;
96                         break;
97                 }
98         }
99
100         // otherwise, find the language
101         for(i = 0; i < n; ++i)
102         {
103                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
104                 {
105                         me.selectedItem = i;
106                         break;
107                 }
108         }
109 }
110
111 void XonoticLanguageList_saveCvars(entity me)
112 {
113         cvar_set("prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
114 }
115
116 void XonoticLanguageList_clickListBoxItem(entity me, float i, vector where)
117 {
118         if(i == me.lastClickedLanguage)
119                 if(time < me.lastClickedTime + 0.3)
120                 {
121                         // DOUBLE CLICK!
122                         me.setSelected(me, i);
123                         me.setLanguage(me);
124                 }
125         me.lastClickedLanguage = i;
126         me.lastClickedTime = time;
127 }
128
129 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
130 {
131         if(scan == K_ENTER || scan == K_KP_ENTER) {
132                 me.setLanguage(me);
133                 return 1;
134         }
135         else
136                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
137 }
138
139 void XonoticLanguageList_destroy(entity me)
140 {
141         buf_del(me.languagelist);
142 }
143
144 void XonoticLanguageList_getLanguages(entity me)
145 {
146         float buf, i, n, fh;
147         string s;
148
149         buf = buf_create();
150
151         fh = fopen("languages.txt", FILE_READ);
152         while((s = fgets(fh)))
153         {
154                 n = tokenize_console(s);
155                 if(n < 3)
156                         continue;
157                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
158                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
159                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, argv(2));
160                 ++i;
161         }
162         fclose(fh);
163
164         me.languagelist = buf;
165         me.nItems = i;
166 }
167
168 void XonoticLanguageList_setLanguage(entity me)
169 {
170         localcmd(sprintf("\n%s\n", me.doubleClickCommand));
171 }
172
173 string XonoticLanguageList_languageParameter(entity me, float i, float key)
174 {
175         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
176 }
177
178 void SetLanguage_Click(entity btn, entity me)
179 {
180         me.setLanguage(me);
181 }
182
183 #endif