9d217fc514e463a5a6566889f287dde15f9c5c53
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / languagelist.qc
1 #ifdef INTERFACE
2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, int, vector, bool, float))
6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
8         METHOD(XonoticLanguageList, loadCvars, void(entity))
9         METHOD(XonoticLanguageList, saveCvars, void(entity))
10
11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
15         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
16         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
17
18         METHOD(XonoticLanguageList, doubleClickListBoxItem, void(entity, float, vector))
19         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
20
21         METHOD(XonoticLanguageList, destroy, void(entity))
22
23         ATTRIB(XonoticLanguageList, languagelist, float, -1)
24         METHOD(XonoticLanguageList, getLanguages, void(entity))
25         METHOD(XonoticLanguageList, setLanguage, void(entity))
26         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
27
28         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
29 ENDCLASS(XonoticLanguageList)
30
31 entity makeXonoticLanguageList();
32 void SetLanguage_Click(entity btn, entity me);
33 #endif
34
35 #ifdef IMPLEMENTATION
36
37 const float LANGPARM_ID = 0;
38 const float LANGPARM_NAME = 1;
39 const float LANGPARM_NAME_LOCALIZED = 2;
40 const float LANGPARM_PERCENTAGE = 3;
41 const float LANGPARM_COUNT = 4;
42
43 entity makeXonoticLanguageList()
44 {
45         entity me;
46         me = spawnXonoticLanguageList();
47         me.configureXonoticLanguageList(me);
48         return me;
49 }
50
51 void XonoticLanguageList_configureXonoticLanguageList(entity me)
52 {
53         me.configureXonoticListBox(me);
54         me.getLanguages(me);
55         me.loadCvars(me);
56 }
57
58 void XonoticLanguageList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, float highlightedTime)
59 {
60         string s, p;
61         if(isSelected)
62                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
63         else if(highlightedTime)
64                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, getHighlightAlpha(SKINALPHA_LISTBOX_SELECTED * 0.1, highlightedTime));
65
66         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
67
68         vector save_fontscale = draw_fontscale;
69         float f = draw_CondensedFontFactor(s, false, me.realFontSize, 1);
70         draw_fontscale.x *= f;
71         vector fs = me.realFontSize;
72         fs.x *= f;
73         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
74         draw_fontscale = save_fontscale;
75
76         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
77         if(p != "")
78         {
79                 vector save_fontscale = draw_fontscale;
80                 float f = draw_CondensedFontFactor(p, false, me.realFontSize, 1);
81                 draw_fontscale.x *= f;
82                 vector fs = me.realFontSize;
83                 fs.x *= f;
84                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, fs))) * eX, p, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
85                 draw_fontscale = save_fontscale;
86         }
87 }
88
89 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
90 {
91         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
92         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
93         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
94         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
95         me.columnPercentageSize = me.realFontSize.x * 3;
96         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
97         me.columnNameOrigin = 0;
98         me.columnNameSize = me.columnPercentageOrigin;
99 }
100
101 void XonoticLanguageList_setSelected(entity me, float i)
102 {
103         SUPER(XonoticLanguageList).setSelected(me, i);
104         me.saveCvars(me);
105 }
106
107 void XonoticLanguageList_loadCvars(entity me)
108 {
109         string s;
110         float i, n;
111         s = cvar_string("_menu_prvm_language");
112         n = me.nItems;
113
114         // default to English
115         for(i = 0; i < n; ++i)
116         {
117                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
118                 {
119                         me.selectedItem = i;
120                         break;
121                 }
122         }
123
124         // otherwise, find the language
125         for(i = 0; i < n; ++i)
126         {
127                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
128                 {
129                         me.selectedItem = i;
130                         break;
131                 }
132         }
133
134         // save it off (turning anything unknown into "en")
135         me.saveCvars(me);
136 }
137
138 void XonoticLanguageList_saveCvars(entity me)
139 {
140         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
141 }
142
143 void XonoticLanguageList_doubleClickListBoxItem(entity me, float i, vector where)
144 {
145         m_play_click_sound(MENU_SOUND_EXECUTE);
146         me.setLanguage(me);
147 }
148
149 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
150 {
151         if(scan == K_ENTER || scan == K_KP_ENTER)
152         {
153                 m_play_click_sound(MENU_SOUND_EXECUTE);
154                 me.setLanguage(me);
155                 return 1;
156         }
157         else
158                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
159 }
160
161 void XonoticLanguageList_destroy(entity me)
162 {
163         buf_del(me.languagelist);
164 }
165
166 void XonoticLanguageList_getLanguages(entity me)
167 {
168         float buf, i, n, fh;
169         string s;
170
171         buf = buf_create();
172
173         fh = fopen("languages.txt", FILE_READ);
174         i = 0;
175         while((s = fgets(fh)))
176         {
177                 n = tokenize_console(s);
178                 if(n < 3)
179                         continue;
180                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
181                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
182                 float k = strstrofs(argv(2), "(", 0);
183                 if(k > 0)
184                 if(substring(argv(2), strlen(argv(2)) - 1, 1) == ")")
185                 {
186                         string percent = substring(argv(2), k + 1, -2);
187                         if(percent != "100%")
188                                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
189                 }
190                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, (k < 0) ? argv(2) : substring(argv(2), 0, k - 1));
191                 ++i;
192         }
193         fclose(fh);
194
195         me.languagelist = buf;
196         me.nItems = i;
197 }
198
199 void XonoticLanguageList_setLanguage(entity me)
200 {
201         if(prvm_language != cvar_string("_menu_prvm_language"))
202         {
203                 if(!(gamestatus & GAME_CONNECTED))
204                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
205                 else
206                         DialogOpenButton_Click(me, main.languageWarningDialog);
207         }
208 }
209
210 string XonoticLanguageList_languageParameter(entity me, float i, float key)
211 {
212         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
213 }
214
215 void SetLanguage_Click(entity btn, entity me)
216 {
217         me.setLanguage(me);
218 }
219
220 #endif