qcsrc/menu/xonotic/languagelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
   4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
   8         METHOD(XonoticLanguageList, loadCvars, void(entity))
   9         METHOD(XonoticLanguageList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  15
  16         METHOD(XonoticLanguageList, clickListBoxItem, void(entity, float, vector)) // double click handling
  17         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
  18         ATTRIB(XonoticLanguageList, lastClickedLanguage, float, -1)
  19         ATTRIB(XonoticLanguageList, lastClickedTime, float, 0)
  20
  21         METHOD(XonoticLanguageList, destroy, void(entity))
  22
  23         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  24         METHOD(XonoticLanguageList, getLanguages, void(entity))
  25         METHOD(XonoticLanguageList, setLanguage, void(entity))
  26         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
  27
  28         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  29
  30         ATTRIB(XonoticLanguageList, doubleClickCommand, string, "prvm_language \"$_menu_prvm_language\"\nmenu_restart\nmenu_cmd languageselect")
  31 ENDCLASS(XonoticLanguageList)
  32
  33 entity makeXonoticLanguageList();
  34 void SetLanguage_Click(entity btn, entity me);
  35 #endif
  36
  37 #ifdef IMPLEMENTATION
  38
  39 #define LANGPARM_ID 0
  40 #define LANGPARM_NAME 1
  41 #define LANGPARM_NAME_LOCALIZED 2
  42 #define LANGPARM_COUNT 3
  43
  44 entity makeXonoticLanguageList()
  45 {
  46         entity me;
  47         me = spawnXonoticLanguageList();
  48         me.configureXonoticLanguageList(me);
  49         return me;
  50 }
  51
  52 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  53 {
  54         me.configureXonoticListBox(me);
  55         me.getLanguages(me);
  56         me.loadCvars(me);
  57 }
  58
  59 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  60 {
  61         string s;
  62         if(isSelected)
  63                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  64         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  65         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  66 }
  67
  68 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  69 {
  70         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  71         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
  72         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
  73         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  74         me.columnNameOrigin = 0;
  75         me.columnNameSize = 1;
  76 }
  77
  78 void XonoticLanguageList_setSelected(entity me, float i)
  79 {
  80         SUPER(XonoticLanguageList).setSelected(me, i);
  81         me.saveCvars(me);
  82 }
  83
  84 void XonoticLanguageList_loadCvars(entity me)
  85 {
  86         string s;
  87         float i, n;
  88         s = cvar_string("_menu_prvm_language");
  89         n = me.nItems;
  90
  91         // default to English
  92         for(i = 0; i < n; ++i)
  93         {
  94                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
  95                 {
  96                         me.selectedItem = i;
  97                         break;
  98                 }
  99         }
 100
 101         // otherwise, find the language
 102         for(i = 0; i < n; ++i)
 103         {
 104                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 105                 {
 106                         me.selectedItem = i;
 107                         break;
 108                 }
 109         }
 110
 111         // save it off (turning anything unknown into "en")
 112         me.saveCvars(me);
 113 }
 114
 115 void XonoticLanguageList_saveCvars(entity me)
 116 {
 117         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 118 }
 119
 120 void XonoticLanguageList_clickListBoxItem(entity me, float i, vector where)
 121 {
 122         if(i == me.lastClickedLanguage)
 123                 if(time < me.lastClickedTime + 0.3)
 124                 {
 125                         // DOUBLE CLICK!
 126                         me.setSelected(me, i);
 127                         me.setLanguage(me);
 128                 }
 129         me.lastClickedLanguage = i;
 130         me.lastClickedTime = time;
 131 }
 132
 133 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 134 {
 135         if(scan == K_ENTER || scan == K_KP_ENTER) {
 136                 me.setLanguage(me);
 137                 return 1;
 138         }
 139         else
 140                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 141 }
 142
 143 void XonoticLanguageList_destroy(entity me)
 144 {
 145         buf_del(me.languagelist);
 146 }
 147
 148 void XonoticLanguageList_getLanguages(entity me)
 149 {
 150         float buf, i, n, fh;
 151         string s;
 152
 153         buf = buf_create();
 154
 155         fh = fopen("languages.txt", FILE_READ);
 156         while((s = fgets(fh)))
 157         {
 158                 n = tokenize_console(s);
 159                 if(n < 3)
 160                         continue;
 161                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 162                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 163                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, argv(2));
 164                 ++i;
 165         }
 166         fclose(fh);
 167
 168         me.languagelist = buf;
 169         me.nItems = i;
 170 }
 171
 172 void XonoticLanguageList_setLanguage(entity me)
 173 {
 174         localcmd(sprintf("\n%s\n", me.doubleClickCommand));
 175 }
 176
 177 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 178 {
 179         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 180 }
 181
 182 void SetLanguage_Click(entity btn, entity me)
 183 {
 184         me.setLanguage(me);
 185 }
 186
 187 #endif