qcsrc/menu/xonotic/serverlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticServerList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticServerList, configureXonoticServerList, void(entity))
   4         ATTRIB(XonoticServerList, rowsPerItem, float, 1)
   5         METHOD(XonoticServerList, draw, void(entity))
   6         METHOD(XonoticServerList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticServerList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(XonoticServerList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(XonoticServerList, keyDown, float(entity, float, float, float))
  10         METHOD(XonoticServerList, toggleFavorite, void(entity, string))
  11
  12         ATTRIB(XonoticServerList, iconsSizeFactor, float, 0.85)
  13
  14         ATTRIB(XonoticServerList, realFontSize, vector, '0 0 0')
  15         ATTRIB(XonoticServerList, realUpperMargin, float, 0)
  16         ATTRIB(XonoticServerList, columnIconsOrigin, float, 0)
  17         ATTRIB(XonoticServerList, columnIconsSize, float, 0)
  18         ATTRIB(XonoticServerList, columnPingOrigin, float, 0)
  19         ATTRIB(XonoticServerList, columnPingSize, float, 0)
  20         ATTRIB(XonoticServerList, columnNameOrigin, float, 0)
  21         ATTRIB(XonoticServerList, columnNameSize, float, 0)
  22         ATTRIB(XonoticServerList, columnMapOrigin, float, 0)
  23         ATTRIB(XonoticServerList, columnMapSize, float, 0)
  24         ATTRIB(XonoticServerList, columnTypeOrigin, float, 0)
  25         ATTRIB(XonoticServerList, columnTypeSize, float, 0)
  26         ATTRIB(XonoticServerList, columnPlayersOrigin, float, 0)
  27         ATTRIB(XonoticServerList, columnPlayersSize, float, 0)
  28
  29         ATTRIB(XonoticServerList, selectedServer, string, string_null) // to restore selected server when needed
  30         METHOD(XonoticServerList, setSelected, void(entity, float))
  31         METHOD(XonoticServerList, setSortOrder, void(entity, float, float))
  32         ATTRIB(XonoticServerList, filterShowEmpty, float, 1)
  33         ATTRIB(XonoticServerList, filterShowFull, float, 1)
  34         ATTRIB(XonoticServerList, filterString, string, string_null)
  35         ATTRIB(XonoticServerList, controlledTextbox, entity, NULL)
  36         ATTRIB(XonoticServerList, ipAddressBox, entity, NULL)
  37         ATTRIB(XonoticServerList, favoriteButton, entity, NULL)
  38         ATTRIB(XonoticServerList, nextRefreshTime, float, 0)
  39         METHOD(XonoticServerList, refreshServerList, void(entity, float)) // refresh mode: REFRESHSERVERLIST_*
  40         ATTRIB(XonoticServerList, needsRefresh, float, 1)
  41         METHOD(XonoticServerList, focusEnter, void(entity))
  42         METHOD(XonoticServerList, positionSortButton, void(entity, entity, float, float, string, void(entity, entity)))
  43         ATTRIB(XonoticServerList, sortButton1, entity, NULL)
  44         ATTRIB(XonoticServerList, sortButton2, entity, NULL)
  45         ATTRIB(XonoticServerList, sortButton3, entity, NULL)
  46         ATTRIB(XonoticServerList, sortButton4, entity, NULL)
  47         ATTRIB(XonoticServerList, sortButton5, entity, NULL)
  48         ATTRIB(XonoticServerList, connectButton, entity, NULL)
  49         ATTRIB(XonoticServerList, infoButton, entity, NULL)
  50         ATTRIB(XonoticServerList, currentSortOrder, float, 0)
  51         ATTRIB(XonoticServerList, currentSortField, float, -1)
  52         ATTRIB(XonoticServerList, lastBumpSelectTime, float, 0)
  53         ATTRIB(XonoticServerList, lastClickedServer, float, -1)
  54         ATTRIB(XonoticServerList, lastClickedTime, float, 0)
  55
  56         ATTRIB(XonoticServerList, ipAddressBoxFocused, float, -1)
  57
  58         ATTRIB(XonoticServerList, seenIPv4, float, 0)
  59         ATTRIB(XonoticServerList, seenIPv6, float, 0)
  60         ATTRIB(XonoticServerList, categoriesHeight, float, 1.5)
  61
  62         METHOD(XonoticServerList, getTotalHeight, float(entity))
  63         METHOD(XonoticServerList, getItemAtPos, float(entity, float))
  64         METHOD(XonoticServerList, getItemStart, float(entity, float))
  65         METHOD(XonoticServerList, getItemHeight, float(entity, float))
  66 ENDCLASS(XonoticServerList)
  67 entity makeXonoticServerList();
  68
  69 #ifndef IMPLEMENTATION
  70 var float autocvar_menu_slist_categories = TRUE;
  71 var float autocvar_menu_slist_categories_onlyifmultiple = TRUE;
  72 var float autocvar_menu_slist_purethreshold = 10;
  73 var float autocvar_menu_slist_modimpurity = 10;
  74 var float autocvar_menu_slist_recommendations = 2;
  75 var float autocvar_menu_slist_recommendations_maxping = 150;
  76 var float autocvar_menu_slist_recommendations_minfreeslots = 1;
  77 var float autocvar_menu_slist_recommendations_minhumans = 1;
  78 var float autocvar_menu_slist_recommendations_purethreshold = -1;
  79 //var string autocvar_menu_slist_recommended = "76.124.107.5:26004";
  80
  81 // server cache fields
  82 #define SLIST_FIELDS \
  83         SLIST_FIELD(CNAME,       "cname") \
  84         SLIST_FIELD(PING,        "ping") \
  85         SLIST_FIELD(GAME,        "game") \
  86         SLIST_FIELD(MOD,         "mod") \
  87         SLIST_FIELD(MAP,         "map") \
  88         SLIST_FIELD(NAME,        "name") \
  89         SLIST_FIELD(MAXPLAYERS,  "maxplayers") \
  90         SLIST_FIELD(NUMPLAYERS,  "numplayers") \
  91         SLIST_FIELD(NUMHUMANS,   "numhumans") \
  92         SLIST_FIELD(NUMBOTS,     "numbots") \
  93         SLIST_FIELD(PROTOCOL,    "protocol") \
  94         SLIST_FIELD(FREESLOTS,   "freeslots") \
  95         SLIST_FIELD(PLAYERS,     "players") \
  96         SLIST_FIELD(QCSTATUS,    "qcstatus") \
  97         SLIST_FIELD(CATEGORY,    "category") \
  98         SLIST_FIELD(ISFAVORITE,  "isfavorite")
  99
 100 #define SLIST_FIELD(suffix,name) float SLIST_FIELD_##suffix;
 101 SLIST_FIELDS
 102 #undef SLIST_FIELD
 103
 104 const float REFRESHSERVERLIST_RESORT = 0;    // sort the server list again to update for changes to e.g. favorite status, categories
 105 const float REFRESHSERVERLIST_REFILTER = 1;  // ..., also update filter and sort criteria
 106 const float REFRESHSERVERLIST_ASK = 2;       // ..., also suggest querying servers now
 107 const float REFRESHSERVERLIST_RESET = 3;     // ..., also clear the list first
 108
 109 // function declarations
 110 entity RetrieveCategoryEnt(float catnum);
 111
 112 float IsServerInList(string list, string srv);
 113 #define IsFavorite(srv) IsServerInList(cvar_string("net_slist_favorites"), srv)
 114 #define IsRecommended(srv) IsServerInList(_Nex_ExtResponseSystem_RecommendedServers, srv)
 115
 116 float CheckCategoryOverride(float cat);
 117 float CheckCategoryForEntry(float entry);
 118 float m_gethostcachecategory(float entry) { return CheckCategoryOverride(CheckCategoryForEntry(entry)); }
 119
 120 void RegisterSLCategories();
 121
 122 void ServerList_Connect_Click(entity btn, entity me);
 123 void ServerList_Categories_Click(entity box, entity me);
 124 void ServerList_ShowEmpty_Click(entity box, entity me);
 125 void ServerList_ShowFull_Click(entity box, entity me);
 126 void ServerList_Filter_Change(entity box, entity me);
 127 void ServerList_Favorite_Click(entity btn, entity me);
 128 void ServerList_Info_Click(entity btn, entity me);
 129 void ServerList_Update_favoriteButton(entity btn, entity me);
 130
 131 // fields for category entities
 132 #define MAX_CATEGORIES 9
 133 #define CATEGORY_FIRST 1
 134 entity categories[MAX_CATEGORIES];
 135 float category_ent_count;
 136 .string cat_name;
 137 .string cat_string;
 138 .string cat_enoverride_string;
 139 .string cat_dioverride_string;
 140 .float cat_enoverride;
 141 .float cat_dioverride;
 142
 143 // fields for drawing categories
 144 float category_name[MAX_CATEGORIES];
 145 float category_item[MAX_CATEGORIES];
 146 float category_draw_count;
 147
 148 #define SLIST_CATEGORIES \
 149         SLIST_CATEGORY(CAT_FAVORITED,    "",            "",             ZCTX(_("SLCAT^Favorites"))) \
 150         SLIST_CATEGORY(CAT_RECOMMENDED,  "",            "CAT_SERVERS",  ZCTX(_("SLCAT^Recommended"))) \
 151         SLIST_CATEGORY(CAT_NORMAL,       "",            "CAT_SERVERS",  ZCTX(_("SLCAT^Normal Servers"))) \
 152         SLIST_CATEGORY(CAT_SERVERS,      "CAT_NORMAL",  "CAT_SERVERS",  ZCTX(_("SLCAT^Servers"))) \
 153         SLIST_CATEGORY(CAT_XPM,          "CAT_NORMAL",  "CAT_SERVERS",  ZCTX(_("SLCAT^Competitive Mode"))) \
 154         SLIST_CATEGORY(CAT_MODIFIED,     "",            "CAT_SERVERS",  ZCTX(_("SLCAT^Modified Servers"))) \
 155         SLIST_CATEGORY(CAT_OVERKILL,     "",            "CAT_SERVERS",  ZCTX(_("SLCAT^Overkill Mode"))) \
 156         SLIST_CATEGORY(CAT_MINSTAGIB,    "",            "CAT_SERVERS",  ZCTX(_("SLCAT^MinstaGib Mode"))) \
 157         SLIST_CATEGORY(CAT_DEFRAG,       "",            "CAT_SERVERS",  ZCTX(_("SLCAT^Defrag Mode")))
 158
 159 #define SLIST_CATEGORY_AUTOCVAR(name) autocvar_menu_slist_categories_##name##_override
 160 #define SLIST_CATEGORY(name,enoverride,dioverride,str) \
 161         float name; \
 162         var string SLIST_CATEGORY_AUTOCVAR(name) = enoverride;
 163 SLIST_CATEGORIES
 164 #undef SLIST_CATEGORY
 165
 166 #endif
 167 #endif
 168 #ifdef IMPLEMENTATION
 169
 170 void RegisterSLCategories()
 171 {
 172         entity cat;
 173         #define SLIST_CATEGORY(name,enoverride,dioverride,str) \
 174                 SET_FIELD_COUNT(name, CATEGORY_FIRST, category_ent_count) \
 175                 CHECK_MAX_COUNT(name, MAX_CATEGORIES, category_ent_count, "SLIST_CATEGORY") \
 176                 cat = spawn(); \
 177                 categories[name - 1] = cat; \
 178                 cat.classname = "slist_category"; \
 179                 cat.cat_name = strzone(#name); \
 180                 cat.cat_enoverride_string = strzone(SLIST_CATEGORY_AUTOCVAR(name)); \
 181                 cat.cat_dioverride_string = strzone(dioverride); \
 182                 cat.cat_string = strzone(str);
 183         SLIST_CATEGORIES
 184         #undef SLIST_CATEGORY
 185
 186         float i, x, catnum;
 187         string s;
 188
 189         #define PROCESS_OVERRIDE(override_string,override_field) \
 190                 for(i = 0; i < category_ent_count; ++i) \
 191                 { \
 192                         s = categories[i].override_string; \
 193                         if((s != "") && (s != categories[i].cat_name)) \
 194                         { \
 195                                 catnum = 0; \
 196                                 for(x = 0; x < category_ent_count; ++x) \
 197                                 { if(categories[x].cat_name == s) { \
 198                                         catnum = (x+1); \
 199                                         break; \
 200                                 } } \
 201                                 if(catnum) \
 202                                 { \
 203                                         strunzone(categories[i].override_string); \
 204                                         categories[i].override_field = catnum; \
 205                                         continue; \
 206                                 } \
 207                                 else \
 208                                 { \
 209                                         print(sprintf( \
 210                                                 "RegisterSLCategories(): Improper override '%s' for category '%s'!\n", \
 211                                                 s, \
 212                                                 categories[i].cat_name \
 213                                         )); \
 214                                 } \
 215                         } \
 216                         strunzone(categories[i].override_string); \
 217                         categories[i].override_field = 0; \
 218                 }
 219         PROCESS_OVERRIDE(cat_enoverride_string, cat_enoverride)
 220         PROCESS_OVERRIDE(cat_dioverride_string, cat_dioverride)
 221         #undef PROCESS_OVERRIDE
 222 }
 223
 224 // Supporting Functions
 225 entity RetrieveCategoryEnt(float catnum)
 226 {
 227         if((catnum > 0) && (catnum <= category_ent_count))
 228         {
 229                 return categories[catnum - 1];
 230         }
 231         else
 232         {
 233                 error(sprintf("RetrieveCategoryEnt(%d): Improper category number!\n", catnum));
 234                 return world;
 235         }
 236 }
 237
 238 float IsServerInList(string list, string srv)
 239 {
 240         string p;
 241         float i, n;
 242         if(srv == "")
 243                 return FALSE;
 244         srv = netaddress_resolve(srv, 26000);
 245         if(srv == "")
 246                 return FALSE;
 247         p = crypto_getidfp(srv);
 248         n = tokenize_console(list);
 249         for(i = 0; i < n; ++i)
 250         {
 251                 if(substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
 252                 {
 253                         if(p)
 254                                 if(argv(i) == p)
 255                                         return TRUE;
 256                 }
 257                 else
 258                 {
 259                         if(srv == netaddress_resolve(argv(i), 26000))
 260                                 return TRUE;
 261                 }
 262         }
 263         return FALSE;
 264 }
 265
 266 float CheckCategoryOverride(float cat)
 267 {
 268         entity catent = RetrieveCategoryEnt(cat);
 269         if(catent)
 270         {
 271                 float override = (autocvar_menu_slist_categories ? catent.cat_enoverride : catent.cat_dioverride);
 272                 if(override) { return override; }
 273                 else { return cat; }
 274         }
 275         else
 276         {
 277                 error(sprintf("CheckCategoryOverride(%d): Improper category number!\n", cat));
 278                 return cat;
 279         }
 280 }
 281
 282 float CheckCategoryForEntry(float entry)
 283 {
 284         string s, k, v, modtype = "";
 285         float j, m, impure = 0, freeslots = 0, sflags = 0;
 286         s = gethostcachestring(SLIST_FIELD_QCSTATUS, entry);
 287         m = tokenizebyseparator(s, ":");
 288
 289         for(j = 2; j < m; ++j)
 290         {
 291                 if(argv(j) == "") { break; }
 292                 k = substring(argv(j), 0, 1);
 293                 v = substring(argv(j), 1, -1);
 294                 switch(k)
 295                 {
 296                         case "P": { impure = stof(v); break; }
 297                         case "S": { freeslots = stof(v); break; }
 298                         case "F": { sflags = stof(v); break; }
 299                         case "M": { modtype = strtolower(v); break; }
 300                 }
 301         }
 302
 303         if(modtype != "xonotic") { impure += autocvar_menu_slist_modimpurity; }
 304
 305         // check if this server is favorited
 306         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, entry)) { return CAT_FAVORITED; }
 307
 308         // now check if it's recommended
 309         if(autocvar_menu_slist_recommendations)
 310         {
 311                 float recommended = 0;
 312                 if(autocvar_menu_slist_recommendations & 1)
 313                 {
 314                         if(IsRecommended(gethostcachestring(SLIST_FIELD_CNAME, entry)))
 315                                 { ++recommended; }
 316                         else
 317                                 { --recommended; }
 318                 }
 319                 if(autocvar_menu_slist_recommendations & 2)
 320                 {
 321                         if(
 322                                 (freeslots >= autocvar_menu_slist_recommendations_minfreeslots)
 323                                 &&
 324                                 (
 325                                         (autocvar_menu_slist_recommendations_purethreshold < 0)
 326                                         ||
 327                                         (impure <= autocvar_menu_slist_recommendations_purethreshold)
 328                                 )
 329                                 &&
 330                                 (
 331                                         gethostcachenumber(SLIST_FIELD_NUMHUMANS, entry)
 332                                         >=
 333                                         autocvar_menu_slist_recommendations_minhumans
 334                                 )
 335                                 &&
 336                                 (
 337                                         gethostcachenumber(SLIST_FIELD_PING, entry)
 338                                         <=
 339                                         autocvar_menu_slist_recommendations_maxping
 340                                 )
 341                         )
 342                                 { ++recommended; }
 343                         else
 344                                 { --recommended; }
 345                 }
 346                 if(recommended > 0) { return CAT_RECOMMENDED; }
 347         }
 348
 349         // if not favorited or recommended, check modname
 350         if(modtype != "xonotic")
 351         {
 352                 switch(modtype)
 353                 {
 354                         // old servers which don't report their mod name are considered modified now
 355                         case "": { return CAT_MODIFIED; }
 356
 357                         case "xpm": { return CAT_XPM; }
 358                         case "minstagib": { return CAT_MINSTAGIB; }
 359                         case "overkill": { return CAT_OVERKILL; }
 360                         //case "nix": { return CAT_NIX; }
 361                         //case "newtoys": { return CAT_NEWTOYS; }
 362
 363                         // "cts" is allowed as compat, xdf is replacement
 364                         case "cts":
 365                         case "xdf": { return CAT_DEFRAG; }
 366
 367                         default: { dprint(sprintf("Found strange mod type: %s\n", modtype)); return CAT_MODIFIED; }
 368                 }
 369         }
 370
 371         // must be normal or impure server
 372         return ((impure > autocvar_menu_slist_purethreshold) ? CAT_MODIFIED : CAT_NORMAL);
 373 }
 374
 375 float CheckItemNumber(float num)
 376 {
 377         float i, n;
 378
 379         if not(category_draw_count) { return num; } // there are no categories to process
 380
 381         for(i = 0, n = 1; n <= category_draw_count; ++i, ++n)
 382         {
 383                 if(category_item[i] == (num - i)) { return -category_name[i]; }
 384                 else if(n == category_draw_count) { return (num - n); }
 385                 else if((num - i) <= category_item[n]) { return (num - n); }
 386         }
 387
 388         // should never hit this point
 389         error(sprintf("CheckItemNumber(%d): Function fell through without normal return!\n", num));
 390         return FALSE;
 391 }
 392
 393 void XonoticServerList_toggleFavorite(entity me, string srv)
 394 {
 395         string s, s0, s1, s2, srv_resolved, p;
 396         float i, n, f;
 397         srv_resolved = netaddress_resolve(srv, 26000);
 398         p = crypto_getidfp(srv_resolved);
 399         s = cvar_string("net_slist_favorites");
 400         n = tokenize_console(s);
 401         f = 0;
 402         for(i = 0; i < n; ++i)
 403         {
 404                 if(substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
 405                 {
 406                         if(p)
 407                                 if(argv(i) != p)
 408                                         continue;
 409                 }
 410                 else
 411                 {
 412                         if(srv_resolved != netaddress_resolve(argv(i), 26000))
 413                                 continue;
 414                 }
 415                 s0 = s1 = s2 = "";
 416                 if(i > 0)
 417                         s0 = substring(s, 0, argv_end_index(i - 1));
 418                 if(i < n-1)
 419                         s2 = substring(s, argv_start_index(i + 1), -1);
 420                 if(s0 != "" && s2 != "")
 421                         s1 = " ";
 422                 cvar_set("net_slist_favorites", strcat(s0, s1, s2));
 423                 s = cvar_string("net_slist_favorites");
 424                 n = tokenize_console(s);
 425                 f = 1;
 426                 --i;
 427         }
 428
 429         if(!f)
 430         {
 431                 s1 = "";
 432                 if(s != "")
 433                         s1 = " ";
 434                 if(p)
 435                         cvar_set("net_slist_favorites", strcat(s, s1, p));
 436                 else
 437                         cvar_set("net_slist_favorites", strcat(s, s1, srv));
 438         }
 439
 440         me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 441 }
 442
 443 void ServerList_Update_favoriteButton(entity btn, entity me)
 444 {
 445         me.favoriteButton.setText(me.favoriteButton,
 446                 (IsFavorite(me.ipAddressBox.text) ?
 447                         _("Remove") : _("Bookmark")
 448                 )
 449         );
 450 }
 451
 452 entity makeXonoticServerList()
 453 {
 454         entity me;
 455         me = spawnXonoticServerList();
 456         me.configureXonoticServerList(me);
 457         return me;
 458 }
 459 void XonoticServerList_configureXonoticServerList(entity me)
 460 {
 461         me.configureXonoticListBox(me);
 462
 463         // update field ID's
 464         #define SLIST_FIELD(suffix,name) SLIST_FIELD_##suffix = gethostcacheindexforkey(name);
 465         SLIST_FIELDS
 466         #undef SLIST_FIELD
 467
 468         // clear list
 469         me.nItems = 0;
 470 }
 471 void XonoticServerList_setSelected(entity me, float i)
 472 {
 473         // todo: add logic to skip categories
 474         float save, num;
 475         save = me.selectedItem;
 476         SUPER(XonoticServerList).setSelected(me, i);
 477         /*
 478         if(me.selectedItem == save)
 479                 return;
 480         */
 481         if(me.nItems == 0)
 482                 return;
 483
 484         //if(gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT) != CheckItemNumber(me.nItems))
 485         //      { error("^1XonoticServerList_setSelected(); ERROR: ^7Host cache viewcount mismatches nItems!\n"); return; } // sorry, it would be wrong
 486         // ^ todo: make this work somehow?
 487
 488         #define SET_SELECTED_SERVER(cachenum) \
 489                 if(me.selectedServer) { strunzone(me.selectedServer); } \
 490                 me.selectedServer = strzone(gethostcachestring(SLIST_FIELD_CNAME, cachenum)); \
 491                 me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer); \
 492                 me.ipAddressBox.cursorPos = strlen(me.selectedServer); \
 493                 me.ipAddressBoxFocused = -1; \
 494                 return;
 495
 496         num = CheckItemNumber(me.selectedItem);
 497
 498         if(num >= 0) { SET_SELECTED_SERVER(num); }
 499         else if(save > me.selectedItem)
 500         {
 501                 if(me.selectedItem == 0) { return; }
 502                 else
 503                 {
 504                         if(me.lastClickedTime >= me.lastBumpSelectTime)
 505                         {
 506                                 SUPER(XonoticServerList).setSelected(me, me.selectedItem - 1);
 507                                 num = CheckItemNumber(me.selectedItem);
 508                                 if(num >= 0)
 509                                 {
 510                                         me.lastBumpSelectTime = time;
 511                                         SET_SELECTED_SERVER(num);
 512                                 }
 513                         }
 514                 }
 515         }
 516         else if(save < me.selectedItem)
 517         {
 518                 if(me.selectedItem == me.nItems) { return; }
 519                 else
 520                 {
 521                         if(me.lastClickedTime >= me.lastBumpSelectTime)
 522                         {
 523                                 SUPER(XonoticServerList).setSelected(me, me.selectedItem + 1);
 524                                 num = CheckItemNumber(me.selectedItem);
 525                                 if(num >= 0)
 526                                 {
 527                                         me.lastBumpSelectTime = time;
 528                                         SET_SELECTED_SERVER(num);
 529                                 }
 530                         }
 531                 }
 532         }
 533 }
 534
 535 void XonoticServerList_refreshServerList(entity me, float mode)
 536 {
 537         //print("refresh of type ", ftos(mode), "\n");
 538
 539         if(mode >= REFRESHSERVERLIST_REFILTER)
 540         {
 541                 float m, i, n;
 542                 float listflags = 0;
 543                 string s, typestr, modstr;
 544
 545                 s = me.filterString;
 546
 547                 m = strstrofs(s, ":", 0);
 548                 if(m >= 0)
 549                 {
 550                         typestr = substring(s, 0, m);
 551                         s = substring(s, m + 1, strlen(s) - m - 1);
 552                         while(substring(s, 0, 1) == " ")
 553                                 s = substring(s, 1, strlen(s) - 1);
 554                 }
 555                 else
 556                         typestr = "";
 557
 558                 modstr = cvar_string("menu_slist_modfilter");
 559
 560                 m = SLIST_MASK_AND - 1;
 561                 resethostcachemasks();
 562
 563                 // ping: reject negative ping (no idea why this happens in the first place, engine bug)
 564                 sethostcachemasknumber(++m, SLIST_FIELD_PING, 0, SLIST_TEST_GREATEREQUAL);
 565
 566                 // show full button
 567                 if(!me.filterShowFull)
 568                 {
 569                         sethostcachemasknumber(++m, SLIST_FIELD_FREESLOTS, 1, SLIST_TEST_GREATEREQUAL); // legacy
 570                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, ":S0:", SLIST_TEST_NOTCONTAIN); // g_maxplayers support
 571                 }
 572
 573                 // show empty button
 574                 if(!me.filterShowEmpty)
 575                         sethostcachemasknumber(++m, SLIST_FIELD_NUMHUMANS, 1, SLIST_TEST_GREATEREQUAL);
 576
 577                 // gametype filtering
 578                 if(typestr != "")
 579                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(typestr, ":"), SLIST_TEST_STARTSWITH);
 580
 581                 // mod filtering
 582                 if(modstr != "")
 583                 {
 584                         if(substring(modstr, 0, 1) == "!")
 585                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(substring(modstr, 1, strlen(modstr) - 1)), SLIST_TEST_NOTEQUAL);
 586                         else
 587                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(modstr), SLIST_TEST_EQUAL);
 588                 }
 589
 590                 // server banning
 591                 n = tokenizebyseparator(_Nex_ExtResponseSystem_BannedServers, " ");
 592                 for(i = 0; i < n; ++i)
 593                         if(argv(i) != "")
 594                                 sethostcachemaskstring(++m, SLIST_FIELD_CNAME, argv(i), SLIST_TEST_NOTSTARTSWITH);
 595
 596                 m = SLIST_MASK_OR - 1;
 597                 if(s != "")
 598                 {
 599                         sethostcachemaskstring(++m, SLIST_FIELD_NAME, s, SLIST_TEST_CONTAINS);
 600                         sethostcachemaskstring(++m, SLIST_FIELD_MAP, s, SLIST_TEST_CONTAINS);
 601                         sethostcachemaskstring(++m, SLIST_FIELD_PLAYERS, s, SLIST_TEST_CONTAINS);
 602                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(s, ":"), SLIST_TEST_STARTSWITH);
 603                 }
 604
 605                 // sorting flags
 606                 //listflags |= SLSF_FAVORITES;
 607                 listflags |= SLSF_CATEGORIES;
 608                 if(me.currentSortOrder < 0) { listflags |= SLSF_DESCENDING; }
 609                 sethostcachesort(me.currentSortField, listflags);
 610         }
 611
 612         resorthostcache();
 613         if(mode >= REFRESHSERVERLIST_ASK)
 614                 refreshhostcache(mode >= REFRESHSERVERLIST_RESET);
 615 }
 616 void XonoticServerList_focusEnter(entity me)
 617 {
 618         if(time < me.nextRefreshTime)
 619         {
 620                 //print("sorry, no refresh yet\n");
 621                 return;
 622         }
 623         me.nextRefreshTime = time + 10;
 624         me.refreshServerList(me, REFRESHSERVERLIST_ASK);
 625 }
 626
 627 void XonoticServerList_draw(entity me)
 628 {
 629         float i, found, owned, num;
 630
 631         if(_Nex_ExtResponseSystem_BannedServersNeedsRefresh)
 632         {
 633                 if(!me.needsRefresh)
 634                         me.needsRefresh = 2;
 635                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 0;
 636         }
 637
 638         if(_Nex_ExtResponseSystem_RecommendedServersNeedsRefresh)
 639         {
 640                 if(!me.needsRefresh)
 641                         me.needsRefresh = 3;
 642                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 0;
 643         }
 644
 645         if(me.currentSortField == -1)
 646         {
 647                 me.setSortOrder(me, SLIST_FIELD_PING, +1);
 648                 me.refreshServerList(me, REFRESHSERVERLIST_RESET);
 649         }
 650         else if(me.needsRefresh == 1)
 651         {
 652                 me.needsRefresh = 2; // delay by one frame to make sure "slist" has been executed
 653         }
 654         else if(me.needsRefresh == 2)
 655         {
 656                 me.needsRefresh = 0;
 657                 me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 658         }
 659         else if(me.needsRefresh == 3)
 660         {
 661                 me.needsRefresh = 0;
 662                 me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 663         }
 664
 665         owned = ((me.selectedServer == me.ipAddressBox.text) && (me.ipAddressBox.text != ""));
 666
 667         for(i = 0; i < category_draw_count; ++i) { category_name[i] = -1; category_item[i] = -1; }
 668         category_draw_count = 0;
 669
 670         if(autocvar_menu_slist_categories >= 0) // if less than 0, don't even draw a category heading for favorites
 671         {
 672                 float itemcount = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT);
 673                 me.nItems = itemcount;
 674
 675                 //float visible = floor(me.scrollPos / me.itemHeight);
 676                 // ^ unfortunately no such optimization can be made-- we must process through the
 677                 // entire list, otherwise there is no way to know which item is first in its category.
 678
 679                 // binary search method suggested by div
 680                 float x;
 681                 float begin = 0;
 682                 for(x = 1; x <= category_ent_count; ++x) {
 683                         float first = begin;
 684                         float last = (itemcount - 1);
 685                         if (first > last) {
 686                                 // List is empty.
 687                                 break;
 688                         }
 689                         float catf = gethostcachenumber(SLIST_FIELD_CATEGORY, first);
 690                         float catl = gethostcachenumber(SLIST_FIELD_CATEGORY, last);
 691                         if (catf > x) {
 692                                 // The first one is already > x.
 693                                 // Therefore, category x does not exist.
 694                                 // Higher numbered categories do exist though.
 695                         } else if (catl < x) {
 696                                 // The last one is < x.
 697                                 // Thus this category - and any following -
 698                                 // don't exist.
 699                                 break;
 700                         } else if (catf == x) {
 701                                 // Starts at first. This breaks the loop
 702                                 // invariant in the binary search and thus has
 703                                 // to be handled separately.
 704                                 print(sprintf("hit: x='%d', dc='%d', first='%d', last='%d', catf='%d', catl='%d'.\n", x, category_draw_count, first, last, catf, catl));
 705                                 category_name[category_draw_count] = x;
 706                                 category_item[category_draw_count] = first;
 707                                 ++category_draw_count;
 708                                 ++me.nItems;
 709                                 begin = first + 1;
 710                         } else {
 711                                 // At this point, catf <= x < catl, thus
 712                                 // catf < catl, thus first < last.
 713                                 // INVARIANTS:
 714                                 // last - first >= 1
 715                                 // catf == gethostcachenumber(SLIST_FIELD_CATEGORY(first)
 716                                 // catl == gethostcachenumber(SLIST_FIELD_CATEGORY(last)
 717                                 // catf < x
 718                                 // catl >= x
 719                                 while (last - first > 1) {
 720                                         float middle = floor((first + last) / 2);
 721                                         // By loop condition, middle != first && middle != last.
 722                                         float cat = gethostcachenumber(SLIST_FIELD_CATEGORY, middle);
 723                                         if (cat >= x) {
 724                                                 last = middle;
 725                                                 catl = cat;
 726                                         } else {
 727                                                 first = middle;
 728                                                 catf = cat;
 729                                         }
 730                                 }
 731                                 if (catl == x) {
 732                                         print(sprintf("hit: x='%d', dc='%d', first='%d', last='%d', catf='%d', catl='%d'.\n", x, category_draw_count, first, last, catf, catl));
 733                                         category_name[category_draw_count] = x;
 734                                         category_item[category_draw_count] = last;
 735                                         ++category_draw_count;
 736                                         ++me.nItems;
 737                                 }
 738                                 begin = last + 1; // already scanned through these, skip 'em
 739                         }
 740                 }
 741
 742                 if(autocvar_menu_slist_categories_onlyifmultiple && (category_draw_count == 1))
 743                 {
 744                         category_name[0] = -1;
 745                         category_item[0] = -1;
 746                         category_draw_count = 0;
 747                         me.nItems = itemcount;
 748                 }
 749         }
 750         else { me.nItems = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT); }
 751
 752         me.connectButton.disabled = ((me.nItems == 0) && (me.ipAddressBox.text == ""));
 753         me.infoButton.disabled = ((me.nItems == 0) || !owned);
 754         me.favoriteButton.disabled = ((me.nItems == 0) && (me.ipAddressBox.text == ""));
 755
 756         found = 0;
 757         if(me.selectedServer)
 758         {
 759                 for(i = 0; i < me.nItems; ++i)
 760                 {
 761                         num = CheckItemNumber(i);
 762                         if(num >= 0)
 763                         {
 764                                 if(gethostcachestring(SLIST_FIELD_CNAME, num) == me.selectedServer)
 765                                 {
 766                                         if(i != me.selectedItem)
 767                                         {
 768                                                 me.lastClickedServer = -1;
 769                                                 me.selectedItem = i;
 770                                         }
 771                                         found = 1;
 772                                         break;
 773                                 }
 774                         }
 775                 }
 776         }
 777         if(!found)
 778         {
 779                 if(me.nItems > 0)
 780                 {
 781                         if(me.selectedItem >= me.nItems) { me.selectedItem = me.nItems - 1; }
 782                         if(me.selectedServer) { strunzone(me.selectedServer); }
 783
 784                         num = CheckItemNumber(me.selectedItem);
 785                         if(num >= 0) { me.selectedServer = strzone(gethostcachestring(SLIST_FIELD_CNAME, num)); }
 786                 }
 787         }
 788
 789         if(owned)
 790         {
 791                 if(me.selectedServer != me.ipAddressBox.text)
 792                 {
 793                         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
 794                         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
 795                         me.ipAddressBoxFocused = -1;
 796                 }
 797         }
 798
 799         if(me.ipAddressBoxFocused != me.ipAddressBox.focused)
 800         {
 801                 if(me.ipAddressBox.focused || me.ipAddressBoxFocused < 0)
 802                         ServerList_Update_favoriteButton(NULL, me);
 803                 me.ipAddressBoxFocused = me.ipAddressBox.focused;
 804         }
 805
 806         SUPER(XonoticServerList).draw(me);
 807 }
 808 void ServerList_PingSort_Click(entity btn, entity me)
 809 {
 810         me.setSortOrder(me, SLIST_FIELD_PING, +1);
 811 }
 812 void ServerList_NameSort_Click(entity btn, entity me)
 813 {
 814         me.setSortOrder(me, SLIST_FIELD_NAME, -1); // why?
 815 }
 816 void ServerList_MapSort_Click(entity btn, entity me)
 817 {
 818         me.setSortOrder(me, SLIST_FIELD_MAP, -1); // why?
 819 }
 820 void ServerList_PlayerSort_Click(entity btn, entity me)
 821 {
 822         me.setSortOrder(me, SLIST_FIELD_NUMHUMANS, -1);
 823 }
 824 void ServerList_TypeSort_Click(entity btn, entity me)
 825 {
 826         string s, t;
 827         float i, m;
 828         s = me.filterString;
 829         m = strstrofs(s, ":", 0);
 830         if(m >= 0)
 831         {
 832                 s = substring(s, 0, m);
 833                 while(substring(s, m+1, 1) == " ") // skip spaces
 834                         ++m;
 835         }
 836         else
 837                 s = "";
 838
 839         for(i = 1; ; i *= 2) // 20 modes ought to be enough for anyone
 840         {
 841                 t = MapInfo_Type_ToString(i);
 842                 if(i > 1)
 843                         if(t == "") // it repeats (default case)
 844                         {
 845                                 // no type was found
 846                                 // choose the first one
 847                                 s = MapInfo_Type_ToString(1);
 848                                 break;
 849                         }
 850                 if(s == t)
 851                 {
 852                         // the type was found
 853                         // choose the next one
 854                         s = MapInfo_Type_ToString(i * 2);
 855                         if(s == "")
 856                                 s = MapInfo_Type_ToString(1);
 857                         break;
 858                 }
 859         }
 860
 861         if(s != "")
 862                 s = strcat(s, ":");
 863         s = strcat(s, substring(me.filterString, m+1, strlen(me.filterString) - m - 1));
 864
 865         me.controlledTextbox.setText(me.controlledTextbox, s);
 866         me.controlledTextbox.keyDown(me.controlledTextbox, K_END, 0, 0);
 867         me.controlledTextbox.keyUp(me.controlledTextbox, K_END, 0, 0);
 868         //ServerList_Filter_Change(me.controlledTextbox, me);
 869 }
 870 void ServerList_Filter_Change(entity box, entity me)
 871 {
 872         if(me.filterString)
 873                 strunzone(me.filterString);
 874         if(box.text != "")
 875                 me.filterString = strzone(box.text);
 876         else
 877                 me.filterString = string_null;
 878         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 879
 880         me.ipAddressBox.setText(me.ipAddressBox, "");
 881         me.ipAddressBox.cursorPos = 0;
 882         me.ipAddressBoxFocused = -1;
 883 }
 884 void ServerList_Categories_Click(entity box, entity me)
 885 {
 886         box.setChecked(box, autocvar_menu_slist_categories = !autocvar_menu_slist_categories);
 887         me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 888
 889         me.ipAddressBox.setText(me.ipAddressBox, "");
 890         me.ipAddressBox.cursorPos = 0;
 891         me.ipAddressBoxFocused = -1;
 892 }
 893 void ServerList_ShowEmpty_Click(entity box, entity me)
 894 {
 895         box.setChecked(box, me.filterShowEmpty = !me.filterShowEmpty);
 896         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 897
 898         me.ipAddressBox.setText(me.ipAddressBox, "");
 899         me.ipAddressBox.cursorPos = 0;
 900         me.ipAddressBoxFocused = -1;
 901 }
 902 void ServerList_ShowFull_Click(entity box, entity me)
 903 {
 904         box.setChecked(box, me.filterShowFull = !me.filterShowFull);
 905         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 906
 907         me.ipAddressBox.setText(me.ipAddressBox, "");
 908         me.ipAddressBox.cursorPos = 0;
 909         me.ipAddressBoxFocused = -1;
 910 }
 911 void XonoticServerList_setSortOrder(entity me, float fld, float direction)
 912 {
 913         if(me.currentSortField == fld)
 914                 direction = -me.currentSortOrder;
 915         me.currentSortOrder = direction;
 916         me.currentSortField = fld;
 917         me.sortButton1.forcePressed = (fld == SLIST_FIELD_PING);
 918         me.sortButton2.forcePressed = (fld == SLIST_FIELD_NAME);
 919         me.sortButton3.forcePressed = (fld == SLIST_FIELD_MAP);
 920         me.sortButton4.forcePressed = 0;
 921         me.sortButton5.forcePressed = (fld == SLIST_FIELD_NUMHUMANS);
 922         me.selectedItem = 0;
 923         if(me.selectedServer)
 924                 strunzone(me.selectedServer);
 925         me.selectedServer = string_null;
 926         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 927 }
 928 void XonoticServerList_positionSortButton(entity me, entity btn, float theOrigin, float theSize, string theTitle, void(entity, entity) theFunc)
 929 {
 930         vector originInLBSpace, sizeInLBSpace;
 931         originInLBSpace = eY * (-me.itemHeight);
 932         sizeInLBSpace = eY * me.itemHeight + eX * (1 - me.controlWidth);
 933
 934         vector originInDialogSpace, sizeInDialogSpace;
 935         originInDialogSpace = boxToGlobal(originInLBSpace, me.Container_origin, me.Container_size);
 936         sizeInDialogSpace = boxToGlobalSize(sizeInLBSpace, me.Container_size);
 937
 938         btn.Container_origin_x = originInDialogSpace_x + sizeInDialogSpace_x * theOrigin;
 939         btn.Container_size_x   =                         sizeInDialogSpace_x * theSize;
 940         btn.setText(btn, theTitle);
 941         btn.onClick = theFunc;
 942         btn.onClickEntity = me;
 943         btn.resized = 1;
 944 }
 945 void XonoticServerList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 946 {
 947         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 948
 949         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
 950         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
 951         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 952
 953         me.columnIconsOrigin = 0;
 954         me.columnIconsSize = me.realFontSize_x * 4 * me.iconsSizeFactor;
 955         me.columnPingSize = me.realFontSize_x * 3;
 956         me.columnMapSize = me.realFontSize_x * 10;
 957         me.columnTypeSize = me.realFontSize_x * 4;
 958         me.columnPlayersSize = me.realFontSize_x * 5;
 959         me.columnNameSize = 1 - me.columnPlayersSize - me.columnMapSize - me.columnPingSize - me.columnIconsSize - me.columnTypeSize - 5 * me.realFontSize_x;
 960         me.columnPingOrigin = me.columnIconsOrigin + me.columnIconsSize + me.realFontSize_x;
 961         me.columnNameOrigin = me.columnPingOrigin + me.columnPingSize + me.realFontSize_x;
 962         me.columnMapOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize_x;
 963         me.columnTypeOrigin = me.columnMapOrigin + me.columnMapSize + me.realFontSize_x;
 964         me.columnPlayersOrigin = me.columnTypeOrigin + me.columnTypeSize + me.realFontSize_x;
 965
 966         me.positionSortButton(me, me.sortButton1, me.columnPingOrigin, me.columnPingSize, _("Ping"), ServerList_PingSort_Click);
 967         me.positionSortButton(me, me.sortButton2, me.columnNameOrigin, me.columnNameSize, _("Host name"), ServerList_NameSort_Click);
 968         me.positionSortButton(me, me.sortButton3, me.columnMapOrigin, me.columnMapSize, _("Map"), ServerList_MapSort_Click);
 969         me.positionSortButton(me, me.sortButton4, me.columnTypeOrigin, me.columnTypeSize, _("Type"), ServerList_TypeSort_Click);
 970         me.positionSortButton(me, me.sortButton5, me.columnPlayersOrigin, me.columnPlayersSize, _("Players"), ServerList_PlayerSort_Click);
 971
 972         float f;
 973         f = me.currentSortField;
 974         if(f >= 0)
 975         {
 976                 me.currentSortField = -1;
 977                 me.setSortOrder(me, f, me.currentSortOrder); // force resetting the sort order
 978         }
 979 }
 980 void ServerList_Connect_Click(entity btn, entity me)
 981 {
 982         localcmd(sprintf("connect %s\n",
 983                 ((me.ipAddressBox.text != "") ?
 984                         me.ipAddressBox.text : me.selectedServer
 985                 )
 986         ));
 987 }
 988 void ServerList_Favorite_Click(entity btn, entity me)
 989 {
 990         string ipstr;
 991         ipstr = netaddress_resolve(me.ipAddressBox.text, 26000);
 992         if(ipstr != "")
 993         {
 994                 me.toggleFavorite(me, me.ipAddressBox.text);
 995                 me.ipAddressBoxFocused = -1;
 996         }
 997 }
 998 void ServerList_Info_Click(entity btn, entity me)
 999 {
1000         main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, CheckItemNumber(me.selectedItem));
1001         DialogOpenButton_Click(me, main.serverInfoDialog);
1002 }
1003 void XonoticServerList_clickListBoxItem(entity me, float i, vector where)
1004 {
1005         float num = CheckItemNumber(i);
1006         if(num >= 0)
1007         {
1008                 if(num == me.lastClickedServer)
1009                         if(time < me.lastClickedTime + 0.3)
1010                         {
1011                                 // DOUBLE CLICK!
1012                                 ServerList_Connect_Click(NULL, me);
1013                         }
1014                 me.lastClickedServer = num;
1015                 me.lastClickedTime = time;
1016         }
1017 }
1018 void XonoticServerList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
1019 {
1020         // layout: Ping, Server name, Map name, NP, TP, MP
1021         float p, q;
1022         float isv4, isv6;
1023         vector theColor;
1024         float theAlpha;
1025         float m, pure, freeslots, j, sflags;
1026         string s, typestr, versionstr, k, v, modname;
1027
1028         float item = CheckItemNumber(i);
1029         //print(sprintf("time: %f, i: %d, item: %d, nitems: %d\n", time, i, item, me.nItems));
1030
1031         if(item < 0)
1032         {
1033                 entity catent = RetrieveCategoryEnt(-item);
1034                 if(catent)
1035                 {
1036                         draw_Text(
1037                                 eY * me.realUpperMargin
1038                                 +
1039                                 eX * (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(catent.cat_string, 0, me.realFontSize)) * 0.5),
1040                                 catent.cat_string,
1041                                 me.realFontSize,
1042                                 '1 1 1',
1043                                 SKINALPHA_TEXT,
1044                                 0
1045                         );
1046                         return;
1047                 }
1048         }
1049
1050         if(isSelected)
1051                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
1052
1053         s = gethostcachestring(SLIST_FIELD_QCSTATUS, item);
1054         m = tokenizebyseparator(s, ":");
1055         typestr = "";
1056         if(m >= 2)
1057         {
1058                 typestr = argv(0);
1059                 versionstr = argv(1);
1060         }
1061         freeslots = -1;
1062         sflags = -1;
1063         modname = "";
1064         pure = 0;
1065         for(j = 2; j < m; ++j)
1066         {
1067                 if(argv(j) == "")
1068                         break;
1069                 k = substring(argv(j), 0, 1);
1070                 v = substring(argv(j), 1, -1);
1071                 if(k == "P")
1072                         pure = stof(v);
1073                 else if(k == "S")
1074                         freeslots = stof(v);
1075                 else if(k == "F")
1076                         sflags = stof(v);
1077                 else if(k == "M")
1078                         modname = v;
1079         }
1080
1081 #ifdef COMPAT_NO_MOD_IS_XONOTIC
1082         if(modname == "")
1083                 modname = "Xonotic";
1084 #endif
1085
1086         /*
1087         SLIST_FIELD_MOD = gethostcacheindexforkey("mod");
1088         s = gethostcachestring(SLIST_FIELD_MOD, item);
1089         if(s != "data")
1090                 if(modname == "Xonotic")
1091                         modname = s;
1092         */
1093
1094         // list the mods here on which the pure server check actually works
1095         if(modname != "Xonotic")
1096         if(modname != "MinstaGib")
1097         if(modname != "CTS")
1098         if(modname != "NIX")
1099         if(modname != "NewToys")
1100                 pure = 0;
1101
1102         if(gethostcachenumber(SLIST_FIELD_FREESLOTS, item) <= 0)
1103                 theAlpha = SKINALPHA_SERVERLIST_FULL;
1104         else if(freeslots == 0)
1105                 theAlpha = SKINALPHA_SERVERLIST_FULL; // g_maxplayers support
1106         else if not(gethostcachenumber(SLIST_FIELD_NUMHUMANS, item))
1107                 theAlpha = SKINALPHA_SERVERLIST_EMPTY;
1108         else
1109                 theAlpha = 1;
1110
1111         p = gethostcachenumber(SLIST_FIELD_PING, item);
1112 #define PING_LOW 75
1113 #define PING_MED 200
1114 #define PING_HIGH 500
1115         if(p < PING_LOW)
1116                 theColor = SKINCOLOR_SERVERLIST_LOWPING + (SKINCOLOR_SERVERLIST_MEDPING - SKINCOLOR_SERVERLIST_LOWPING) * (p / PING_LOW);
1117         else if(p < PING_MED)
1118                 theColor = SKINCOLOR_SERVERLIST_MEDPING + (SKINCOLOR_SERVERLIST_HIGHPING - SKINCOLOR_SERVERLIST_MEDPING) * ((p - PING_LOW) / (PING_MED - PING_LOW));
1119         else if(p < PING_HIGH)
1120         {
1121                 theColor = SKINCOLOR_SERVERLIST_HIGHPING;
1122                 theAlpha *= 1 + (SKINALPHA_SERVERLIST_HIGHPING - 1) * ((p - PING_MED) / (PING_HIGH - PING_MED));
1123         }
1124         else
1125         {
1126                 theColor = eX;
1127                 theAlpha *= SKINALPHA_SERVERLIST_HIGHPING;
1128         }
1129
1130         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, item))
1131         {
1132                 theColor = theColor * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINCOLOR_SERVERLIST_FAVORITE * SKINALPHA_SERVERLIST_FAVORITE;
1133                 theAlpha = theAlpha * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINALPHA_SERVERLIST_FAVORITE;
1134         }
1135
1136         s = gethostcachestring(SLIST_FIELD_CNAME, item);
1137
1138         isv4 = isv6 = 0;
1139         if(substring(s, 0, 1) == "[")
1140         {
1141                 isv6 = 1;
1142                 me.seenIPv6 += 1;
1143         }
1144         else if(strstrofs("0123456789", substring(s, 0, 1), 0) >= 0)
1145         {
1146                 isv4 = 1;
1147                 me.seenIPv4 += 1;
1148         }
1149
1150         q = stof(substring(crypto_getencryptlevel(s), 0, 1));
1151         if((q <= 0 && cvar("crypto_aeslevel") >= 3) || (q >= 3 && cvar("crypto_aeslevel") <= 0))
1152         {
1153                 theColor = SKINCOLOR_SERVERLIST_IMPOSSIBLE;
1154                 theAlpha = SKINALPHA_SERVERLIST_IMPOSSIBLE;
1155         }
1156
1157         if(q == 1)
1158         {
1159                 if(cvar("crypto_aeslevel") >= 2)
1160                         q |= 4;
1161         }
1162         if(q == 2)
1163         {
1164                 if(cvar("crypto_aeslevel") >= 1)
1165                         q |= 4;
1166         }
1167         if(q == 3)
1168                 q = 5;
1169         else if(q >= 3)
1170                 q -= 2;
1171         // possible status:
1172         // 0: crypto off
1173         // 1: AES possible
1174         // 2: AES recommended but not available
1175         // 3: AES possible and will be used
1176         // 4: AES recommended and will be used
1177         // 5: AES required
1178
1179         // --------------
1180         //  RENDER ICONS
1181         // --------------
1182         vector iconSize = '0 0 0';
1183         iconSize_y = me.realFontSize_y * me.iconsSizeFactor;
1184         iconSize_x = me.realFontSize_x * me.iconsSizeFactor;
1185
1186         vector iconPos = '0 0 0';
1187         iconPos_x = (me.columnIconsSize - 3 * iconSize_x) * 0.5;
1188         iconPos_y = (1 - iconSize_y) * 0.5;
1189
1190         string n;
1191
1192         if not(me.seenIPv4 && me.seenIPv6)
1193         {
1194                 iconPos_x += iconSize_x * 0.5;
1195         }
1196         else if(me.seenIPv4 && me.seenIPv6)
1197         {
1198                 n = string_null;
1199                 if(isv6)
1200                         draw_PreloadPictureWithFlags(n = strcat(SKINGFX_SERVERLIST_ICON, "_ipv6"), 0); // PRECACHE_PIC_MIPMAP
1201                 else if(isv4)
1202                         draw_PreloadPictureWithFlags(n = strcat(SKINGFX_SERVERLIST_ICON, "_ipv4"), 0); // PRECACHE_PIC_MIPMAP
1203                 if(n)
1204                         draw_Picture(iconPos, n, iconSize, '1 1 1', 1);
1205                 iconPos_x += iconSize_x;
1206         }
1207
1208         if(q > 0)
1209         {
1210                 draw_PreloadPictureWithFlags(n = strcat(SKINGFX_SERVERLIST_ICON, "_aeslevel", ftos(q)), 0); // PRECACHE_PIC_MIPMAP
1211                 draw_Picture(iconPos, n, iconSize, '1 1 1', 1);
1212         }
1213         iconPos_x += iconSize_x;
1214
1215         if(modname == "Xonotic")
1216         {
1217                 if(pure == 0)
1218                 {
1219                         draw_PreloadPictureWithFlags(n = strcat(SKINGFX_SERVERLIST_ICON, "_pure1"), PRECACHE_PIC_MIPMAP);
1220                         draw_Picture(iconPos, n, iconSize, '1 1 1', 1);
1221                 }
1222         }
1223         else
1224         {
1225                 draw_PreloadPictureWithFlags(n = strcat(SKINGFX_SERVERLIST_ICON, "_mod_", modname), PRECACHE_PIC_MIPMAP);
1226                 if(draw_PictureSize(n) == '0 0 0')
1227                         draw_PreloadPictureWithFlags(n = strcat(SKINGFX_SERVERLIST_ICON, "_mod_"), PRECACHE_PIC_MIPMAP);
1228                 if(pure == 0)
1229                         draw_Picture(iconPos, n, iconSize, '1 1 1', 1);
1230                 else
1231                         draw_Picture(iconPos, n, iconSize, '1 1 1', SKINALPHA_SERVERLIST_ICON_NONPURE);
1232         }
1233         iconPos_x += iconSize_x;
1234
1235         if(sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS))
1236         {
1237                 draw_PreloadPictureWithFlags(n = strcat(SKINGFX_SERVERLIST_ICON, "_stats1"), 0); // PRECACHE_PIC_MIPMAP
1238                 draw_Picture(iconPos, n, iconSize, '1 1 1', 1);
1239         }
1240         iconPos_x += iconSize_x;
1241
1242         // --------------
1243         //  RENDER TEXT
1244         // --------------
1245
1246         // ping
1247         s = ftos(p);
1248         draw_Text(me.realUpperMargin * eY + (me.columnPingOrigin + me.columnPingSize - draw_TextWidth(s, 0, me.realFontSize)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1249
1250         // server name
1251         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_NAME, item), me.columnNameSize, 0, me.realFontSize);
1252         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
1253
1254         // server map
1255         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_MAP, item), me.columnMapSize, 0, me.realFontSize);
1256         draw_Text(me.realUpperMargin * eY + (me.columnMapOrigin + (me.columnMapSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1257
1258         // server gametype
1259         s = draw_TextShortenToWidth(typestr, me.columnTypeSize, 0, me.realFontSize);
1260         draw_Text(me.realUpperMargin * eY + (me.columnTypeOrigin + (me.columnTypeSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1261
1262         // server playercount
1263         s = strcat(ftos(gethostcachenumber(SLIST_FIELD_NUMHUMANS, item)), "/", ftos(gethostcachenumber(SLIST_FIELD_MAXPLAYERS, item)));
1264         draw_Text(me.realUpperMargin * eY + (me.columnPlayersOrigin + (me.columnPlayersSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1265 }
1266
1267 float XonoticServerList_keyDown(entity me, float scan, float ascii, float shift)
1268 {
1269         float i = CheckItemNumber(me.selectedItem);
1270         vector org, sz;
1271
1272         org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
1273         sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
1274
1275         me.lastBumpSelectTime = 0;
1276
1277         if(scan == K_ENTER || scan == K_KP_ENTER)
1278         {
1279                 ServerList_Connect_Click(NULL, me);
1280                 return 1;
1281         }
1282         else if(scan == K_MOUSE2 || scan == K_SPACE)
1283         {
1284                 if((me.nItems != 0) && (i >= 0))
1285                 {
1286                         main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, i);
1287                         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
1288                         return 1;
1289                 }
1290                 return 0;
1291         }
1292         else if(scan == K_INS || scan == K_MOUSE3 || scan == K_KP_INS)
1293         {
1294                 if((me.nItems != 0) && (i >= 0))
1295                 {
1296                         me.toggleFavorite(me, me.selectedServer);
1297                         me.ipAddressBoxFocused = -1;
1298                         return 1;
1299                 }
1300                 return 0;
1301         }
1302         else if(SUPER(XonoticServerList).keyDown(me, scan, ascii, shift))
1303                 return 1;
1304         else if(!me.controlledTextbox)
1305                 return 0;
1306         else
1307                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
1308 }
1309
1310 float XonoticServerList_getTotalHeight(entity me) {
1311         float height_of_normal_rows = me.nItems - category_draw_count;
1312         float height_of_category_headers = me.categoriesHeight * category_draw_count;
1313         return me.itemHeight * (height_of_normal_rows + height_of_category_headers);
1314 }
1315 float XonoticServerList_getItemAtPos(entity me, float pos) {
1316         float i;
1317         float ret;
1318         pos = pos / me.itemHeight;
1319         ret = floor(pos);
1320         for (i = 0; i < category_draw_count; ++i) {
1321                 float first = i + category_item[i];
1322                 float firstPos = i * me.categoriesHeight + category_item[i];
1323                 if (pos >= firstPos)
1324                         ret = first;
1325                 if (pos >= firstPos + me.categoriesHeight)
1326                         ret = first + 1 + floor(pos - firstPos - me.categoriesHeight);
1327         }
1328         return ret;
1329 }
1330 float XonoticServerList_getItemStart(entity me, float item) {
1331         float i;
1332         float start = item;
1333         for (i = 0; i < category_draw_count; ++i) {
1334                 float first = i + category_item[i];
1335                 if (item >= first)
1336                         start += me.categoriesHeight - 1;
1337         }
1338         return me.itemHeight * start;
1339 }
1340 float XonoticServerList_getItemHeight(entity me, float item) {
1341         float i;
1342         for (i = 0; i < category_draw_count; ++i) {
1343                 float first = i + category_item[i];
1344                 if (item == first)
1345                         return me.itemHeight * me.categoriesHeight;
1346         }
1347         return me.itemHeight;
1348 }
1349
1350 #endif