qcsrc/menu/xonotic/radiobutton.qc

   1 #ifndef RADIOBUTTON_H
   2 #define RADIOBUTTON_H
   3 #include "../item/radiobutton.qc"
   4 CLASS(XonoticRadioButton, RadioButton)
   5         METHOD(XonoticRadioButton, configureXonoticRadioButton, void(entity, float, string, string, string))
   6         METHOD(XonoticRadioButton, draw, void(entity))
   7         METHOD(XonoticRadioButton, setChecked, void(entity, float))
   8         ATTRIB(XonoticRadioButton, fontSize, float, SKINFONTSIZE_NORMAL)
   9         ATTRIB(XonoticRadioButton, image, string, SKINGFX_RADIOBUTTON)
  10         ATTRIB(XonoticRadioButton, color, vector, SKINCOLOR_RADIOBUTTON_N)
  11         ATTRIB(XonoticRadioButton, colorC, vector, SKINCOLOR_RADIOBUTTON_C)
  12         ATTRIB(XonoticRadioButton, colorF, vector, SKINCOLOR_RADIOBUTTON_F)
  13         ATTRIB(XonoticRadioButton, colorD, vector, SKINCOLOR_RADIOBUTTON_D)
  14
  15         ATTRIB(XonoticRadioButton, cvarName, string, string_null)
  16         ATTRIB(XonoticRadioButton, cvarValue, string, string_null)
  17         ATTRIB(XonoticRadioButton, cvarOffValue, string, string_null)
  18         ATTRIB(XonoticRadioButton, getCvarValueFromCvar, float, 0)
  19         METHOD(XonoticRadioButton, loadCvars, void(entity))
  20         METHOD(XonoticRadioButton, saveCvars, void(entity))
  21
  22         ATTRIB(XonoticRadioButton, alpha, float, SKINALPHA_TEXT)
  23         ATTRIB(XonoticRadioButton, disabledAlpha, float, SKINALPHA_DISABLED)
  24 ENDCLASS(XonoticRadioButton)
  25 entity makeXonoticRadioButton(float, string, string, string);
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29 entity makeXonoticRadioButton(float theGroup, string theCvar, string theValue, string theText)
  30 {
  31         entity me;
  32         me = NEW(XonoticRadioButton);
  33         me.configureXonoticRadioButton(me, theGroup, theCvar, theValue, theText);
  34         return me;
  35 }
  36 void XonoticRadioButton_configureXonoticRadioButton(entity me, float theGroup, string theCvar, string theValue, string theText)
  37 {
  38         if(theCvar)
  39         {
  40                 me.cvarName = theCvar;
  41                 me.cvarValue = theValue;
  42                 me.tooltip = getZonedTooltipForIdentifier(theCvar);
  43                 me.loadCvars(me);
  44         }
  45         me.configureRadioButton(me, theText, me.fontSize, me.image, theGroup, 0);
  46 }
  47 void XonoticRadioButton_setChecked(entity me, float val)
  48 {
  49         if(val != me.checked)
  50         {
  51                 me.checked = val;
  52                 me.saveCvars(me);
  53         }
  54 }
  55 void XonoticRadioButton_loadCvars(entity me)
  56 {
  57         if(me.cvarValue)
  58         {
  59                 if(me.cvarName)
  60                         me.checked = (cvar_string(me.cvarName) == me.cvarValue);
  61         }
  62         else
  63         {
  64                 if(me.cvarName)
  65                 {
  66                         me.checked = !!cvar(me.cvarName);
  67                 }
  68                 else
  69                 {
  70                         // this is difficult
  71                         // this is the "generic" selection... but at this time, not
  72                         // everything is constructed yet.
  73                         // we need to set this later in draw()
  74                         me.checked = 0;
  75                 }
  76         }
  77 }
  78 void XonoticRadioButton_draw(entity me)
  79 {
  80         if (!me.cvarValue)
  81                 if (!me.cvarName)
  82                 {
  83                         // this is the "other" option
  84                         // always select this if none other is
  85                         entity e;
  86                         float found;
  87                         found = 0;
  88                         for(e = me.parent.firstChild; e; e = e.nextSibling)
  89                                 if(e.group == me.group)
  90                                         if(e.checked)
  91                                                 found = 1;
  92                         if(!found)
  93                                 me.setChecked(me, 1);
  94                 }
  95         SUPER(XonoticRadioButton).draw(me);
  96 }
  97 void XonoticRadioButton_saveCvars(entity me)
  98 {
  99         if(me.cvarValue)
 100         {
 101                 if(me.cvarName)
 102                 {
 103                         if(me.checked)
 104                         {
 105                                 if(me.getCvarValueFromCvar)
 106                                         cvar_set(me.cvarName, cvar_string(me.cvarValue));
 107                                 else
 108                                         cvar_set(me.cvarName, me.cvarValue);
 109                         }
 110                         else if(me.cvarOffValue)
 111                                 cvar_set(me.cvarName, me.cvarOffValue);
 112                 }
 113         }
 114         else
 115         {
 116                 if(me.cvarName)
 117                 {
 118                         cvar_set(me.cvarName, ftos(me.checked));
 119                 }
 120         }
 121 }
 122 #endif