qcsrc/menu/xonotic/playermodel.qc

   1 #include "playermodel.qh"
   2
   3 entity makeXonoticPlayerModelSelector()
   4 {
   5         entity me;
   6         me = NEW(XonoticPlayerModelSelector);
   7         me.configureXonoticPlayerModelSelector(me);
   8         return me;
   9 }
  10
  11 const float BUFMODELS_TITLE = 0;
  12 const float BUFMODELS_IMAGE = 1;
  13 const float BUFMODELS_MODEL = 2;
  14 const float BUFMODELS_SKIN = 3;
  15 const float BUFMODELS_DESC = 4;
  16 const float BUFMODELS_COUNT = 5;
  17
  18 #define XONVOTE186 1 // (nyov) removal of model text description
  19
  20 void XonoticPlayerModelSelector_configureXonoticPlayerModelSelector(entity me)
  21 {
  22         me.configureXonoticImage(me, string_null, -1);
  23 }
  24
  25 void XonoticPlayerModelSelector_loadModels(entity me)
  26 {
  27         int i;
  28         string fn;
  29
  30         float glob = search_begin(language_filename(get_model_datafilename(string_null, -1, "txt")), true, true);
  31         if (glob < 0)
  32                 return;
  33
  34         float sortbuf = buf_create();
  35         for(i = 0; i < search_getsize(glob); ++i)
  36         {
  37                 // select model #i!
  38                 fn = search_getfilename(glob, i);
  39                 if(!get_model_parameters(fn, -1))
  40                         continue;
  41                 bufstr_add(sortbuf, sprintf("%-128s%s", get_model_parameters_name, fn), 1);
  42         }
  43         search_end(glob);
  44         buf_sort(sortbuf, 128, 0);
  45         me.numModels = buf_getsize(sortbuf);
  46         me.bufModels = buf_create();
  47         for(i = 0; i < me.numModels; ++i)
  48         {
  49                 fn = substring(bufstr_get(sortbuf, i), 128, -1);
  50                 if(!get_model_parameters(fn, -1))
  51                         error("But it JUST worked!");
  52                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_TITLE, get_model_parameters_name);
  53                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_IMAGE, strcat("/", substring(get_model_datafilename(get_model_parameters_modelname, get_model_parameters_modelskin, "tga"), 0, -5)));
  54                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_MODEL, get_model_parameters_modelname);
  55                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_SKIN, ftos(get_model_parameters_modelskin));
  56                 get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
  57 #if XONVOTE186
  58                 if(get_model_parameters_sex)
  59                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\n%s", get_model_parameters_sex));
  60 #else
  61                 if(get_model_parameters_description)
  62                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\n%s\n", get_model_parameters_description));
  63                 if(get_model_parameters_sex)
  64                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\nSex: %s", get_model_parameters_sex));
  65                 if(get_model_parameters_weight)
  66                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\nWeight: %g kg", get_model_parameters_weight));
  67                 if(get_model_parameters_age)
  68                         get_model_parameters_desc = strcat(get_model_parameters_desc, sprintf("\nAge: %g", get_model_parameters_age));
  69 #endif
  70                 while(substring(get_model_parameters_desc, -1, 1) == "\n")
  71                         get_model_parameters_desc = substring(get_model_parameters_desc, 0, -2);
  72                 bufstr_set(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_DESC, get_model_parameters_desc);
  73         }
  74         buf_del(sortbuf);
  75         get_model_parameters(string_null, 0);
  76         me.loadCvars(me); // this will select the initial model, depending on the current cvars
  77         me.go(me, 0); // this will set the vars for the selected model
  78 }
  79
  80 void XonoticPlayerModelSelector_destroy(entity me)
  81 {
  82         if(me.bufModels >= 0)
  83         {
  84                 buf_del(me.bufModels);
  85                 me.bufModels = -1;
  86         }
  87 }
  88
  89 void XonoticPlayerModelSelector_loadCvars(entity me)
  90 {
  91         string skin, modelname;
  92         float i;
  93
  94         skin = cvar_string("_cl_playerskin");
  95         modelname = cvar_string("_cl_playermodel");
  96
  97         for(i = 0; i < me.numModels; ++i)
  98         {
  99                 if(bufstr_get(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_MODEL) == modelname)
 100                 if(bufstr_get(me.bufModels, BUFMODELS_COUNT*i+BUFMODELS_SKIN) == skin)
 101                         break;
 102         }
 103         if(i >= me.numModels) // fail
 104                 i = 0;
 105         me.idxModels = i;
 106 }
 107
 108 void XonoticPlayerModelSelector_go(entity me, float d)
 109 {
 110         me.idxModels = mod(me.idxModels + d + me.numModels, me.numModels);
 111
 112         if(me.currentModel)
 113                 strunzone(me.currentModel);
 114         if(me.currentModelTitle)
 115                 strunzone(me.currentModelTitle);
 116         if(me.currentModelImage)
 117                 strunzone(me.currentModelImage);
 118         if(me.currentModelDescription)
 119                 strunzone(me.currentModelDescription);
 120
 121         // select model #i!
 122         me.currentModelTitle = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_TITLE));
 123         me.currentModelImage = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_IMAGE));
 124         me.currentSkin = stof(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_SKIN));
 125         me.currentModel = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_MODEL));
 126         me.currentModelDescription = strzone(bufstr_get(me.bufModels, BUFMODELS_COUNT*me.idxModels+BUFMODELS_DESC));
 127
 128         // fix the image
 129         if(draw_PictureSize(me.currentModelImage) == '0 0 0')
 130                 me.src = "nopreview_player";
 131         else
 132                 me.src = me.currentModelImage;
 133         me.updateAspect(me);
 134 }
 135
 136 void PlayerModelSelector_Next_Click(entity btn, entity me)
 137 {
 138         if (me.numModels <= 0)
 139                 return;
 140         me.go(me, +1);
 141         me.saveCvars(me);
 142 }
 143
 144 void PlayerModelSelector_Prev_Click(entity btn, entity me)
 145 {
 146         if (me.numModels <= 0)
 147                 return;
 148         me.go(me, -1);
 149         me.saveCvars(me);
 150 }
 151
 152 void XonoticPlayerModelSelector_saveCvars(entity me)
 153 {
 154         // we can't immediately apply here because of flood control
 155         cvar_set("_cl_playermodel", me.currentModel);
 156         cvar_set("_cl_playerskin", ftos(me.currentSkin));
 157 }
 158
 159 void XonoticPlayerModelSelector_draw(entity me)
 160 {
 161         float i, n;
 162         vector o;
 163
 164         if (me.numModels <= 0)
 165         {
 166                 draw_CenterText('0.5 0.5 0', _("<no model found>"), me.realFontSize, SKINCOLOR_TEXT, 0.6, false);
 167                 return;
 168         }
 169
 170         SUPER(XonoticPlayerModelSelector).draw(me);
 171         // draw text on the image, handle \n in the description
 172
 173         draw_beginBoldFont();
 174
 175 #if XONVOTE186 // (nyov) lower name display looks better when there is no description text
 176         draw_CenterText('0.5 0.8 0', me.currentModelTitle, me.realFontSize * (me.titleFontSize / me.fontSize), SKINCOLOR_MODELTITLE, SKINALPHA_MODELTITLE, false);
 177 #else
 178         draw_CenterText('0.5 0 0', me.currentModelTitle, me.realFontSize * (me.titleFontSize / me.fontSize), SKINCOLOR_MODELTITLE, SKINALPHA_MODELTITLE, false);
 179 #endif
 180
 181         draw_endBoldFont();
 182
 183         o = '0.5 1 0' - eY * me.realFontSize.y * ((n = tokenizebyseparator(me.currentModelDescription, "\n")) + 0.5);
 184         for(i = 0; i < n; ++i)
 185         {
 186                 draw_CenterText(o, argv(i), me.realFontSize, SKINCOLOR_TEXT, 1, false);
 187                 o += eY * me.realFontSize.y;
 188         }
 189 }
 190
 191 void XonoticPlayerModelSelector_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 192 {
 193         SUPER(XonoticPlayerModelSelector).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 194         me.realFontSize_y = me.fontSize / absSize.y;
 195         me.realFontSize_x = me.fontSize / absSize.x;
 196 }
 197
 198 void XonoticPlayerModelSelector_showNotify(entity me)
 199 {
 200         // Reinitialize self.
 201         me.destroy(me);
 202         me.loadModels(me);
 203 }