qcsrc/menu/xonotic/languagelist.qc

   1 #ifdef INTERFACE
   2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
   4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
   8         METHOD(XonoticLanguageList, loadCvars, void(entity))
   9         METHOD(XonoticLanguageList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  15         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
  16         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
  17
  18         METHOD(XonoticLanguageList, doubleClickListBoxItem, void(entity, float, vector))
  19         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
  20
  21         METHOD(XonoticLanguageList, destroy, void(entity))
  22
  23         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  24         METHOD(XonoticLanguageList, getLanguages, void(entity))
  25         METHOD(XonoticLanguageList, setLanguage, void(entity))
  26         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
  27
  28         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  29 ENDCLASS(XonoticLanguageList)
  30
  31 entity makeXonoticLanguageList();
  32 void SetLanguage_Click(entity btn, entity me);
  33 #endif
  34
  35 #ifdef IMPLEMENTATION
  36
  37 const float LANGPARM_ID = 0;
  38 const float LANGPARM_NAME = 1;
  39 const float LANGPARM_NAME_LOCALIZED = 2;
  40 const float LANGPARM_PERCENTAGE = 3;
  41 const float LANGPARM_COUNT = 4;
  42
  43 entity makeXonoticLanguageList()
  44 {
  45         entity me;
  46         me = spawnXonoticLanguageList();
  47         me.configureXonoticLanguageList(me);
  48         return me;
  49 }
  50
  51 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  52 {
  53         me.configureXonoticListBox(me);
  54         me.getLanguages(me);
  55         me.loadCvars(me);
  56 }
  57
  58 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  59 {
  60         string s, p;
  61         if(isSelected)
  62                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  63
  64         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  65
  66         vector save_fontscale = draw_fontscale;
  67         float f = draw_CondensedFontFactor(s, false, me.realFontSize, 1);
  68         draw_fontscale.x *= f;
  69         vector fs = me.realFontSize;
  70         fs.x *= f;
  71         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  72         draw_fontscale = save_fontscale;
  73
  74         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  75         if(p != "")
  76         {
  77                 vector save_fontscale = draw_fontscale;
  78                 float f = draw_CondensedFontFactor(p, false, me.realFontSize, 1);
  79                 draw_fontscale.x *= f;
  80                 vector fs = me.realFontSize;
  81                 fs.x *= f;
  82                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, fs))) * eX, p, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  83                 draw_fontscale = save_fontscale;
  84         }
  85 }
  86
  87 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  88 {
  89         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  90         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
  91         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
  92         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  93         me.columnPercentageSize = me.realFontSize.x * 3;
  94         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
  95         me.columnNameOrigin = 0;
  96         me.columnNameSize = me.columnPercentageOrigin;
  97 }
  98
  99 void XonoticLanguageList_setSelected(entity me, float i)
 100 {
 101         SUPER(XonoticLanguageList).setSelected(me, i);
 102         me.saveCvars(me);
 103 }
 104
 105 void XonoticLanguageList_loadCvars(entity me)
 106 {
 107         string s;
 108         float i, n;
 109         s = cvar_string("_menu_prvm_language");
 110         n = me.nItems;
 111
 112         // default to English
 113         for(i = 0; i < n; ++i)
 114         {
 115                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
 116                 {
 117                         me.selectedItem = i;
 118                         break;
 119                 }
 120         }
 121
 122         // otherwise, find the language
 123         for(i = 0; i < n; ++i)
 124         {
 125                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 126                 {
 127                         me.selectedItem = i;
 128                         break;
 129                 }
 130         }
 131
 132         // save it off (turning anything unknown into "en")
 133         me.saveCvars(me);
 134 }
 135
 136 void XonoticLanguageList_saveCvars(entity me)
 137 {
 138         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 139 }
 140
 141 void XonoticLanguageList_doubleClickListBoxItem(entity me, float i, vector where)
 142 {
 143         m_play_click_sound(MENU_SOUND_EXECUTE);
 144         me.setLanguage(me);
 145 }
 146
 147 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 148 {
 149         if(scan == K_ENTER || scan == K_KP_ENTER)
 150         {
 151                 m_play_click_sound(MENU_SOUND_EXECUTE);
 152                 me.setLanguage(me);
 153                 return 1;
 154         }
 155         else
 156                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 157 }
 158
 159 void XonoticLanguageList_destroy(entity me)
 160 {
 161         buf_del(me.languagelist);
 162 }
 163
 164 void XonoticLanguageList_getLanguages(entity me)
 165 {
 166         float buf, i, n, fh;
 167         string s;
 168
 169         buf = buf_create();
 170
 171         fh = fopen("languages.txt", FILE_READ);
 172         i = 0;
 173         while((s = fgets(fh)))
 174         {
 175                 n = tokenize_console(s);
 176                 if(n < 3)
 177                         continue;
 178                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 179                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 180                 float k = strstrofs(argv(2), "(", 0);
 181                 if(k > 0)
 182                 if(substring(argv(2), strlen(argv(2)) - 1, 1) == ")")
 183                 {
 184                         string percent = substring(argv(2), k + 1, -2);
 185                         if(percent != "100%")
 186                                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 187                 }
 188                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, (k < 0) ? argv(2) : substring(argv(2), 0, k - 1));
 189                 ++i;
 190         }
 191         fclose(fh);
 192
 193         me.languagelist = buf;
 194         me.nItems = i;
 195 }
 196
 197 void XonoticLanguageList_setLanguage(entity me)
 198 {
 199         if(prvm_language != cvar_string("_menu_prvm_language"))
 200         {
 201                 if(!(gamestatus & GAME_CONNECTED))
 202                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 203                 else
 204                         DialogOpenButton_Click(me, main.languageWarningDialog);
 205         }
 206 }
 207
 208 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 209 {
 210         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 211 }
 212
 213 void SetLanguage_Click(entity btn, entity me)
 214 {
 215         me.setLanguage(me);
 216 }
 217
 218 #endif