qcsrc/menu/xonotic/playlist.qc

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticPlayList, configureXonoticPlayList, void(entity))
   4         ATTRIB(XonoticPlayList, rowsPerItem, float, 1)
   5         METHOD(XonoticPlayList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticPlayList, draw, void(entity))
   7         METHOD(XonoticPlayList, drawListBoxItem, void(entity, float, vector, float))
   8         METHOD(XonoticPlayList, stopSound, void(entity))
   9         METHOD(XonoticPlayList, startSound, void(entity, float))
  10         METHOD(XonoticPlayList, resumeSound, void(entity))
  11         METHOD(XonoticPlayList, pauseSound, void(entity))
  12         METHOD(XonoticPlayList, doubleClickListBoxItem, void(entity, float, vector))
  13         METHOD(XonoticPlayList, keyDown, float(entity, float, float, float))
  14         METHOD(XonoticPlayList, mouseDrag, float(entity, vector))
  15
  16         METHOD(XonoticPlayList, addToPlayList, void(entity, string))
  17         METHOD(XonoticPlayList, removeSelectedFromPlayList, void(entity))
  18         ATTRIB(XonoticPlayList, playingTrack, float, -1)
  19
  20         ATTRIB(XonoticPlayList, realFontSize, vector, '0 0 0')
  21         ATTRIB(XonoticPlayList, columnNameOrigin, float, 0)
  22         ATTRIB(XonoticPlayList, columnNameSize, float, 0)
  23         ATTRIB(XonoticPlayList, columnNumberOrigin, float, 0)
  24         ATTRIB(XonoticPlayList, columnNumberSize, float, 0)
  25         ATTRIB(XonoticPlayList, realUpperMargin, float, 0)
  26         ATTRIB(XonoticPlayList, origin, vector, '0 0 0')
  27         ATTRIB(XonoticPlayList, itemAbsSize, vector, '0 0 0')
  28 ENDCLASS(XonoticPlayList)
  29
  30 entity makeXonoticPlayList();
  31 void PlayList_Remove(entity btn, entity me);
  32 void PlayList_Remove_All(entity btn, entity me);
  33 void StopSound_Click(entity btn, entity me);
  34 void StartSound_Click(entity btn, entity me);
  35 void PauseSound_Click(entity btn, entity me);
  36 void PrevSound_Click(entity btn, entity me);
  37 void NextSound_Click(entity btn, entity me);
  38 #endif
  39
  40 #ifdef IMPLEMENTATION
  41
  42 entity makeXonoticPlayList()
  43 {
  44         entity me;
  45         me = spawnXonoticPlayList();
  46         me.configureXonoticPlayList(me);
  47         return me;
  48 }
  49
  50 void XonoticPlayList_configureXonoticPlayList(entity me)
  51 {
  52         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  53         me.configureXonoticListBox(me);
  54 }
  55
  56 void XonoticPlayList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  57 {
  58         me.itemAbsSize = '0 0 0';
  59         SUPER(XonoticPlayList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  60
  61         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
  62         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
  63         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  64
  65         me.columnNumberOrigin = 0;
  66         me.columnNumberSize = 3 * me.realFontSize.x;
  67
  68         me.columnNameOrigin = me.columnNumberSize + me.realFontSize.x;
  69         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize.x;
  70 }
  71
  72 void XonoticPlayList_addToPlayList(entity me, string track)
  73 {
  74         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  75         if(me.nItems == 0)
  76         {
  77                 cvar_set("music_playlist_list0", track);
  78                 return;
  79         }
  80         float i;
  81         for(i = 0; i < me.nItems; ++i)
  82         {
  83                 if(argv(i) == track)
  84                         return; // track is already in playlist
  85         }
  86         cvar_set("music_playlist_list0", strcat(cvar_string("music_playlist_list0"), " ", track));
  87 }
  88
  89 void XonoticPlayList_removeSelectedFromPlayList(entity me)
  90 {
  91         float i, cpt = false;
  92         string s = "";
  93         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  94         if(me.nItems == 0)
  95                 return;
  96         for(i = 0; i < me.nItems; ++i)
  97         {
  98                 if(i == me.selectedItem)
  99                 {
 100                         if(i == me.nItems - 1)
 101                                 me.setSelected(me, me.selectedItem - 1);
 102                         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 103                         {
 104                                 if(cvar("music_playlist_current0") == i)
 105                                         cpt = true; // current playing track (we can't start next track here because startSound calls tokenize_console)
 106                                 else if(cvar("music_playlist_current0") > i)
 107                                         cvar_set("music_playlist_current0", ftos(cvar("music_playlist_current0") - 1));
 108                         }
 109                         continue;
 110                 }
 111                 s = strcat(s, " ", argv(i));
 112         }
 113         // we must stop the current playing track if it has been removed
 114         // otherwise pause/play button will resume from another track
 115         if(s == "")
 116         {
 117                 cvar_set("music_playlist_list0", "");
 118                 if(cpt)
 119                         me.stopSound(me);
 120         }
 121         else
 122         {
 123                 cvar_set("music_playlist_list0", substring(s, 1, strlen(s))); // remove initial space
 124                 if(cpt)
 125                         me.startSound(me, 0);
 126         }
 127 }
 128
 129 void PlayList_Remove(entity btn, entity me)
 130 {
 131         me.removeSelectedFromPlayList(me);
 132 }
 133
 134 void PlayList_Remove_All(entity btn, entity me)
 135 {
 136         cvar_set("music_playlist_list0", "");
 137         me.stopSound(me);
 138         me.selectedItem = 0;
 139 }
 140
 141 float XonoticPlayList_mouseDrag(entity me, vector pos)
 142 {
 143         float f, i;
 144         i = me.selectedItem;
 145         f = SUPER(XonoticPlayList).mouseDrag(me, pos);
 146
 147         if(me.pressed != 1) // don't change priority if the person is just scrolling
 148         {
 149                 if(me.selectedItem != i)
 150                 {
 151                         cvar_set("music_playlist_list0", swapInPriorityList(cvar_string("music_playlist_list0"), me.selectedItem, i));
 152                         float c = cvar("music_playlist_current0");
 153                         if(c == i)
 154                                 cvar_set("music_playlist_current0", ftos(me.selectedItem));
 155                         else if(c == me.selectedItem)
 156                                 cvar_set("music_playlist_current0", ftos(i));
 157                 }
 158         }
 159
 160         return f;
 161 }
 162
 163 void XonoticPlayList_draw(entity me)
 164 {
 165         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 166         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 167                 me.playingTrack = cvar("music_playlist_current0");
 168         else
 169                 me.playingTrack = -1;
 170         SUPER(XonoticPlayList).draw(me);
 171 }
 172
 173 void XonoticPlayList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 174 {
 175         string s;
 176         if(isSelected)
 177                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 178
 179         if(i == me.playingTrack)
 180         {
 181                 float f = cvar("music_playlist_sampleposition0");
 182                 if(f <= 0 || (((time * 2) & 1) && f > 0))
 183                         draw_Text(me.realUpperMargin * eY + (me.columnNumberOrigin + me.columnNumberSize) * eX, "\xE2\x96\xB6", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 184         }
 185
 186         s = ftos(i+1);
 187         draw_CenterText(me.realUpperMargin * eY + (me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 188
 189         s = draw_TextShortenToWidth(argv(i), me.columnNameSize, 0, me.realFontSize);
 190         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 191 }
 192
 193 void XonoticPlayList_stopSound(entity me)
 194 {
 195         // STOP: list 0 is disabled by setting the index to -1
 196         // we set sampleposition0 to 0 to forget the position that the engine saves in this frame (for this reason we need to wait a frame)
 197         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 198         {
 199                 cvar_set("music_playlist_index", "-1");
 200                 localcmd("\nwait; music_playlist_sampleposition0 0\n");
 201                 localcmd("\ndefer 3 \"cd play $menu_cdtrack\"\n");
 202         }
 203 }
 204
 205 void StopSound_Click(entity btn, entity me)
 206 {
 207         me.stopSound(me);
 208 }
 209
 210 void XonoticPlayList_startSound(entity me, float offset)
 211 {
 212         float f;
 213         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 214         if(offset)
 215         {
 216                 if(cvar("music_playlist_index") == -1)
 217                         return;
 218                 f = bound(0, cvar("music_playlist_current0") + offset, me.nItems - 1);
 219                 if(f == cvar("music_playlist_current0"))
 220                         return;
 221         }
 222         else
 223         {
 224                 f = me.selectedItem;
 225                 // if it was paused then resume
 226                 if(f == cvar("music_playlist_current0"))
 227                 if(cvar("music_playlist_index") == 999)
 228                 {
 229                         me.resumeSound(me);
 230                         return;
 231                 }
 232                 // if it was not paused then proceed with restart
 233         }
 234
 235         // START: list 0 is disabled by setting the index to 999
 236         // we set current0 to the selected track and sampleposition0 to 0 to forget the position that the engine saves in this frame (for this reason we need to wait a frame)
 237         // then we switch back to list 0
 238         cvar_set("music_playlist_index", "999");
 239         cvar_set("music_playlist_current0", ftos(f));
 240         localcmd("\nwait; music_playlist_sampleposition0 0; wait; music_playlist_index 0\n");
 241 }
 242
 243 void StartSound_Click(entity btn, entity me)
 244 {
 245         me.startSound(me, 0);
 246 }
 247
 248 void PrevSound_Click(entity btn, entity me)
 249 {
 250         me.startSound(me, -1);
 251 }
 252
 253 void NextSound_Click(entity btn, entity me)
 254 {
 255         me.startSound(me, +1);
 256 }
 257
 258 void XonoticPlayList_resumeSound(entity me)
 259 {
 260         // RESUME: list 0 is enabled by setting the index to 0
 261         // (we reset sampleposition0 to 0 to mark the track as in playing back state)
 262         if(cvar("music_playlist_index") == 999)
 263                 localcmd("\nmusic_playlist_index 0; wait; music_playlist_sampleposition0 0\n");
 264 }
 265 void XonoticPlayList_pauseSound(entity me)
 266 {
 267         // PAUSE: list 0 is disabled by setting the index to 999
 268         // (we know the track is paused because the engine sets sampleposition0 to remember current position)
 269         if(cvar("music_playlist_index") == 0)
 270                 localcmd("\nmusic_playlist_index 999\n");
 271         else me.resumeSound(me);
 272 }
 273
 274 void PauseSound_Click(entity btn, entity me)
 275 {
 276         me.pauseSound(me);
 277 }
 278
 279 void XonoticPlayList_doubleClickListBoxItem(entity me, float i, vector where)
 280 {
 281         me.startSound(me, 0);
 282 }
 283
 284 float XonoticPlayList_keyDown(entity me, float scan, float ascii, float shift)
 285 {
 286         if(scan == K_ENTER || scan == K_KP_ENTER) {
 287                 me.startSound(me, 0);
 288                 return 1;
 289         }
 290         else if(scan == K_SPACE) {
 291                 me.pauseSound(me);
 292                 return 1;
 293         }
 294         else if(scan == K_DEL || scan == K_KP_DEL || scan == K_BACKSPACE || scan == K_MOUSE3) {
 295                 me.removeSelectedFromPlayList(me);
 296                 return 1;
 297         }
 298         else
 299                 return SUPER(XonoticPlayList).keyDown(me, scan, ascii, shift);
 300 }
 301 #endif
 302