qcsrc/menu/xonotic/languagelist.qc

   1 #ifndef LANGUAGELIST_H
   2 #define LANGUAGELIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticLanguageList, XonoticListBox)
   5         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity));
   6         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   7         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, int, vector, bool, bool));
   8         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector));
   9         METHOD(XonoticLanguageList, setSelected, void(entity, float));
  10         METHOD(XonoticLanguageList, loadCvars, void(entity));
  11         METHOD(XonoticLanguageList, saveCvars, void(entity));
  12
  13         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  14         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  15         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  16         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  17         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
  18         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
  19
  20         METHOD(XonoticLanguageList, doubleClickListBoxItem, void(entity, float, vector));
  21         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)); // enter handling
  22
  23         METHOD(XonoticLanguageList, destroy, void(entity));
  24
  25         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  26         METHOD(XonoticLanguageList, getLanguages, void(entity));
  27         METHOD(XonoticLanguageList, setLanguage, void(entity));
  28         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float));
  29
  30         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  31 ENDCLASS(XonoticLanguageList)
  32
  33 entity makeXonoticLanguageList();
  34 void SetLanguage_Click(entity btn, entity me);
  35 #endif
  36
  37 #ifdef IMPLEMENTATION
  38
  39 const float LANGPARM_ID = 0;
  40 const float LANGPARM_NAME = 1;
  41 const float LANGPARM_NAME_LOCALIZED = 2;
  42 const float LANGPARM_PERCENTAGE = 3;
  43 const float LANGPARM_COUNT = 4;
  44
  45 entity makeXonoticLanguageList()
  46 {
  47         entity me;
  48         me = NEW(XonoticLanguageList);
  49         me.configureXonoticLanguageList(me);
  50         return me;
  51 }
  52
  53 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  54 {
  55         me.configureXonoticListBox(me);
  56         me.getLanguages(me);
  57         me.loadCvars(me);
  58 }
  59
  60 void XonoticLanguageList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
  61 {
  62         string s, p;
  63         if(isSelected)
  64                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  65         else if(isFocused)
  66         {
  67                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
  68                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
  69         }
  70
  71         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  72
  73         vector save_fontscale = draw_fontscale;
  74         float f = draw_CondensedFontFactor(s, false, me.realFontSize, 1);
  75         draw_fontscale.x *= f;
  76         vector fs = me.realFontSize;
  77         fs.x *= f;
  78         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  79         draw_fontscale = save_fontscale;
  80
  81         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  82         if(p != "")
  83         {
  84                 vector save_fontscale = draw_fontscale;
  85                 float f = draw_CondensedFontFactor(p, false, me.realFontSize, 1);
  86                 draw_fontscale.x *= f;
  87                 vector fs = me.realFontSize;
  88                 fs.x *= f;
  89                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, fs))) * eX, p, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  90                 draw_fontscale = save_fontscale;
  91         }
  92 }
  93
  94 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  95 {
  96         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  97         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
  98         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
  99         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 100         me.columnPercentageSize = me.realFontSize.x * 3;
 101         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
 102         me.columnNameOrigin = 0;
 103         me.columnNameSize = me.columnPercentageOrigin;
 104 }
 105
 106 void XonoticLanguageList_setSelected(entity me, float i)
 107 {
 108         SUPER(XonoticLanguageList).setSelected(me, i);
 109         me.saveCvars(me);
 110 }
 111
 112 void XonoticLanguageList_loadCvars(entity me)
 113 {
 114         string s;
 115         float i, n;
 116         s = cvar_string("_menu_prvm_language");
 117         n = me.nItems;
 118
 119         // default to English
 120         for(i = 0; i < n; ++i)
 121         {
 122                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
 123                 {
 124                         SUPER(XonoticLanguageList).setSelected(me, i);
 125                         break;
 126                 }
 127         }
 128
 129         // otherwise, find the language
 130         for(i = 0; i < n; ++i)
 131         {
 132                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 133                 {
 134                         SUPER(XonoticLanguageList).setSelected(me, i);
 135                         break;
 136                 }
 137         }
 138
 139         // save it off (turning anything unknown into "en")
 140         me.saveCvars(me);
 141 }
 142
 143 void XonoticLanguageList_saveCvars(entity me)
 144 {
 145         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 146 }
 147
 148 void XonoticLanguageList_doubleClickListBoxItem(entity me, float i, vector where)
 149 {
 150         m_play_click_sound(MENU_SOUND_EXECUTE);
 151         me.setLanguage(me);
 152 }
 153
 154 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 155 {
 156         if(scan == K_ENTER || scan == K_KP_ENTER)
 157         {
 158                 m_play_click_sound(MENU_SOUND_EXECUTE);
 159                 me.setLanguage(me);
 160                 return 1;
 161         }
 162         else
 163                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 164 }
 165
 166 void XonoticLanguageList_destroy(entity me)
 167 {
 168         buf_del(me.languagelist);
 169 }
 170
 171 void XonoticLanguageList_getLanguages(entity me)
 172 {
 173         float buf, i, n, fh;
 174         string s;
 175
 176         buf = buf_create();
 177
 178         fh = fopen("languages.txt", FILE_READ);
 179         i = 0;
 180         while((s = fgets(fh)))
 181         {
 182                 n = tokenize_console(s);
 183                 if(n < 3)
 184                         continue;
 185                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 186                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 187                 float k = strstrofs(argv(2), "(", 0);
 188                 if(k > 0)
 189                 if(substring(argv(2), strlen(argv(2)) - 1, 1) == ")")
 190                 {
 191                         string percent = substring(argv(2), k + 1, -2);
 192                         if(percent != "100%")
 193                                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 194                 }
 195                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, (k < 0) ? argv(2) : substring(argv(2), 0, k - 1));
 196                 ++i;
 197         }
 198         fclose(fh);
 199
 200         me.languagelist = buf;
 201         me.nItems = i;
 202 }
 203
 204 void XonoticLanguageList_setLanguage(entity me)
 205 {
 206         if(prvm_language != cvar_string("_menu_prvm_language"))
 207         {
 208                 if(!(gamestatus & GAME_CONNECTED))
 209                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 210                 else
 211                         DialogOpenButton_Click(me, main.languageWarningDialog);
 212         }
 213 }
 214
 215 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 216 {
 217         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 218 }
 219
 220 void SetLanguage_Click(entity btn, entity me)
 221 {
 222         me.setLanguage(me);
 223 }
 224
 225 #endif