qcsrc/menu/xonotic/languagelist.qc

   1 #include "languagelist.qh"
   2
   3 #include "../item/modalcontroller.qh"
   4 #include "mainwindow.qh"
   5
   6 const float LANGPARM_ID = 0;
   7 const float LANGPARM_NAME = 1;
   8 const float LANGPARM_NAME_LOCALIZED = 2;
   9 const float LANGPARM_PERCENTAGE = 3;
  10 const float LANGPARM_COUNT = 4;
  11
  12 entity makeXonoticLanguageList()
  13 {
  14         entity me;
  15         me = NEW(XonoticLanguageList);
  16         me.configureXonoticLanguageList(me);
  17         return me;
  18 }
  19
  20 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  21 {
  22         me.configureXonoticListBox(me);
  23         me.getLanguages(me);
  24         me.loadCvars(me);
  25 }
  26
  27 void XonoticLanguageList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
  28 {
  29         string s, p;
  30         if(isSelected)
  31                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  32         else if(isFocused)
  33         {
  34                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
  35                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
  36         }
  37
  38         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  39
  40         vector save_fontscale = draw_fontscale;
  41         float f = draw_CondensedFontFactor(s, false, me.realFontSize, 1);
  42         draw_fontscale.x *= f;
  43         vector fs = me.realFontSize;
  44         fs.x *= f;
  45         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  46         draw_fontscale = save_fontscale;
  47
  48         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  49         if(p != "")
  50         {
  51                 vector save_fontscale = draw_fontscale;
  52                 float f = draw_CondensedFontFactor(p, false, me.realFontSize, 1);
  53                 draw_fontscale.x *= f;
  54                 vector fs = me.realFontSize;
  55                 fs.x *= f;
  56                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, fs))) * eX, p, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  57                 draw_fontscale = save_fontscale;
  58         }
  59 }
  60
  61 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  62 {
  63         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  64         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
  65         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
  66         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  67         me.columnPercentageSize = me.realFontSize.x * 3;
  68         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
  69         me.columnNameOrigin = 0;
  70         me.columnNameSize = me.columnPercentageOrigin;
  71 }
  72
  73 void XonoticLanguageList_setSelected(entity me, float i)
  74 {
  75         SUPER(XonoticLanguageList).setSelected(me, i);
  76         me.saveCvars(me);
  77 }
  78
  79 void XonoticLanguageList_loadCvars(entity me)
  80 {
  81         string s;
  82         float i, n;
  83         s = cvar_string("_menu_prvm_language");
  84         n = me.nItems;
  85
  86         // default to English
  87         for(i = 0; i < n; ++i)
  88         {
  89                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
  90                 {
  91                         SUPER(XonoticLanguageList).setSelected(me, i);
  92                         break;
  93                 }
  94         }
  95
  96         // otherwise, find the language
  97         for(i = 0; i < n; ++i)
  98         {
  99                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 100                 {
 101                         SUPER(XonoticLanguageList).setSelected(me, i);
 102                         break;
 103                 }
 104         }
 105
 106         // save it off (turning anything unknown into "en")
 107         me.saveCvars(me);
 108 }
 109
 110 void XonoticLanguageList_saveCvars(entity me)
 111 {
 112         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 113 }
 114
 115 void XonoticLanguageList_doubleClickListBoxItem(entity me, float i, vector where)
 116 {
 117         m_play_click_sound(MENU_SOUND_EXECUTE);
 118         me.setLanguage(me);
 119 }
 120
 121 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 122 {
 123         if(scan == K_ENTER || scan == K_KP_ENTER)
 124         {
 125                 m_play_click_sound(MENU_SOUND_EXECUTE);
 126                 me.setLanguage(me);
 127                 return 1;
 128         }
 129         else
 130                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 131 }
 132
 133 void XonoticLanguageList_destroy(entity me)
 134 {
 135         buf_del(me.languagelist);
 136 }
 137
 138 void XonoticLanguageList_getLanguages(entity me)
 139 {
 140         float buf, i, n, fh;
 141         string s;
 142
 143         buf = buf_create();
 144
 145         fh = fopen("languages.txt", FILE_READ);
 146         i = 0;
 147         while((s = fgets(fh)))
 148         {
 149                 n = tokenize_console(s);
 150                 if(n < 3)
 151                         continue;
 152                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 153                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 154                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, argv(2));
 155                 string percent = argv(3);
 156                 if(percent && percent != "100%")
 157                         bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 158                 ++i;
 159         }
 160         fclose(fh);
 161
 162         me.languagelist = buf;
 163         me.nItems = i;
 164 }
 165
 166 void XonoticLanguageList_setLanguage(entity me)
 167 {
 168         if(prvm_language != cvar_string("_menu_prvm_language"))
 169         {
 170                 if(!(gamestatus & GAME_CONNECTED))
 171                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 172                 else
 173                         DialogOpenButton_Click(me, main.languageWarningDialog);
 174         }
 175 }
 176
 177 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 178 {
 179         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 180 }
 181
 182 void SetLanguage_Click(entity btn, entity me)
 183 {
 184         me.setLanguage(me);
 185 }