qcsrc/menu/xonotic/playerlist.qc

   1 #ifndef PLAYERLIST_H
   2 #define PLAYERLIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticPlayerList, XonoticListBox)
   5         ATTRIB(XonoticPlayerList, rowsPerItem, float, 1)
   6         METHOD(XonoticPlayerList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticPlayerList, drawListBoxItem, void(entity, float, vector, float))
   8         ATTRIB(XonoticPlayerList, allowFocusSound, float, 0)
   9         ATTRIB(XonoticPlayerList, realFontSize, vector, '0 0 0')
  10         ATTRIB(XonoticPlayerList, columnNameOrigin, float, 0)
  11         ATTRIB(XonoticPlayerList, columnNameSize, float, 0)
  12         ATTRIB(XonoticPlayerList, columnScoreOrigin, float, 0)
  13         ATTRIB(XonoticPlayerList, columnScoreSize, float, 0)
  14         ATTRIB(XonoticPlayerList, realUpperMargin, float, 0)
  15         ATTRIB(XonoticPlayerList, origin, vector, '0 0 0')
  16         ATTRIB(XonoticPlayerList, itemAbsSize, vector, '0 0 0')
  17         METHOD(XonoticPlayerList, setPlayerList, void(entity, string))
  18         METHOD(XonoticPlayerList, getPlayerList, string(entity, float, float))
  19         ATTRIB(XonoticPlayerList, playerList, float, -1)
  20 ENDCLASS(XonoticPlayerList)
  21 entity makeXonoticPlayerList();
  22 #endif
  23
  24 #ifdef IMPLEMENTATION
  25
  26 const float PLAYERPARM_SCORE = 0;
  27 const float PLAYERPARM_PING = 1;
  28 const float PLAYERPARM_TEAM = 2;
  29 const float PLAYERPARM_NAME = 3;
  30 const float PLAYERPARM_COUNT = 4;
  31
  32 entity makeXonoticPlayerList()
  33 {
  34         entity me;
  35         me = NEW(XonoticPlayerList);
  36         me.configureXonoticListBox(me);
  37         return me;
  38 }
  39
  40 void XonoticPlayerList_setPlayerList(entity me, string plist)
  41 {
  42         int buf,i,n;
  43         string s;
  44
  45         buf = buf_create();
  46         me.nItems = tokenizebyseparator(plist, "\n");
  47         for(i = 0; i < me.nItems; ++i)
  48         {
  49                 bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_NAME, argv(i)); // -666 100 "^4Nex ^2Player"
  50         }
  51
  52         for(i = 0; i < me.nItems; ++i)
  53         {
  54                 s = bufstr_get(buf, i * PLAYERPARM_COUNT + PLAYERPARM_NAME);
  55                 n = tokenize_console(s);
  56
  57                 if(n == 4)
  58                 {
  59                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_SCORE, argv(0)); // -666
  60                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_PING,  argv(1)); // 100
  61                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_TEAM,  argv(2)); // 0 for spec, else 1, 2, 3, 4
  62                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_NAME,  argv(3)); // ^4Nex ^2Player
  63                 }
  64                 else
  65                 {
  66                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_SCORE, argv(0)); // -666
  67                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_PING,  argv(1)); // 100
  68                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_TEAM,  "-1");
  69                         bufstr_set(buf, i * PLAYERPARM_COUNT + PLAYERPARM_NAME,  argv(2)); // ^4Nex ^2Player
  70                 }
  71         }
  72         me.playerList = buf;
  73 }
  74
  75 string XonoticPlayerList_getPlayerList(entity me, float i, float key)
  76 {
  77         return bufstr_get(me.playerList, i * PLAYERPARM_COUNT + key);
  78 }
  79
  80 void XonoticPlayerList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  81 {
  82         me.itemAbsSize = '0 0 0';
  83         SUPER(XonoticPlayerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  84
  85         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
  86         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
  87         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  88
  89         // this list does 1 char left and right margin
  90         me.columnScoreSize = 5 * me.realFontSize.x;
  91         me.columnNameSize = 1 - 3 * me.realFontSize.x - me.columnScoreSize;
  92
  93         me.columnNameOrigin = me.realFontSize.x;
  94         me.columnScoreOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
  95 }
  96
  97 void XonoticPlayerList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  98 {
  99         string s;
 100         string score;
 101         float t;
 102         vector rgb;
 103
 104         t = stof(me.getPlayerList(me, i, PLAYERPARM_TEAM));
 105         if(t == 1)
 106                 rgb = colormapPaletteColor(4, 0);
 107         else if(t == 2)
 108                 rgb = colormapPaletteColor(13, 0);
 109         else if(t == 3)
 110                 rgb = colormapPaletteColor(12, 0);
 111         else if(t == 4)
 112                 rgb = colormapPaletteColor(9, 0);
 113         else
 114                 rgb = SKINCOLOR_TEXT;
 115
 116         s = me.getPlayerList(me, i, PLAYERPARM_NAME);
 117         score = me.getPlayerList(me, i, PLAYERPARM_SCORE);
 118
 119         if(substring(score, strlen(score) - 10, 10) == ":spectator")
 120         {
 121                 score = _("spectator");
 122         }
 123         else
 124         {
 125                 if((t = strstrofs(score, ":", 0)) >= 0)
 126                         score = substring(score, 0, t);
 127                 if((t = strstrofs(score, ",", 0)) >= 0)
 128                         score = substring(score, 0, t);
 129
 130                 if(stof(score) == -666)
 131                         score = _("spectator");
 132         }
 133
 134         s = draw_TextShortenToWidth(s, me.columnNameSize, 1, me.realFontSize);
 135         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 1, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', 1, 1);
 136
 137         score = draw_TextShortenToWidth(score, me.columnScoreSize, 0, me.realFontSize);
 138         draw_Text(me.realUpperMargin2 * eY + (me.columnScoreOrigin + 1.00 * (me.columnScoreSize - draw_TextWidth(score, 1, me.realFontSize))) * eX, score, me.realFontSize, rgb, 1, 0);
 139 }
 140
 141 #endif