qcsrc/menu/xonotic/playermodel.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayerModelSelector) EXTENDS(XonoticImage)
   3         METHOD(XonoticPlayerModelSelector, configureXonoticPlayerModelSelector, void(entity))
   4         METHOD(XonoticPlayerModelSelector, loadCvars, void(entity))
   5         METHOD(XonoticPlayerModelSelector, saveCvars, void(entity))
   6         METHOD(XonoticPlayerModelSelector, draw, void(entity))
   7         METHOD(XonoticPlayerModelSelector, resizeNotify, void(entity, vector, vector, vector, vector))
   8         ATTRIB(XonoticPlayerModelSelector, currentModel, string, string_null)
   9         ATTRIB(XonoticPlayerModelSelector, currentSkin, float, 0)
  10         ATTRIB(XonoticPlayerModelSelector, currentModelImage, string, string_null)
  11         ATTRIB(XonoticPlayerModelSelector, currentModelTitle, string, string_null)
  12         ATTRIB(XonoticPlayerModelSelector, currentModelDescription, string, string_null)
  13         METHOD(XonoticPlayerModelSelector, go, void(entity, float))
  14         METHOD(XonoticPlayerModelSelector, destroy, void(entity))
  15         ATTRIB(XonoticPlayerModelSelector, origin, vector, '0 0 0')
  16         ATTRIB(XonoticPlayerModelSelector, size, vector, '0 0 0')
  17         ATTRIB(XonoticPlayerModelSelector, realFontSize, vector, '0 0 0')
  18         ATTRIB(XonoticPlayerModelSelector, fontSize, float, SKINFONTSIZE_NORMAL)
  19         ATTRIB(XonoticPlayerModelSelector, titleFontSize, float, SKINFONTSIZE_TITLE)
  20         ATTRIB(XonoticPlayerModelSelector, bufModels, float, -1)
  21         ATTRIB(XonoticPlayerModelSelector, numModels, float, -1)
  22         ATTRIB(XonoticPlayerModelSelector, idxModels, float, -1)
  23 ENDCLASS(XonoticPlayerModelSelector)
  24 entity makeXonoticPlayerModelSelector();
  25 void PlayerModelSelector_Next_Click(entity btn, entity me);
  26 void PlayerModelSelector_Prev_Click(entity btn, entity me);
  27 #endif
  28
  29 #ifdef IMPLEMENTATION
  30 entity makeXonoticPlayerModelSelector()
  31 {
  32         entity me;
  33         me = spawnXonoticPlayerModelSelector();
  34         me.configureXonoticPlayerModelSelector(me);
  35         return me;
  36 }
  37
  38 #define BUFMODELS_TITLE 0
  39 #define BUFMODELS_IMAGE 1
  40 #define BUFMODELS_MODEL 2
  41 #define BUFMODELS_SKIN 3
  42 #define BUFMODELS_DESC 4
  43 #define BUFMODELS_COUNT 5
  44
  45 void configureXonoticPlayerModelSelectorXonoticPlayerModelSelector(entity me)
  46 {
  47         float sortbuf, glob, i;
  48         string fn;
  49
  50         me.configureXonoticImage(me, string_null, -1);
  51
  52         sortbuf = buf_create();
  53         glob = search_begin(get_model_datafilename(string_null, -1, "txt"), TRUE, TRUE);
  54         for(i = 0; i < search_getsize(glob); ++i)
  55         {
  56                 // select model #i!
  57                 fn = search_getfilename(glob, i);
  58                 if(!get_model_parameters(fn, -1))
  59                         continue;
  60                 bufstr_add(sortbuf, sprintf("%-128s%s", get_model_parameters_name, fn), 1);
  61         }
  62         search_end(glob);
  63         buf_sort(sortbuf, 128, 0);
  64         me.numModels = buf_getsize(sortbuf);
  65         me.bufModels = buf_create();
  66         for(i = 0; i < me.numModels; ++i)
  67         {
  68                 fn = substring(bufstr_get(sortbuf, i), 128, -1);
  69                 if(!get_model_parameters(fn, -1))
  70                         error("But it JUST worked!");
  71                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_TITLE, get_model_parameters_name);
  72                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_IMAGE, strcat("/", substring(get_model_datafilename(get_model_parameters_modelname, get_model_parameters_modelskin, "tga"), 0, -5)));
  73                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_MODEL, get_model_parameters_modelname);
  74                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_SKIN, ftos(get_model_parameters_modelskin));
  75                 get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
  76                 if(get_model_parameters_sex)
  77                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\nSex: ", get_model_parameters_sex);
  78                 if(get_model_parameters_weight)
  79                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\nWeight: ", ftos(get_model_parameters_weight), " kg");
  80                 if(get_model_parameters_age)
  81                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\nAge: ", ftos(get_model_parameters_age));
  82                 while(substring(get_model_parameters_desc, -1, 1) == "\n")
  83                         get_model_parameters_desc = substring(get_model_parameters_desc, 0, -2);
  84                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_DESC, get_model_parameters_desc);
  85         }
  86         buf_del(sortbuf);
  87         get_model_parameters(string_null, 0);
  88         me.loadCvars(me);
  89 }
  90 void destroyXonoticPlayerModelSelector(entity me)
  91 {
  92         buf_del(me.bufModels);
  93         me.bufModels = -1;
  94 }
  95
  96 void loadCvarsXonoticPlayerModelSelector(entity me)
  97 {
  98         float i;
  99         if(me.currentModel)
 100                 strunzone(me.currentModel);
 101         me.currentSkin = cvar("_cl_playerskin");
 102         me.currentModel = strzone(cvar_string("_cl_playermodel"));
 103         for(i = 0; i < me.numModels; ++i)
 104         {
 105                 if(bufstr_get(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_MODEL) == me.currentModel)
 106                 if(bufstr_get(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_SKIN) == ftos(me.currentSkin))
 107                         break;
 108         }
 109         if(i >= me.numModels) // fail
 110                 i = 0;
 111         me.idxModels = i;
 112         me.go(me, 0); // this will set the other vars for currentSkin and currentModel
 113 }
 114
 115 void goXonoticPlayerModelSelector(entity me, float d)
 116 {
 117         me.idxModels = mod(me.idxModels + d + me.numModels, me.numModels);
 118
 119         if(me.currentModel)
 120                 strunzone(me.currentModel);
 121         if(me.currentModelTitle)
 122                 strunzone(me.currentModelTitle);
 123         if(me.currentModelImage)
 124                 strunzone(me.currentModelImage);
 125         if(me.currentModelDescription)
 126                 strunzone(me.currentModelDescription);
 127
 128         // select model #i!
 129         me.currentModelTitle = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_TITLE));
 130         me.currentModelImage = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_IMAGE));
 131         me.currentSkin = stof(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_SKIN));
 132         me.currentModel = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_MODEL));
 133         me.currentModelDescription = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_DESC));
 134
 135         // fix the image
 136         me.src = me.currentModelImage;
 137         me.updateAspect(me);
 138 }
 139
 140 void PlayerModelSelector_Next_Click(entity btn, entity me)
 141 {
 142         me.go(me, +1);
 143         me.saveCvars(me);
 144 }
 145
 146 void PlayerModelSelector_Prev_Click(entity btn, entity me)
 147 {
 148         me.go(me, -1);
 149         me.saveCvars(me);
 150 }
 151
 152 void saveCvarsXonoticPlayerModelSelector(entity me)
 153 {
 154         // we can't immediately apply here because of flood control
 155         cvar_set("_cl_playermodel", me.currentModel);
 156         cvar_set("_cl_playerskin", ftos(me.currentSkin));
 157 }
 158
 159 void drawXonoticPlayerModelSelector(entity me)
 160 {
 161         float i, n;
 162         vector o;
 163
 164         drawImage(me);
 165
 166         // draw text on the image, handle \n in the description
 167         draw_CenterText('0.5 0 0', me.currentModelTitle, me.realFontSize * (me.titleFontSize / me.fontSize), SKINCOLOR_MODELTITLE, SKINALPHA_MODELTITLE, FALSE);
 168
 169         o = '0.5 1 0' - eY * me.realFontSize_y * ((n = tokenizebyseparator(me.currentModelDescription, "\n")) + 0.5);
 170         for(i = 0; i < n; ++i)
 171         {
 172                 draw_CenterText(o, argv(i), me.realFontSize, '1 1 1', 1, FALSE);
 173                 o += eY * me.realFontSize_y;
 174         }
 175 }
 176
 177 void resizeNotifyXonoticPlayerModelSelector(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 178 {
 179         resizeNotifyImage(me, relOrigin, relSize, absOrigin, absSize);
 180         me.realFontSize_y = me.fontSize / absSize_y;
 181         me.realFontSize_x = me.fontSize / absSize_x;
 182 }
 183 #endif