Gametypes: propagate entity references, set limit to 24 due to use of bitflags
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / maplist.qc
1 #include "maplist.qh"
2
3 #include <common/mapinfo.qh>
4 #include "dialog_multiplayer_create_mapinfo.qh"
5 #include "mainwindow.qh"
6 #include "inputbox.qh"
7
8 .bool disabled;
9
10 void XonoticMapList_destroy(entity me)
11 {
12         MapInfo_Shutdown();
13 }
14
15 entity makeXonoticMapList()
16 {
17         entity me;
18         me = NEW(XonoticMapList);
19         me.configureXonoticMapList(me);
20         return me;
21 }
22
23 entity MapList_Set_String_Filter_Box(entity me, entity e)
24 {
25         me.stringFilterBox = e;
26         return e;
27 }
28
29 void XonoticMapList_configureXonoticMapList(entity me)
30 {
31         me.configureXonoticListBox(me);
32         me.refilter(me);
33 }
34
35 void XonoticMapList_loadCvars(entity me)
36 {
37         me.refilter(me);
38 }
39
40
41 float XonoticMapList_g_maplistCacheQuery(entity me, float i)
42 {
43         return stof(substring(me.g_maplistCache, i, 1));
44 }
45 void XonoticMapList_g_maplistCacheToggle(entity me, float i)
46 {
47         string a, b, c, s, bspname;
48         float n;
49         s = me.g_maplistCache;
50         if (!s)
51                 return;
52         b = substring(s, i, 1);
53         if(b == "0")
54                 b = "1";
55         else if(b == "1")
56                 b = "0";
57         else
58                 return; // nothing happens
59         a = substring(s, 0, i);
60         c = substring(s, i+1, strlen(s) - (i+1));
61         strunzone(s);
62         me.g_maplistCache = strzone(strcat(a, b, c));
63         // TODO also update the actual cvar
64         if (!((bspname = MapInfo_BSPName_ByID(i))))
65                 return;
66         if(b == "1")
67                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
68         else
69         {
70                 s = "";
71                 n = tokenize_console(cvar_string("g_maplist"));
72                 for(i = 0; i < n; ++i)
73                         if(argv(i) != bspname)
74                                 s = strcat(s, " ", argv(i));
75                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
76         }
77 }
78
79 void XonoticMapList_draw(entity me)
80 {
81         if(me.startButton)
82                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
83         SUPER(XonoticMapList).draw(me);
84 }
85
86 void XonoticMapList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
87 {
88         me.itemAbsSize = '0 0 0';
89         SUPER(XonoticMapList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
90
91         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
92         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
93         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
94         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
95
96         me.columnPreviewOrigin = 0;
97         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
98         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
99         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
100
101         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
102         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
103 }
104
105 void XonoticMapList_clickListBoxItem(entity me, float i, vector where)
106 {
107         if(where.x <= me.columnPreviewOrigin + me.columnPreviewSize)
108                 if(where.x >= 0)
109                 {
110                         m_play_click_sound(MENU_SOUND_SELECT);
111                         me.g_maplistCacheToggle(me, i);
112                 }
113 }
114
115 void XonoticMapList_doubleClickListBoxItem(entity me, float i, vector where)
116 {
117         if(where.x >= me.columnNameOrigin)
118                 if(where.x <= 1)
119                 {
120                         // pop up map info screen
121                         m_play_click_sound(MENU_SOUND_OPEN);
122                         main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
123                         DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
124                 }
125 }
126
127 void XonoticMapList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
128 {
129         // layout: Ping, Map name, Map name, NP, TP, MP
130         string s;
131         float theAlpha;
132         float included;
133
134         if(!MapInfo_Get_ByID(i))
135                 return;
136
137         included = me.g_maplistCacheQuery(me, i);
138         if(included || isSelected)
139                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
140         else
141                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
142
143         if(isSelected)
144                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
145         else
146         {
147                 if(included)
148                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
149                 if(isFocused)
150                 {
151                         me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
152                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
153                 }
154         }
155
156         if(draw_PictureSize(strcat("/maps/", MapInfo_Map_bspname)) == '0 0 0')
157                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
158         else
159                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
160
161         if(included)
162                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
163         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_titlestring), me.columnNameSize, 0, me.realFontSize);
164         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
165         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_author), me.columnNameSize, 0,  me.realFontSize);
166         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
167
168         MapInfo_ClearTemps();
169 }
170
171 void XonoticMapList_refilter(entity me)
172 {
173         float i, j, n;
174         string s;
175         Gametype gt = MapInfo_CurrentGametype();
176         int f = MapInfo_CurrentFeatures();
177         MapInfo_FilterGametype(gt, f, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
178         if (me.stringFilter)
179                 MapInfo_FilterString(me.stringFilter);
180         me.nItems = MapInfo_count;
181
182         for(i = 0; i < MapInfo_count; ++i)
183                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
184         if(me.g_maplistCache)
185                 strunzone(me.g_maplistCache);
186         s = "0";
187         for(i = 1; i < MapInfo_count; i *= 2)
188                 s = strcat(s, s);
189         n = tokenize_console(cvar_string("g_maplist"));
190         for(i = 0; i < n; ++i)
191         {
192                 j = MapInfo_FindName(argv(i));
193                 if(j >= 0)
194                 {
195                         // double check that the two mapnames are "identical", not just share the same prefix
196                         if (strlen(MapInfo_BSPName_ByID(j)) == strlen(argv(i)))
197                                 s = strcat(
198                                         substring(s, 0, j),
199                                         "1",
200                                         substring(s, j+1, MapInfo_count - (j+1))
201                                 );
202                 }
203         }
204         me.g_maplistCache = strzone(s);
205         if(gt != me.lastGametype || f != me.lastFeatures)
206         {
207                 me.lastGametype = gt;
208                 me.lastFeatures = f;
209                 me.setSelected(me, 0);
210         }
211 }
212
213 void XonoticMapList_refilterCallback(entity me, entity cb)
214 {
215         me.refilter(me);
216 }
217
218 void MapList_StringFilterBox_Change(entity box, entity me)
219 {
220         if(me.stringFilter)
221                 strunzone(me.stringFilter);
222         if(box.text != "")
223                 me.stringFilter = strzone(box.text);
224         else
225                 me.stringFilter = string_null;
226
227         me.refilter(me);
228 }
229
230 void MapList_Add_Shown(entity btn, entity me)
231 {
232         float i, n;
233         n = strlen(me.g_maplistCache);
234         for (i = 0 ; i < n; i++)
235         {
236                 if (!me.g_maplistCacheQuery(me, i))
237                         me.g_maplistCacheToggle(me, i);
238         }
239         me.refilter(me);
240 }
241
242 void MapList_Remove_Shown(entity btn, entity me)
243 {
244         float i, n;
245         n = strlen(me.g_maplistCache);
246         for (i = 0 ; i < n; i++)
247         {
248                 if (me.g_maplistCacheQuery(me, i))
249                         me.g_maplistCacheToggle(me, i);
250         }
251         me.refilter(me);
252 }
253
254 void MapList_Add_All(entity btn, entity me)
255 {
256         float i;
257         string s;
258         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, MapInfo_ForbiddenFlags(), 0); // all
259         s = "";
260         for(i = 0; i < MapInfo_count; ++i)
261                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
262         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
263         me.refilter(me);
264 }
265
266 void MapList_Remove_All(entity btn, entity me)
267 {
268         cvar_set("g_maplist", "");
269         me.refilter(me);
270 }
271
272 void MapList_LoadMap(entity btn, entity me)
273 {
274         string m;
275         float i;
276
277         i = me.selectedItem;
278
279         if(btn.parent.instanceOfXonoticMapInfoDialog)
280         {
281                 i = btn.parent.currentMapIndex;
282                 Dialog_Close(btn, btn.parent);
283         }
284
285         if(i >= me.nItems || i < 0)
286                 return;
287
288         m = MapInfo_BSPName_ByID(i);
289         if (!m)
290         {
291                 LOG_INFO(_("Huh? Can't play this (m is NULL). Refiltering so this won't happen again.\n"));
292                 me.refilter(me);
293                 return;
294         }
295         if(MapInfo_CheckMap(m))
296         {
297                 localcmd("\nmenu_loadmap_prepare\n");
298                 if(cvar("menu_use_default_hostname"))
299                         localcmd("hostname \"", sprintf(_("%s's Xonotic Server"), strdecolorize(cvar_string("_cl_name"))), "\"\n");
300                 MapInfo_LoadMap(m, 1);
301         }
302         else
303         {
304                 LOG_INFO(_("Huh? Can't play this (invalid game type). Refiltering so this won't happen again.\n"));
305                 me.refilter(me);
306                 return;
307         }
308 }
309
310 float XonoticMapList_keyDown(entity me, float scan, float ascii, float shift)
311 {
312         string ch, save;
313         if(me.nItems <= 0)
314                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
315         if(scan == K_MOUSE2 || scan == K_SPACE || scan == K_ENTER || scan == K_KP_ENTER)
316         {
317                 // pop up map info screen
318                 m_play_click_sound(MENU_SOUND_OPEN);
319                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
320                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
321         }
322         else if(scan == K_MOUSE3 || scan == K_INS || scan == K_KP_INS)
323         {
324                 m_play_click_sound(MENU_SOUND_SELECT);
325                 me.g_maplistCacheToggle(me, me.selectedItem);
326         }
327         else if(ascii == 43) // +
328         {
329                 if (!me.g_maplistCacheQuery(me, me.selectedItem))
330                 {
331                         m_play_click_sound(MENU_SOUND_SELECT);
332                         me.g_maplistCacheToggle(me, me.selectedItem);
333                 }
334         }
335         else if(ascii == 45) // -
336         {
337                 if(me.g_maplistCacheQuery(me, me.selectedItem))
338                 {
339                         m_play_click_sound(MENU_SOUND_SELECT);
340                         me.g_maplistCacheToggle(me, me.selectedItem);
341                 }
342         }
343         else if(scan == K_BACKSPACE)
344         {
345                 if(time < me.typeToSearchTime)
346                 {
347                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
348                         if(me.typeToSearchString)
349                                 strunzone(me.typeToSearchString);
350                         me.typeToSearchString = strzone(save);
351                         me.typeToSearchTime = time + 0.5;
352                         if(strlen(me.typeToSearchString))
353                         {
354                                 MapInfo_FindName(me.typeToSearchString);
355                                 if(MapInfo_FindName_firstResult >= 0)
356                                         me.setSelected(me, MapInfo_FindName_firstResult);
357                         }
358                 }
359         }
360         else if(ascii >= 32 && ascii != 127)
361         {
362                 ch = chr(ascii);
363                 if(time > me.typeToSearchTime)
364                         save = ch;
365                 else
366                         save = strcat(me.typeToSearchString, ch);
367                 if(me.typeToSearchString)
368                         strunzone(me.typeToSearchString);
369                 me.typeToSearchString = strzone(save);
370                 me.typeToSearchTime = time + 0.5;
371                 MapInfo_FindName(me.typeToSearchString);
372                 if(MapInfo_FindName_firstResult >= 0)
373                         me.setSelected(me, MapInfo_FindName_firstResult);
374         }
375         else if(shift & S_CTRL && scan == 'f') // ctrl-f (as in "F"ind)
376         {
377                 me.parent.setFocus(me.parent, me.stringFilterBox);
378         }
379         else if(shift & S_CTRL && scan == 'u') // ctrl-u (remove stringFilter line
380         {
381                 me.stringFilterBox.setText(me.stringFilterBox, "");
382                 MapList_StringFilterBox_Change(me.stringFilterBox, me);
383         }
384         else
385                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
386         return 1;
387 }
388
389 float MapList_StringFilterBox_keyDown(entity me, float scan, float ascii, float shift)
390 {
391         // in this section, note that onChangeEntity has the ref to mapListBox
392         // we make use of that, instead of extending a class to add one more attrib
393         switch(scan)
394         {
395                 case K_KP_ENTER:
396                 case K_ENTER:
397                         // move the focus to the mapListBox
398                         me.onChangeEntity.parent.setFocus(me.onChangeEntity.parent, me.onChangeEntity);
399                         return 1;
400                 case K_KP_UPARROW:
401                 case K_UPARROW:
402                 case K_KP_DOWNARROW:
403                 case K_DOWNARROW:
404                         // pass the event to the mapListBox (to scroll up and down)
405                         return me.onChangeEntity.keyDown(me.onChangeEntity, scan, ascii, shift);
406         }
407         return SUPER(XonoticInputBox).keyDown(me, scan, ascii, shift);
408 }