qcsrc/menu/xonotic/screenshotlist.qc

   1 #ifdef INTERFACE
   2 CLASS(XonoticScreenshotList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
   4         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
   5         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticScreenshotList, setSelected, void(entity, float))
   7         METHOD(XonoticScreenshotList, draw, void(entity))
   8         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, float, vector, float))
   9         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
  10         METHOD(XonoticScreenshotList, previewScreenshot, void(entity))
  11         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
  12         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
  13         METHOD(XonoticScreenshotList, doubleClickListBoxItem, void(entity, float, vector))
  14         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
  15         METHOD(XonoticScreenshotList, destroy, void(entity))
  16         METHOD(XonoticScreenshotList, showNotify, void(entity))
  17         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
  18         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
  19         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
  20         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
  21         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
  22         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
  23         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
  24         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
  25         ATTRIB(XonoticScreenshotList, filterBox, entity, NULL)
  26         ATTRIB(XonoticScreenshotList, filterTime, float, 0)
  27
  28         ATTRIB(XonoticScreenshotList, newScreenshotTime, float, 0)
  29         ATTRIB(XonoticScreenshotList, newSlideShowScreenshotTime, float, 0)
  30         ATTRIB(XonoticScreenshotList, prevSelectedItem, float, 0)
  31
  32         ATTRIB(XonoticScreenshotList, screenshotBrowserDialog, entity, NULL)
  33         ATTRIB(XonoticScreenshotList, screenshotPreview, entity, NULL)
  34         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
  35         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
  36         METHOD(XonoticScreenshotList, startSlideShow, void(entity))
  37         METHOD(XonoticScreenshotList, stopSlideShow, void(entity))
  38 ENDCLASS(XonoticScreenshotList)
  39
  40 entity makeXonoticScreenshotList();
  41 void StartScreenshot_Click(entity btn, entity me);
  42 void ScreenshotList_Refresh_Click(entity btn, entity me);
  43 void ScreenshotList_Filter_Would_Change(entity box, entity me);
  44 void ScreenshotList_Filter_Change(entity box, entity me);
  45 #endif
  46
  47 #ifdef IMPLEMENTATION
  48
  49 entity makeXonoticScreenshotList()
  50 {
  51         entity me;
  52         me = spawnXonoticScreenshotList();
  53         me.configureXonoticScreenshotList(me);
  54         return me;
  55 }
  56
  57 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  58 {
  59         me.configureXonoticListBox(me);
  60         me.getScreenshots(me);
  61 }
  62
  63 string XonoticScreenshotList_screenshotName(entity me, float i)
  64 {
  65         string s;
  66         s = bufstr_get(me.listScreenshot, i);
  67
  68         if(substring(s, 0, 1) == "/")
  69                 s = substring(s, 1, strlen(s) - 1);  // remove the first forward slash
  70
  71         return s;
  72 }
  73
  74 // if subdir is true look in subdirectories too (1 level)
  75 void getScreenshots_for_ext(entity me, string ext, float subdir)
  76 {
  77         string s;
  78         if (subdir)
  79                 s="screenshots/*/";
  80         else
  81                 s="screenshots/";
  82         if(me.filterString)
  83                 s=strcat(s, me.filterString, ext);
  84         else
  85                 s=strcat(s, "*", ext);
  86
  87         float list, i, n;
  88         list = search_begin(s, false, true);
  89         if(list >= 0)
  90         {
  91                 n = search_getsize(list);
  92                 for(i = 0; i < n; ++i)
  93                 {
  94                         s = search_getfilename(list, i); // get initial full file name
  95                         s = substring(s, 12, (strlen(s) - 12 - 4)); // remove "screenshots/" prefix and ".<ext>" suffix
  96                         s = strdecolorize(s); // remove any pre-existing colors
  97                         if(subdir)
  98                         {
  99                                 s = strreplace("/", "^7/", s); // clear colors at the forward slash
 100                                 s = strcat("/", rgb_to_hexcolor(SKINCOLOR_SCREENSHOTLIST_SUBDIR), s); // add a forward slash for sorting, then color
 101                                 bufstr_add(me.listScreenshot, s, true);
 102                         }
 103                         else { bufstr_add(me.listScreenshot, s, true); }
 104                 }
 105                 search_end(list);
 106         }
 107
 108         if (subdir)
 109                 getScreenshots_for_ext(me, ext, false);
 110 }
 111
 112 void XonoticScreenshotList_getScreenshots(entity me)
 113 {
 114         if (me.listScreenshot >= 0)
 115                 buf_del(me.listScreenshot);
 116         me.listScreenshot = buf_create();
 117         if (me.listScreenshot < 0)
 118         {
 119                 me.nItems = 0;
 120                 return;
 121         }
 122         getScreenshots_for_ext(me, ".jpg", true);
 123         getScreenshots_for_ext(me, ".tga", true);
 124         getScreenshots_for_ext(me, ".png", true);
 125         me.nItems = buf_getsize(me.listScreenshot);
 126         if(me.nItems > 0)
 127                 buf_sort(me.listScreenshot, 128, false);
 128 }
 129
 130 void XonoticScreenshotList_destroy(entity me)
 131 {
 132         if(me.nItems > 0)
 133                 buf_del(me.listScreenshot);
 134 }
 135
 136 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 137 {
 138         me.itemAbsSize = '0 0 0';
 139         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 140
 141         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 142         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 143         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 144
 145         me.columnNameOrigin = me.realFontSize.x;
 146         me.columnNameSize = 1 - 2 * me.realFontSize.x;
 147 }
 148
 149 void XonoticScreenshotList_setSelected(entity me, float i)
 150 {
 151         if (me.newSlideShowScreenshotTime)
 152                 me.startSlideShow(me);
 153         me.prevSelectedItem = me.selectedItem;
 154         SUPER(XonoticScreenshotList).setSelected(me, i);
 155         if (me.pressed && me.selectedItem != me.prevSelectedItem)
 156         {
 157                 // while dragging the scrollbar (or an item)
 158                 // for a smooth mouse movement do not load immediately the new selected images
 159                 me.newScreenshotTime = time + 0.22; // dragging an item we need a delay > 0.2 (from listbox: me.dragScrollTimer = time + 0.2;)
 160         }
 161         else if (time > me.newScreenshotTime)
 162         {
 163                 me.newScreenshotTime = 0;
 164                 me.previewScreenshot(me); // load the preview on selection change
 165         }
 166 }
 167
 168 void XonoticScreenshotList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 169 {
 170         string s;
 171         if(isSelected)
 172                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 173
 174         s = me.screenshotName(me,i);
 175         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 176         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 1);
 177 }
 178
 179 void XonoticScreenshotList_showNotify(entity me)
 180 {
 181         me.getScreenshots(me);
 182         me.previewScreenshot(me);
 183 }
 184
 185 void ScreenshotList_Refresh_Click(entity btn, entity me)
 186 {
 187         me.getScreenshots(me);
 188         me.setSelected(me, 0); //always select the first element after a list update
 189 }
 190
 191 void ScreenshotList_Filter_Change(entity box, entity me)
 192 {
 193         if(me.filterString)
 194                 strunzone(me.filterString);
 195
 196         if(box.text != "")
 197         {
 198                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 199                         me.filterString = strzone(box.text);
 200                 else
 201                         me.filterString = strzone(strcat("*", box.text, "*"));
 202         }
 203         else
 204                 me.filterString = string_null;
 205
 206         ScreenshotList_Refresh_Click(world, me);
 207 }
 208
 209 void ScreenshotList_Filter_Would_Change(entity box, entity me)
 210 {
 211         me.filterBox = box;
 212         me.filterTime = time + 0.5;
 213 }
 214
 215 void XonoticScreenshotList_draw(entity me)
 216 {
 217         if (me.filterTime && time > me.filterTime)
 218         {
 219                 ScreenshotList_Filter_Change(me.filterBox, me);
 220                 me.filterTime = 0;
 221         }
 222         if (me.newScreenshotTime && time > me.newScreenshotTime)
 223         {
 224                 me.previewScreenshot(me);
 225                 me.newScreenshotTime = 0;
 226         }
 227         else if (me.newSlideShowScreenshotTime && time > me.newSlideShowScreenshotTime)
 228         {
 229                 if (me.selectedItem == me.nItems - 1) //last screenshot?
 230                 {
 231                         // restart from the first screenshot
 232                         me.setSelected(me, 0);
 233                         me.goScreenshot(me, +0);
 234                 }
 235                 else
 236                         me.goScreenshot(me, +1);
 237         }
 238         SUPER(XonoticScreenshotList).draw(me);
 239 }
 240
 241 void XonoticScreenshotList_startSlideShow(entity me)
 242 {
 243         me.newSlideShowScreenshotTime = time + 3;
 244 }
 245
 246 void XonoticScreenshotList_stopSlideShow(entity me)
 247 {
 248         me.newSlideShowScreenshotTime = 0;
 249 }
 250
 251 void XonoticScreenshotList_goScreenshot(entity me, float d)
 252 {
 253         if(!me.screenshotViewerDialog)
 254                 return;
 255         me.setSelected(me, me.selectedItem + d);
 256         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 257 }
 258
 259 void XonoticScreenshotList_startScreenshot(entity me)
 260 {
 261         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 262         // pop up screenshot
 263         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
 264 }
 265
 266 void XonoticScreenshotList_previewScreenshot(entity me)
 267 {
 268         if(!me.screenshotBrowserDialog)
 269                 return;
 270         if (me.nItems <= 0)
 271                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
 272         else
 273                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", strdecolorize(me.screenshotName(me,me.selectedItem))));
 274 }
 275
 276 void StartScreenshot_Click(entity btn, entity me)
 277 {
 278         me.startScreenshot(me);
 279 }
 280
 281 void XonoticScreenshotList_doubleClickListBoxItem(entity me, float i, vector where)
 282 {
 283         me.startScreenshot(me);
 284 }
 285
 286 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 287 {
 288         if(scan == K_ENTER || scan == K_KP_ENTER || scan == K_MOUSE2 || scan == K_SPACE) {
 289                 me.startScreenshot(me);
 290                 return 1;
 291         }
 292         if(scan == K_MWHEELUP || scan == K_MWHEELDOWN)
 293                 me.newScreenshotTime = time + 0.2;
 294         return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 295 }
 296 #endif