Merge branch 'master' into terencehill/menu_listbox_changes
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / screenshotlist.qc
1 #ifndef SCREENSHOTLIST_H
2 #define SCREENSHOTLIST_H
3 #include "listbox.qc"
4 CLASS(XonoticScreenshotList, XonoticListBox)
5         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
6         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
7         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
8         METHOD(XonoticScreenshotList, setSelected, void(entity, float))
9         METHOD(XonoticScreenshotList, draw, void(entity))
10         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, int, vector, bool, bool))
11         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
12         METHOD(XonoticScreenshotList, previewScreenshot, void(entity))
13         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
14         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
15         METHOD(XonoticScreenshotList, doubleClickListBoxItem, void(entity, float, vector))
16         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
17         METHOD(XonoticScreenshotList, destroy, void(entity))
18         METHOD(XonoticScreenshotList, showNotify, void(entity))
19         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
20         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
21         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
22         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
23         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
24         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
25         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
26         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
27         ATTRIB(XonoticScreenshotList, filterBox, entity, NULL)
28         ATTRIB(XonoticScreenshotList, filterTime, float, 0)
29
30         ATTRIB(XonoticScreenshotList, newScreenshotTime, float, 0)
31         ATTRIB(XonoticScreenshotList, newSlideShowScreenshotTime, float, 0)
32
33         ATTRIB(XonoticScreenshotList, screenshotBrowserDialog, entity, NULL)
34         ATTRIB(XonoticScreenshotList, screenshotPreview, entity, NULL)
35         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
36         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
37         METHOD(XonoticScreenshotList, startSlideShow, void(entity))
38         METHOD(XonoticScreenshotList, stopSlideShow, void(entity))
39 ENDCLASS(XonoticScreenshotList)
40
41 entity makeXonoticScreenshotList();
42 void StartScreenshot_Click(entity btn, entity me);
43 void ScreenshotList_Refresh_Click(entity btn, entity me);
44 void ScreenshotList_Filter_Would_Change(entity box, entity me);
45 void ScreenshotList_Filter_Change(entity box, entity me);
46 #endif
47
48 #ifdef IMPLEMENTATION
49
50 entity makeXonoticScreenshotList()
51 {
52         entity me;
53         me = NEW(XonoticScreenshotList);
54         me.configureXonoticScreenshotList(me);
55         return me;
56 }
57
58 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
59 {
60         me.configureXonoticListBox(me);
61         me.getScreenshots(me);
62 }
63
64 string XonoticScreenshotList_screenshotName(entity me, float i)
65 {
66         string s;
67         s = bufstr_get(me.listScreenshot, i);
68
69         if(substring(s, 0, 1) == "/")
70                 s = substring(s, 1, strlen(s) - 1);  // remove the first forward slash
71
72         return s;
73 }
74
75 // if subdir is true look in subdirectories too (1 level)
76 void getScreenshots_for_ext(entity me, string ext, float subdir)
77 {
78         string s;
79         if (subdir)
80                 s="screenshots/*/";
81         else
82                 s="screenshots/";
83         if(me.filterString)
84                 s=strcat(s, me.filterString, ext);
85         else
86                 s=strcat(s, "*", ext);
87
88         float list, i, n;
89         list = search_begin(s, false, true);
90         if(list >= 0)
91         {
92                 n = search_getsize(list);
93                 for(i = 0; i < n; ++i)
94                 {
95                         s = search_getfilename(list, i); // get initial full file name
96                         s = substring(s, 12, (strlen(s) - 12 - 4)); // remove "screenshots/" prefix and ".<ext>" suffix
97                         s = strdecolorize(s); // remove any pre-existing colors
98                         if(subdir)
99                         {
100                                 s = strreplace("/", "^7/", s); // clear colors at the forward slash
101                                 s = strcat("/", rgb_to_hexcolor(SKINCOLOR_SCREENSHOTLIST_SUBDIR), s); // add a forward slash for sorting, then color
102                                 bufstr_add(me.listScreenshot, s, true);
103                         }
104                         else { bufstr_add(me.listScreenshot, s, true); }
105                 }
106                 search_end(list);
107         }
108
109         if (subdir)
110                 getScreenshots_for_ext(me, ext, false);
111 }
112
113 void XonoticScreenshotList_getScreenshots(entity me)
114 {
115         if (me.listScreenshot >= 0)
116                 buf_del(me.listScreenshot);
117         me.listScreenshot = buf_create();
118         if (me.listScreenshot < 0)
119         {
120                 me.nItems = 0;
121                 return;
122         }
123         getScreenshots_for_ext(me, ".jpg", true);
124         getScreenshots_for_ext(me, ".tga", true);
125         getScreenshots_for_ext(me, ".png", true);
126         me.nItems = buf_getsize(me.listScreenshot);
127         if(me.nItems > 0)
128                 buf_sort(me.listScreenshot, 128, false);
129 }
130
131 void XonoticScreenshotList_destroy(entity me)
132 {
133         if(me.nItems > 0)
134                 buf_del(me.listScreenshot);
135 }
136
137 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
138 {
139         me.itemAbsSize = '0 0 0';
140         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
141
142         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
143         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
144         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
145
146         me.columnNameOrigin = me.realFontSize.x;
147         me.columnNameSize = 1 - 2 * me.realFontSize.x;
148 }
149
150 void XonoticScreenshotList_setSelected(entity me, float i)
151 {
152         if (me.newSlideShowScreenshotTime)
153                 me.startSlideShow(me);
154         float selectedItem_save = me.selectedItem;
155         SUPER(XonoticScreenshotList).setSelected(me, i);
156         if (me.pressed && me.selectedItem != selectedItem_save)
157         {
158                 // avoid immediate image loading on quick repeated selection changes
159                 me.newScreenshotTime = time + 0.22;
160         }
161         else if (time > me.newScreenshotTime)
162         {
163                 me.newScreenshotTime = 0;
164                 me.previewScreenshot(me); // load the preview on selection change
165         }
166 }
167
168 void XonoticScreenshotList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
169 {
170         string s;
171         if(isSelected)
172                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
173         else if(isFocused)
174         {
175                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
176                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
177         }
178
179         s = me.screenshotName(me,i);
180         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
181         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 1);
182 }
183
184 void XonoticScreenshotList_showNotify(entity me)
185 {
186         me.getScreenshots(me);
187         me.previewScreenshot(me);
188 }
189
190 void ScreenshotList_Refresh_Click(entity btn, entity me)
191 {
192         me.getScreenshots(me);
193         me.setSelected(me, 0); //always select the first element after a list update
194 }
195
196 void ScreenshotList_Filter_Change(entity box, entity me)
197 {
198         if(me.filterString)
199                 strunzone(me.filterString);
200
201         if(box.text != "")
202         {
203                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
204                         me.filterString = strzone(box.text);
205                 else
206                         me.filterString = strzone(strcat("*", box.text, "*"));
207         }
208         else
209                 me.filterString = string_null;
210
211         ScreenshotList_Refresh_Click(world, me);
212 }
213
214 void ScreenshotList_Filter_Would_Change(entity box, entity me)
215 {
216         me.filterBox = box;
217         me.filterTime = time + 0.5;
218 }
219
220 void XonoticScreenshotList_draw(entity me)
221 {
222         if (me.filterTime && time > me.filterTime)
223         {
224                 ScreenshotList_Filter_Change(me.filterBox, me);
225                 me.filterTime = 0;
226         }
227         if (me.newScreenshotTime && time > me.newScreenshotTime)
228         {
229                 me.previewScreenshot(me);
230                 me.newScreenshotTime = 0;
231         }
232         else if (me.newSlideShowScreenshotTime && time > me.newSlideShowScreenshotTime)
233         {
234                 if (me.selectedItem == me.nItems - 1) //last screenshot?
235                 {
236                         // restart from the first screenshot
237                         me.setSelected(me, 0);
238                         me.goScreenshot(me, +0);
239                 }
240                 else
241                         me.goScreenshot(me, +1);
242         }
243         SUPER(XonoticScreenshotList).draw(me);
244 }
245
246 void XonoticScreenshotList_startSlideShow(entity me)
247 {
248         me.newSlideShowScreenshotTime = time + 3;
249 }
250
251 void XonoticScreenshotList_stopSlideShow(entity me)
252 {
253         me.newSlideShowScreenshotTime = 0;
254 }
255
256 void XonoticScreenshotList_goScreenshot(entity me, float d)
257 {
258         if(!me.screenshotViewerDialog)
259                 return;
260         me.setSelected(me, me.selectedItem + d);
261         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
262 }
263
264 void XonoticScreenshotList_startScreenshot(entity me)
265 {
266         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
267         // pop up screenshot
268         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
269 }
270
271 void XonoticScreenshotList_previewScreenshot(entity me)
272 {
273         if(!me.screenshotBrowserDialog)
274                 return;
275         if (me.nItems <= 0)
276                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
277         else
278                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
279 }
280
281 void StartScreenshot_Click(entity btn, entity me)
282 {
283         me.startScreenshot(me);
284 }
285
286 void XonoticScreenshotList_doubleClickListBoxItem(entity me, float i, vector where)
287 {
288         me.startScreenshot(me);
289 }
290
291 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
292 {
293         if(scan == K_ENTER || scan == K_KP_ENTER || scan == K_MOUSE2 || scan == K_SPACE) {
294                 me.startScreenshot(me);
295                 return 1;
296         }
297         return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
298 }
299 #endif