qcsrc/menu/xonotic/playlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticPlayList, configureXonoticPlayList, void(entity))
   4         ATTRIB(XonoticPlayList, rowsPerItem, float, 1)
   5         METHOD(XonoticPlayList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticPlayList, draw, void(entity))
   7         METHOD(XonoticPlayList, drawListBoxItem, void(entity, float, vector, float))
   8         METHOD(XonoticPlayList, stopSound, void(entity))
   9         METHOD(XonoticPlayList, startSound, void(entity, float))
  10         METHOD(XonoticPlayList, resumeSound, void(entity))
  11         METHOD(XonoticPlayList, pauseSound, void(entity))
  12         METHOD(XonoticPlayList, clickListBoxItem, void(entity, float, vector))
  13         METHOD(XonoticPlayList, keyDown, float(entity, float, float, float))
  14         METHOD(XonoticPlayList, mouseDrag, float(entity, vector))
  15
  16         METHOD(XonoticPlayList, addToPlayList, void(entity, string))
  17         METHOD(XonoticPlayList, removeSelectedFromPlayList, void(entity))
  18         ATTRIB(XonoticPlayList, playingTrack, float, -1)
  19
  20         ATTRIB(XonoticPlayList, realFontSize, vector, '0 0 0')
  21         ATTRIB(XonoticPlayList, columnNameOrigin, float, 0)
  22         ATTRIB(XonoticPlayList, columnNameSize, float, 0)
  23         ATTRIB(XonoticPlayList, columnNumberOrigin, float, 0)
  24         ATTRIB(XonoticPlayList, columnNumberSize, float, 0)
  25         ATTRIB(XonoticPlayList, realUpperMargin, float, 0)
  26         ATTRIB(XonoticPlayList, origin, vector, '0 0 0')
  27         ATTRIB(XonoticPlayList, itemAbsSize, vector, '0 0 0')
  28
  29         ATTRIB(XonoticPlayList, lastClickedSound, float, -1)
  30         ATTRIB(XonoticPlayList, lastClickedTime, float, 0)
  31 ENDCLASS(XonoticPlayList)
  32
  33 entity makeXonoticPlayList();
  34 void PlayList_Remove(entity btn, entity me);
  35 void PlayList_Remove_All(entity btn, entity me);
  36 void StopSound_Click(entity btn, entity me);
  37 void StartSound_Click(entity btn, entity me);
  38 void PauseSound_Click(entity btn, entity me);
  39 void PrevSound_Click(entity btn, entity me);
  40 void NextSound_Click(entity btn, entity me);
  41 #endif
  42
  43 #ifdef IMPLEMENTATION
  44
  45 entity makeXonoticPlayList()
  46 {
  47         entity me;
  48         me = spawnXonoticPlayList();
  49         me.configureXonoticPlayList(me);
  50         return me;
  51 }
  52
  53 void XonoticPlayList_configureXonoticPlayList(entity me)
  54 {
  55         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  56         me.configureXonoticListBox(me);
  57 }
  58
  59 void XonoticPlayList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  60 {
  61         me.itemAbsSize = '0 0 0';
  62         SUPER(XonoticPlayList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  63
  64         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  65         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  66         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  67
  68         me.columnNumberOrigin = 0;
  69         me.columnNumberSize = 3 * me.realFontSize_x;
  70
  71         me.columnNameOrigin = me.columnNumberSize + me.realFontSize_x;
  72         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize_x;
  73 }
  74
  75 void XonoticPlayList_addToPlayList(entity me, string track)
  76 {
  77         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  78         if(me.nItems == 0)
  79         {
  80                 cvar_set("music_playlist_list0", track);
  81                 return;
  82         }
  83         float i;
  84         for(i = 0; i < me.nItems; ++i)
  85         {
  86                 if(argv(i) == track)
  87                         return; // track is already in playlist
  88         }
  89         cvar_set("music_playlist_list0", strcat(cvar_string("music_playlist_list0"), " ", track));
  90 }
  91
  92 void XonoticPlayList_removeSelectedFromPlayList(entity me)
  93 {
  94         float i, cpt = FALSE;
  95         string s = "";
  96         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  97         if(me.nItems == 0)
  98                 return;
  99         for(i = 0; i < me.nItems; ++i)
 100         {
 101                 if(i == me.selectedItem)
 102                 {
 103                         if(i == me.nItems - 1)
 104                                 me.setSelected(me, me.selectedItem - 1);
 105                         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 106                         {
 107                                 if(cvar("music_playlist_current0") == i)
 108                                         cpt = TRUE; // current playing track (we can't start next track here because startSound calls tokenize_console)
 109                                 else if(cvar("music_playlist_current0") > i)
 110                                         cvar_set("music_playlist_current0", ftos(cvar("music_playlist_current0") - 1));
 111                         }
 112                         continue;
 113                 }
 114                 s = strcat(s, " ", argv(i));
 115         }
 116         // we must stop the current playing track if it has been removed
 117         // otherwise pause/play button will resume from another track
 118         if(s == "")
 119         {
 120                 cvar_set("music_playlist_list0", "");
 121                 if(cpt)
 122                         me.stopSound(me);
 123         }
 124         else
 125         {
 126                 cvar_set("music_playlist_list0", substring(s, 1, strlen(s))); // remove initial space
 127                 if(cpt)
 128                         me.startSound(me, 0);
 129         }
 130 }
 131
 132 void PlayList_Remove(entity btn, entity me)
 133 {
 134         me.removeSelectedFromPlayList(me);
 135 }
 136
 137 void PlayList_Remove_All(entity btn, entity me)
 138 {
 139         cvar_set("music_playlist_list0", "");
 140         me.stopSound(me);
 141         me.selectedItem = 0;
 142 }
 143
 144 float XonoticPlayList_mouseDrag(entity me, vector pos)
 145 {
 146         float f, i;
 147         i = me.selectedItem;
 148         f = SUPER(XonoticPlayList).mouseDrag(me, pos);
 149
 150         if(me.pressed != 1) // don't change priority if the person is just scrolling
 151         {
 152                 if(me.selectedItem != i)
 153                 {
 154                         cvar_set("music_playlist_list0", swapInPriorityList(cvar_string("music_playlist_list0"), me.selectedItem, i));
 155                         float c = cvar("music_playlist_current0");
 156                         if(c == i)
 157                                 cvar_set("music_playlist_current0", ftos(me.selectedItem));
 158                         else if(c == me.selectedItem)
 159                                 cvar_set("music_playlist_current0", ftos(i));
 160                 }
 161         }
 162
 163         return f;
 164 }
 165
 166 void XonoticPlayList_draw(entity me)
 167 {
 168         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 169         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 170                 me.playingTrack = cvar("music_playlist_current0");
 171         else
 172                 me.playingTrack = -1;
 173         SUPER(XonoticPlayList).draw(me);
 174 }
 175
 176 void XonoticPlayList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 177 {
 178         string s;
 179         if(isSelected)
 180                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 181
 182         if(i == me.playingTrack)
 183         {
 184                 float f = cvar("music_playlist_sampleposition0");
 185                 if(f <= 0 || (((time * 2) & 1) && f > 0))
 186                         draw_Text(me.realUpperMargin * eY + (me.columnNumberOrigin + me.columnNumberSize) * eX, chr(0xE000 + 141), me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 187         }
 188
 189         s = ftos(i+1);
 190         draw_CenterText(me.realUpperMargin * eY + (me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 191
 192         s = draw_TextShortenToWidth(argv(i), me.columnNameSize, 0, me.realFontSize);
 193         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 194 }
 195
 196 void XonoticPlayList_stopSound(entity me)
 197 {
 198         // STOP: list 0 is disabled by setting the index to -1
 199         // we set sampleposition0 to 0 to forget the position that the engine saves in this frame (for this reason we need to wait a frame)
 200         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 201         {
 202                 cvar_set("music_playlist_index", "-1");
 203                 localcmd("\nwait; music_playlist_sampleposition0 0\n");
 204                 localcmd("\ndefer 3 \"cd play $menu_cdtrack\"\n");
 205         }
 206 }
 207
 208 void StopSound_Click(entity btn, entity me)
 209 {
 210         me.stopSound(me);
 211 }
 212
 213 void XonoticPlayList_startSound(entity me, float offset)
 214 {
 215         float f;
 216         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 217         if(offset)
 218         {
 219                 if(cvar("music_playlist_index") == -1)
 220                         return;
 221                 f = bound(0, cvar("music_playlist_current0") + offset, me.nItems - 1);
 222                 if(f == cvar("music_playlist_current0"))
 223                         return;
 224         }
 225         else
 226         {
 227                 f = me.selectedItem;
 228                 // if it was paused then resume
 229                 if(f == cvar("music_playlist_current0"))
 230                 if(cvar("music_playlist_index") == 999)
 231                 {
 232                         me.resumeSound(me);
 233                         return;
 234                 }
 235                 // if it was not paused then proceed with restart
 236         }
 237
 238         // START: list 0 is disabled by setting the index to 999
 239         // we set current0 to the selected track and sampleposition0 to 0 to forget the position that the engine saves in this frame (for this reason we need to wait a frame)
 240         // then we switch back to list 0
 241         cvar_set("music_playlist_index", "999");
 242         cvar_set("music_playlist_current0", ftos(f));
 243         localcmd("\nwait; music_playlist_sampleposition0 0; wait; music_playlist_index 0\n");
 244 }
 245
 246 void StartSound_Click(entity btn, entity me)
 247 {
 248         me.startSound(me, 0);
 249 }
 250
 251 void PrevSound_Click(entity btn, entity me)
 252 {
 253         me.startSound(me, -1);
 254 }
 255
 256 void NextSound_Click(entity btn, entity me)
 257 {
 258         me.startSound(me, +1);
 259 }
 260
 261 void XonoticPlayList_resumeSound(entity me)
 262 {
 263         // RESUME: list 0 is enabled by setting the index to 0
 264         // (we reset sampleposition0 to 0 to mark the track as in playing back state)
 265         if(cvar("music_playlist_index") == 999)
 266                 localcmd("\nmusic_playlist_index 0; wait; music_playlist_sampleposition0 0\n");
 267 }
 268 void XonoticPlayList_pauseSound(entity me)
 269 {
 270         // PAUSE: list 0 is disabled by setting the index to 999
 271         // (we know the track is paused because the engine sets sampleposition0 to remember current position)
 272         if(cvar("music_playlist_index") == 0)
 273                 localcmd("\nmusic_playlist_index 999\n");
 274         else me.resumeSound(me);
 275 }
 276
 277 void PauseSound_Click(entity btn, entity me)
 278 {
 279         me.pauseSound(me);
 280 }
 281
 282 void XonoticPlayList_clickListBoxItem(entity me, float i, vector where)
 283 {
 284         if(i == me.lastClickedSound)
 285                 if(time < me.lastClickedTime + 0.3)
 286                 {
 287                         // DOUBLE CLICK!
 288                         me.setSelected(me, i);
 289                         me.startSound(me, 0);
 290                 }
 291         me.lastClickedSound = i;
 292         me.lastClickedTime = time;
 293 }
 294
 295 float XonoticPlayList_keyDown(entity me, float scan, float ascii, float shift)
 296 {
 297         if(scan == K_ENTER || scan == K_KP_ENTER) {
 298                 me.startSound(me, 0);
 299                 return 1;
 300         }
 301         else if(scan == K_SPACE) {
 302                 me.pauseSound(me);
 303                 return 1;
 304         }
 305         else if(scan == K_DEL || scan == K_KP_DEL || scan == K_BACKSPACE || scan == K_MOUSE3) {
 306                 me.removeSelectedFromPlayList(me);
 307                 return 1;
 308         }
 309         else
 310                 return SUPER(XonoticPlayList).keyDown(me, scan, ascii, shift);
 311 }
 312 #endif
 313