qcsrc/menu/xonotic/screenshotlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticScreenshotList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
   4         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
   5         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticScreenshotList, setSelected, void(entity, float))
   7         METHOD(XonoticScreenshotList, draw, void(entity))
   8         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, float, vector, float))
   9         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
  10         METHOD(XonoticScreenshotList, previewScreenshot, void(entity))
  11         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
  12         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
  13         METHOD(XonoticScreenshotList, clickListBoxItem, void(entity, float, vector))
  14         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
  15         METHOD(XonoticScreenshotList, destroy, void(entity))
  16         METHOD(XonoticScreenshotList, showNotify, void(entity))
  17         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
  18         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
  19         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
  20         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
  21         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
  22         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
  23         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
  24         ATTRIB(XonoticScreenshotList, lastClickedScreenshot, float, -1)
  25         ATTRIB(XonoticScreenshotList, lastClickedTime, float, 0)
  26         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
  27         ATTRIB(XonoticScreenshotList, filterBox, entity, NULL)
  28         ATTRIB(XonoticScreenshotList, filterTime, float, 0)
  29
  30         ATTRIB(XonoticScreenshotList, newScreenshotTime, float, 0)
  31         ATTRIB(XonoticScreenshotList, newSlideShowScreenshotTime, float, 0)
  32         ATTRIB(XonoticScreenshotList, prevSelectedItem, float, 0)
  33
  34         ATTRIB(XonoticScreenshotList, screenshotBrowserDialog, entity, NULL)
  35         ATTRIB(XonoticScreenshotList, screenshotPreview, entity, NULL)
  36         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
  37         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
  38         METHOD(XonoticScreenshotList, startSlideShow, void(entity))
  39         METHOD(XonoticScreenshotList, stopSlideShow, void(entity))
  40 ENDCLASS(XonoticScreenshotList)
  41
  42 entity makeXonoticScreenshotList();
  43 void StartScreenshot_Click(entity btn, entity me);
  44 void ScreenshotList_Refresh_Click(entity btn, entity me);
  45 void ScreenshotList_Filter_Would_Change(entity box, entity me);
  46 void ScreenshotList_Filter_Change(entity box, entity me);
  47 #endif
  48
  49 #ifdef IMPLEMENTATION
  50
  51 entity makeXonoticScreenshotList()
  52 {
  53         entity me;
  54         me = spawnXonoticScreenshotList();
  55         me.configureXonoticScreenshotList(me);
  56         return me;
  57 }
  58
  59 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  60 {
  61         me.configureXonoticListBox(me);
  62         me.getScreenshots(me);
  63 }
  64
  65 string XonoticScreenshotList_screenshotName(entity me, float i)
  66 {
  67         string s;
  68         s = bufstr_get(me.listScreenshot, i);
  69
  70         if(substring(s, 0, 1) == "/")
  71                 s = substring(s, 1, strlen(s) - 1);  // remove the first forward slash
  72
  73         return s;
  74 }
  75
  76 // if subdir is TRUE look in subdirectories too (1 level)
  77 void getScreenshots_for_ext(entity me, string ext, float subdir)
  78 {
  79         string s;
  80         if (subdir)
  81                 s="screenshots/*/";
  82         else
  83                 s="screenshots/";
  84         if(me.filterString)
  85                 s=strcat(s, me.filterString, ext);
  86         else
  87                 s=strcat(s, "*", ext);
  88
  89         float list, i, n;
  90         list = search_begin(s, FALSE, TRUE);
  91         if(list >= 0)
  92         {
  93                 n = search_getsize(list);
  94                 for(i = 0; i < n; ++i)
  95                 {
  96                         s = search_getfilename(list, i); // get initial full file name
  97                         s = substring(s, 12, (strlen(s) - 12 - 4)); // remove "screenshots/" prefix and ".<ext>" suffix
  98                         s = strdecolorize(s); // remove any pre-existing colors
  99                         if(subdir)
 100                         {
 101                                 s = strreplace("/", "^7/", s); // clear colors at the forward slash
 102                                 s = strcat("/", rgb_to_hexcolor(SKINCOLOR_SCREENSHOTLIST_SUBDIR), s); // add a forward slash for sorting, then color
 103                                 bufstr_add(me.listScreenshot, s, TRUE);
 104                         }
 105                         else { bufstr_add(me.listScreenshot, s, TRUE); }
 106                 }
 107                 search_end(list);
 108         }
 109
 110         if (subdir)
 111                 getScreenshots_for_ext(me, ext, FALSE);
 112 }
 113
 114 void XonoticScreenshotList_getScreenshots(entity me)
 115 {
 116         if (me.listScreenshot >= 0)
 117                 buf_del(me.listScreenshot);
 118         me.listScreenshot = buf_create();
 119         if (me.listScreenshot < 0)
 120         {
 121                 me.nItems = 0;
 122                 return;
 123         }
 124         getScreenshots_for_ext(me, ".jpg", TRUE);
 125         getScreenshots_for_ext(me, ".tga", TRUE);
 126         getScreenshots_for_ext(me, ".png", TRUE);
 127         me.nItems = buf_getsize(me.listScreenshot);
 128         if(me.nItems > 0)
 129                 buf_sort(me.listScreenshot, 128, FALSE);
 130 }
 131
 132 void XonoticScreenshotList_destroy(entity me)
 133 {
 134         if(me.nItems > 0)
 135                 buf_del(me.listScreenshot);
 136 }
 137
 138 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 139 {
 140         me.itemAbsSize = '0 0 0';
 141         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 142
 143         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 144         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 145         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 146
 147         me.columnNameOrigin = me.realFontSize_x;
 148         me.columnNameSize = 1 - 2 * me.realFontSize_x;
 149 }
 150
 151 void XonoticScreenshotList_setSelected(entity me, float i)
 152 {
 153         if (me.newSlideShowScreenshotTime)
 154                 me.startSlideShow(me);
 155         me.prevSelectedItem = me.selectedItem;
 156         SUPER(XonoticScreenshotList).setSelected(me, i);
 157         if (me.pressed && me.selectedItem != me.prevSelectedItem)
 158         {
 159                 // while dragging the scrollbar (or an item)
 160                 // for a smooth mouse movement do not load immediately the new selected images
 161                 me.newScreenshotTime = time + 0.22; // dragging an item we need a delay > 0.2 (from listbox: me.dragScrollTimer = time + 0.2;)
 162         }
 163         else if (time > me.newScreenshotTime)
 164         {
 165                 me.newScreenshotTime = 0;
 166                 me.previewScreenshot(me); // load the preview on selection change
 167         }
 168 }
 169
 170 void XonoticScreenshotList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 171 {
 172         string s;
 173         if(isSelected)
 174                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 175
 176         s = me.screenshotName(me,i);
 177         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 178         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 1);
 179 }
 180
 181 void XonoticScreenshotList_showNotify(entity me)
 182 {
 183         me.getScreenshots(me);
 184         me.previewScreenshot(me);
 185 }
 186
 187 void ScreenshotList_Refresh_Click(entity btn, entity me)
 188 {
 189         me.getScreenshots(me);
 190         me.setSelected(me, 0); //always select the first element after a list update
 191 }
 192
 193 void ScreenshotList_Filter_Change(entity box, entity me)
 194 {
 195         if(me.filterString)
 196                 strunzone(me.filterString);
 197
 198         if(box.text != "")
 199         {
 200                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 201                         me.filterString = strzone(box.text);
 202                 else
 203                         me.filterString = strzone(strcat("*", box.text, "*"));
 204         }
 205         else
 206                 me.filterString = string_null;
 207
 208         ScreenshotList_Refresh_Click(world, me);
 209 }
 210
 211 void ScreenshotList_Filter_Would_Change(entity box, entity me)
 212 {
 213         me.filterBox = box;
 214         me.filterTime = time + 0.5;
 215 }
 216
 217 void XonoticScreenshotList_draw(entity me)
 218 {
 219         if (me.filterTime && time > me.filterTime)
 220         {
 221                 ScreenshotList_Filter_Change(me.filterBox, me);
 222                 me.filterTime = 0;
 223         }
 224         if (me.newScreenshotTime && time > me.newScreenshotTime)
 225         {
 226                 me.previewScreenshot(me);
 227                 me.newScreenshotTime = 0;
 228         }
 229         else if (me.newSlideShowScreenshotTime && time > me.newSlideShowScreenshotTime)
 230         {
 231                 if (me.selectedItem == me.nItems - 1) //last screenshot?
 232                 {
 233                         // restart from the first screenshot
 234                         me.setSelected(me, 0);
 235                         me.goScreenshot(me, +0);
 236                 }
 237                 else
 238                         me.goScreenshot(me, +1);
 239         }
 240         SUPER(XonoticScreenshotList).draw(me);
 241 }
 242
 243 void XonoticScreenshotList_startSlideShow(entity me)
 244 {
 245         me.newSlideShowScreenshotTime = time + 3;
 246 }
 247
 248 void XonoticScreenshotList_stopSlideShow(entity me)
 249 {
 250         me.newSlideShowScreenshotTime = 0;
 251 }
 252
 253 void XonoticScreenshotList_goScreenshot(entity me, float d)
 254 {
 255         if(!me.screenshotViewerDialog)
 256                 return;
 257         me.setSelected(me, me.selectedItem + d);
 258         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 259 }
 260
 261 void XonoticScreenshotList_startScreenshot(entity me)
 262 {
 263         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 264         // pop up screenshot
 265         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 266 }
 267
 268 void XonoticScreenshotList_previewScreenshot(entity me)
 269 {
 270         if(!me.screenshotBrowserDialog)
 271                 return;
 272         if (me.nItems <= 0)
 273                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
 274         else
 275                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 276 }
 277
 278 void StartScreenshot_Click(entity btn, entity me)
 279 {
 280         me.startScreenshot(me);
 281 }
 282
 283 void XonoticScreenshotList_clickListBoxItem(entity me, float i, vector where)
 284 {
 285         if(i == me.lastClickedScreenshot)
 286                 if(time < me.lastClickedTime + 0.3)
 287                 {
 288                         // DOUBLE CLICK!
 289                         // pop up screenshot
 290                         me.setSelected(me, i);
 291                         me.startScreenshot(me);
 292                 }
 293         me.lastClickedScreenshot = i;
 294         me.lastClickedTime = time;
 295 }
 296
 297 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 298 {
 299         if(scan == K_ENTER || scan == K_KP_ENTER) {
 300                 me.startScreenshot(me);
 301                 return 1;
 302         }
 303         if(scan == K_MWHEELUP || scan == K_MWHEELDOWN)
 304                 me.newScreenshotTime = time + 0.2;
 305         return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 306 }
 307 #endif