qcsrc/menu/xonotic/languagelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
   4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
   8         METHOD(XonoticLanguageList, loadCvars, void(entity))
   9         METHOD(XonoticLanguageList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  15         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
  16         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
  17
  18         METHOD(XonoticLanguageList, clickListBoxItem, void(entity, float, vector)) // double click handling
  19         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
  20         ATTRIB(XonoticLanguageList, lastClickedLanguage, float, -1)
  21         ATTRIB(XonoticLanguageList, lastClickedTime, float, 0)
  22
  23         METHOD(XonoticLanguageList, destroy, void(entity))
  24
  25         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  26         METHOD(XonoticLanguageList, getLanguages, void(entity))
  27         METHOD(XonoticLanguageList, setLanguage, void(entity))
  28         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
  29
  30         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  31
  32         ATTRIB(XonoticLanguageList, doubleClickCommand, string, "prvm_language \"$_menu_prvm_language\"\nmenu_restart\nmenu_cmd languageselect")
  33 ENDCLASS(XonoticLanguageList)
  34
  35 entity makeXonoticLanguageList();
  36 void SetLanguage_Click(entity btn, entity me);
  37 #endif
  38
  39 #ifdef IMPLEMENTATION
  40
  41 #define LANGPARM_ID 0
  42 #define LANGPARM_NAME 1
  43 #define LANGPARM_NAME_LOCALIZED 2
  44 #define LANGPARM_PERCENTAGE 3
  45 #define LANGPARM_COUNT 4
  46
  47 entity makeXonoticLanguageList()
  48 {
  49         entity me;
  50         me = spawnXonoticLanguageList();
  51         me.configureXonoticLanguageList(me);
  52         return me;
  53 }
  54
  55 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  56 {
  57         me.configureXonoticListBox(me);
  58         me.getLanguages(me);
  59         me.loadCvars(me);
  60 }
  61
  62 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  63 {
  64         string s, p;
  65         if(isSelected)
  66                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  67
  68         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  69         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
  70         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  71
  72         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  73         if(p != "")
  74         {
  75                 p = draw_TextShortenToWidth(p, me.columnPercentageSize, 0, me.realFontSize);
  76                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, me.realFontSize))) * eX, p, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
  77         }
  78 }
  79
  80 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  81 {
  82         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  83         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
  84         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
  85         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  86         me.columnPercentageSize = me.realFontSize_x * 3;
  87         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
  88         me.columnNameOrigin = 0;
  89         me.columnNameSize = me.columnPercentageOrigin;
  90 }
  91
  92 void XonoticLanguageList_setSelected(entity me, float i)
  93 {
  94         SUPER(XonoticLanguageList).setSelected(me, i);
  95         me.saveCvars(me);
  96 }
  97
  98 void XonoticLanguageList_loadCvars(entity me)
  99 {
 100         string s;
 101         float i, n;
 102         s = cvar_string("_menu_prvm_language");
 103         n = me.nItems;
 104
 105         // default to English
 106         for(i = 0; i < n; ++i)
 107         {
 108                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
 109                 {
 110                         me.selectedItem = i;
 111                         break;
 112                 }
 113         }
 114
 115         // otherwise, find the language
 116         for(i = 0; i < n; ++i)
 117         {
 118                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 119                 {
 120                         me.selectedItem = i;
 121                         break;
 122                 }
 123         }
 124
 125         // save it off (turning anything unknown into "en")
 126         me.saveCvars(me);
 127 }
 128
 129 void XonoticLanguageList_saveCvars(entity me)
 130 {
 131         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 132 }
 133
 134 void XonoticLanguageList_clickListBoxItem(entity me, float i, vector where)
 135 {
 136         if(i == me.lastClickedLanguage)
 137                 if(time < me.lastClickedTime + 0.3)
 138                 {
 139                         // DOUBLE CLICK!
 140                         me.setSelected(me, i);
 141                         me.setLanguage(me);
 142                 }
 143         me.lastClickedLanguage = i;
 144         me.lastClickedTime = time;
 145 }
 146
 147 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 148 {
 149         if(scan == K_ENTER || scan == K_KP_ENTER) {
 150                 me.setLanguage(me);
 151                 return 1;
 152         }
 153         else
 154                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 155 }
 156
 157 void XonoticLanguageList_destroy(entity me)
 158 {
 159         buf_del(me.languagelist);
 160 }
 161
 162 void XonoticLanguageList_getLanguages(entity me)
 163 {
 164         float buf, i, n, fh;
 165         string s;
 166
 167         buf = buf_create();
 168
 169         fh = fopen("languages.txt", FILE_READ);
 170         i = 0;
 171         while((s = fgets(fh)))
 172         {
 173                 n = tokenize_console(s);
 174                 if(n < 3)
 175                         continue;
 176                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 177                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 178                 float k = strstrofs(argv(2), "(", 0);
 179                 if(k > 0)
 180                 if(substring(argv(2), strlen(argv(2)) - 1, 1) == ")")
 181                 {
 182                         string percent = substring(argv(2), k + 1, -2);
 183                         if(percent != "100%")
 184                                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 185                 }
 186                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, (k < 0) ? argv(2) : substring(argv(2), 0, k - 1));
 187                 ++i;
 188         }
 189         fclose(fh);
 190
 191         me.languagelist = buf;
 192         me.nItems = i;
 193 }
 194
 195 void XonoticLanguageList_setLanguage(entity me)
 196 {
 197         localcmd(sprintf("\n%s\n", me.doubleClickCommand));
 198 }
 199
 200 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 201 {
 202         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 203 }
 204
 205 void SetLanguage_Click(entity btn, entity me)
 206 {
 207         me.setLanguage(me);
 208 }
 209
 210 #endif