Gametypes: propagate entity references, set limit to 24 due to use of bitflags
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / serverlist.qc
1 #include "serverlist.qh"
2
3 #include "checkbox.qh"
4 #include "inputbox.qh"
5 #include "mainwindow.qh"
6 #include "dialog_multiplayer_join_serverinfo.qh"
7 #include <common/mapinfo.qh>
8
9 void RegisterSLCategories()
10 {
11         entity cat;
12         #define SLIST_CATEGORY(name,enoverride,dioverride,str) \
13                 SET_FIELD_COUNT(name, CATEGORY_FIRST, category_ent_count) \
14                 CHECK_MAX_COUNT(name, MAX_CATEGORIES, category_ent_count, "SLIST_CATEGORY") \
15                 cat = categories[name - 1] = new(slist_category); \
16                 cat.cat_name = #name; \
17                 cat.cat_enoverride_string = strzone(SLIST_CATEGORY_AUTOCVAR(name)); \
18                 cat.cat_dioverride_string = strzone(dioverride); \
19                 cat.cat_string = strzone(str);
20         SLIST_CATEGORIES
21         #undef SLIST_CATEGORY
22
23         int i, x, catnum;
24         string s;
25
26         #define PROCESS_OVERRIDE(override_string,override_field) \
27                 for(i = 0; i < category_ent_count; ++i) \
28                 { \
29                         s = categories[i].override_string; \
30                         if((s != "") && (s != categories[i].cat_name)) \
31                         { \
32                                 catnum = 0; \
33                                 for(x = 0; x < category_ent_count; ++x) \
34                                 { if(categories[x].cat_name == s) { \
35                                         catnum = (x+1); \
36                                         break; \
37                                 } } \
38                                 if(catnum) \
39                                 { \
40                                         strunzone(categories[i].override_string); \
41                                         categories[i].override_string = string_null; \
42                                         categories[i].override_field = catnum; \
43                                         continue; \
44                                 } \
45                                 else \
46                                 { \
47                                         LOG_INFOF( \
48                                                 "RegisterSLCategories(): Improper override '%s' for category '%s'!\n", \
49                                                 s, \
50                                                 categories[i].cat_name \
51                                         ); \
52                                 } \
53                         } \
54                         strunzone(categories[i].override_string); \
55                         categories[i].override_string = string_null; \
56                         categories[i].override_field = 0; \
57                 }
58         PROCESS_OVERRIDE(cat_enoverride_string, cat_enoverride)
59         PROCESS_OVERRIDE(cat_dioverride_string, cat_dioverride)
60         #undef PROCESS_OVERRIDE
61 }
62
63 // Supporting Functions
64 entity RetrieveCategoryEnt(int catnum)
65 {
66         if((catnum > 0) && (catnum <= category_ent_count))
67         {
68                 return categories[catnum - 1];
69         }
70         else
71         {
72                 error(sprintf("RetrieveCategoryEnt(%d): Improper category number!\n", catnum));
73                 return NULL;
74         }
75 }
76
77 bool IsServerInList(string list, string srv)
78 {
79         string p;
80         int i, n;
81         if(srv == "")
82                 return false;
83         srv = netaddress_resolve(srv, 26000);
84         if(srv == "")
85                 return false;
86         p = crypto_getidfp(srv);
87         n = tokenize_console(list);
88         for(i = 0; i < n; ++i)
89         {
90                 if(substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
91                 {
92                         if(p)
93                                 if(argv(i) == p)
94                                         return true;
95                 }
96                 else
97                 {
98                         if(srv == netaddress_resolve(argv(i), 26000))
99                                 return true;
100                 }
101         }
102         return false;
103 }
104
105 int CheckCategoryOverride(int cat)
106 {
107         entity catent = RetrieveCategoryEnt(cat);
108         if(catent)
109         {
110                 int override = (autocvar_menu_slist_categories ? catent.cat_enoverride : catent.cat_dioverride);
111                 if(override) { return override; }
112                 else { return cat; }
113         }
114         else
115         {
116                 error(sprintf("CheckCategoryOverride(%d): Improper category number!\n", cat));
117                 return cat;
118         }
119 }
120
121 int CheckCategoryForEntry(int entry)
122 {
123         string s, k, v, modtype = "";
124         int j, m, impure = 0, freeslots = 0, sflags = 0;
125         s = gethostcachestring(SLIST_FIELD_QCSTATUS, entry);
126         m = tokenizebyseparator(s, ":");
127
128         for(j = 2; j < m; ++j)
129         {
130                 if(argv(j) == "") { break; }
131                 k = substring(argv(j), 0, 1);
132                 v = substring(argv(j), 1, -1);
133                 switch(k)
134                 {
135                         case "P": { impure = stof(v); break; }
136                         case "S": { freeslots = stof(v); break; }
137                         case "F": { sflags = stof(v); break; }
138                         case "M": { modtype = strtolower(v); break; }
139                 }
140         }
141
142         if(modtype != "xonotic") { impure += autocvar_menu_slist_modimpurity; }
143
144         // check if this server is favorited
145         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, entry)) { return CAT_FAVORITED; }
146
147         // now check if it's recommended
148         if(autocvar_menu_slist_recommendations)
149         {
150                 string cname = gethostcachestring(SLIST_FIELD_CNAME, entry);
151
152                 if(IsPromoted(cname)) { return CAT_RECOMMENDED; }
153                 else
154                 {
155                         float recommended = 0;
156                         if(autocvar_menu_slist_recommendations & 1)
157                         {
158                                 if(IsRecommended(cname)) { ++recommended; }
159                                 else { --recommended; }
160                         }
161                         if(autocvar_menu_slist_recommendations & 2)
162                         {
163                                 if(
164                                         ///// check for minimum free slots
165                                         (freeslots >= autocvar_menu_slist_recommendations_minfreeslots)
166
167                                         && // check for purity requirement
168                                         (
169                                                 (autocvar_menu_slist_recommendations_purethreshold < 0)
170                                                 ||
171                                                 (impure <= autocvar_menu_slist_recommendations_purethreshold)
172                                         )
173
174                                         && // check for minimum amount of humans
175                                         (
176                                                 gethostcachenumber(SLIST_FIELD_NUMHUMANS, entry)
177                                                 >=
178                                                 autocvar_menu_slist_recommendations_minhumans
179                                         )
180
181                                         && // check for maximum latency
182                                         (
183                                                 gethostcachenumber(SLIST_FIELD_PING, entry)
184                                                 <=
185                                                 autocvar_menu_slist_recommendations_maxping
186                                         )
187                                 )
188                                         { ++recommended; }
189                                 else
190                                         { --recommended; }
191                         }
192                         if(recommended > 0) { return CAT_RECOMMENDED; }
193                 }
194         }
195
196         // if not favorited or recommended, check modname
197         if(modtype != "xonotic")
198         {
199                 switch(modtype)
200                 {
201                         // old servers which don't report their mod name are considered modified now
202                         case "": { return CAT_MODIFIED; }
203
204                         case "xpm": { return CAT_XPM; }
205                         case "minstagib":
206                         case "instagib": { return CAT_INSTAGIB; }
207                         case "overkill": { return CAT_OVERKILL; }
208                         //case "nix": { return CAT_NIX; }
209                         //case "newtoys": { return CAT_NEWTOYS; }
210
211                         // "cts" is allowed as compat, xdf is replacement
212                         case "cts":
213                         case "xdf": { return CAT_DEFRAG; }
214
215                         default: { LOG_TRACEF("Found strange mod type: %s\n", modtype); return CAT_MODIFIED; }
216                 }
217         }
218
219         // must be normal or impure server
220         return ((impure > autocvar_menu_slist_purethreshold) ? CAT_MODIFIED : CAT_NORMAL);
221 }
222
223 METHOD(XonoticServerList, toggleFavorite, void(XonoticServerList this, string srv))
224 {
225         bool adding = true;
226         string srv_resolved = netaddress_resolve(srv, 26000);
227         string p = crypto_getidfp(srv_resolved);
228         string s = cvar_string("net_slist_favorites");
229         string ret = s;
230         for (int i = 0, n = tokenize_console(s); i < n; ++i)
231         {
232                 bool match;
233                 if (substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
234                 {
235                         // it's a pubkey hash
236                         match = (p && p == argv(i));
237                 }
238                 else
239                 {
240                         // it's an ip
241                         match = (srv_resolved == netaddress_resolve(argv(i), 26000));
242                 }
243                 if (!match) continue;
244                 // on match: remove
245                 adding = false;
246                 string before = (i > 0) ? substring(s, 0, argv_end_index(i - 1)) : "";
247                 string after = (i < n - 1) ? substring(s, argv_start_index(i + 1), -1) : "";
248                 s = strcat(before, (before != "" && after != "" ? " " : ""), after);
249                 ret = s;
250                 // keep searching
251                 // TODO: why not break here?
252                 n = tokenize_console(s);
253                 --i; // offset the increment that is about to happen
254         }
255         if (adding)
256         {
257                 ret = strcat(s, (s != "" ? " " : ""), p ? p : srv);
258         }
259         cvar_set("net_slist_favorites", ret);
260         this.refreshServerList(this, REFRESHSERVERLIST_RESORT);
261 }
262
263 void ServerList_Update_favoriteButton(entity btn, entity me)
264 {
265         entity e = me.favoriteButton;
266         if(IsFavorite(me.ipAddressBox.text))
267         {
268                 e.setText(e, _("Remove"));
269                 clearTooltip(e);
270         }
271         else
272         {
273                 e.setText(e, _("Favorite"));
274                 setZonedTooltip(e, _("Bookmark the currently highlighted server so that it's faster to find in the future"), string_null);
275         }
276 }
277
278 entity makeXonoticServerList()
279 {
280         entity me;
281         me = NEW(XonoticServerList);
282         me.configureXonoticServerList(me);
283         return me;
284 }
285 void XonoticServerList_configureXonoticServerList(entity me)
286 {
287         me.configureXonoticListBox(me);
288
289         // update field ID's
290         #define SLIST_FIELD(suffix,name) SLIST_FIELD_##suffix = gethostcacheindexforkey(name);
291         SLIST_FIELDS
292         #undef SLIST_FIELD
293
294         // clear list
295         me.nItems = 0;
296 }
297 void XonoticServerList_setSelected(entity me, int i)
298 {
299         me.lockedSelectedItem = false;
300         //int save = me.selectedItem;
301         SUPER(XonoticServerList).setSelected(me, i);
302         /*
303         if(me.selectedItem == save)
304                 return;
305         */
306         if(me.nItems == 0)
307                 return;
308         if(gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT) != me.nItems)
309                 return; // sorry, it would be wrong
310
311         if(me.selectedServer)
312                 strunzone(me.selectedServer);
313         me.selectedServer = strzone(gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
314
315         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
316         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
317         me.ipAddressBoxFocused = -1;
318 }
319 void XonoticServerList_refreshServerList(entity me, int mode)
320 {
321         //print("refresh of type ", ftos(mode), "\n");
322
323         if(mode >= REFRESHSERVERLIST_REFILTER)
324         {
325                 float m;
326                 int i, n;
327                 int listflags = 0;
328                 string s, typestr, modstr;
329
330                 s = me.filterString;
331
332                 m = strstrofs(s, ":", 0);
333                 if(m >= 0)
334                 {
335                         typestr = substring(s, 0, m);
336                         s = substring(s, m + 1, strlen(s) - m - 1);
337                         while(substring(s, 0, 1) == " ")
338                                 s = substring(s, 1, strlen(s) - 1);
339                 }
340                 else
341                         typestr = "";
342
343                 modstr = cvar_string("menu_slist_modfilter");
344
345                 m = SLIST_MASK_AND - 1;
346                 resethostcachemasks();
347
348                 // ping: reject negative ping (no idea why this happens in the first place, engine bug)
349                 sethostcachemasknumber(++m, SLIST_FIELD_PING, 0, SLIST_TEST_GREATEREQUAL);
350
351                 // show full button
352                 if(!me.filterShowFull)
353                 {
354                         sethostcachemasknumber(++m, SLIST_FIELD_FREESLOTS, 1, SLIST_TEST_GREATEREQUAL); // legacy
355                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, ":S0:", SLIST_TEST_NOTCONTAIN); // g_maxplayers support
356                 }
357
358                 // show empty button
359                 if(!me.filterShowEmpty)
360                         sethostcachemasknumber(++m, SLIST_FIELD_NUMHUMANS, 1, SLIST_TEST_GREATEREQUAL);
361
362                 // gametype filtering
363                 if(typestr != "")
364                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(typestr, ":"), SLIST_TEST_STARTSWITH);
365
366                 // mod filtering
367                 if(modstr != "")
368                 {
369                         if(substring(modstr, 0, 1) == "!")
370                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(substring(modstr, 1, strlen(modstr) - 1)), SLIST_TEST_NOTEQUAL);
371                         else
372                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(modstr), SLIST_TEST_EQUAL);
373                 }
374
375                 // server banning
376                 n = tokenizebyseparator(_Nex_ExtResponseSystem_BannedServers, " ");
377                 for(i = 0; i < n; ++i)
378                         if(argv(i) != "")
379                                 sethostcachemaskstring(++m, SLIST_FIELD_CNAME, argv(i), SLIST_TEST_NOTSTARTSWITH);
380
381                 m = SLIST_MASK_OR - 1;
382                 if(s != "")
383                 {
384                         sethostcachemaskstring(++m, SLIST_FIELD_NAME, s, SLIST_TEST_CONTAINS);
385                         sethostcachemaskstring(++m, SLIST_FIELD_MAP, s, SLIST_TEST_CONTAINS);
386                         sethostcachemaskstring(++m, SLIST_FIELD_PLAYERS, s, SLIST_TEST_CONTAINS);
387                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(s, ":"), SLIST_TEST_STARTSWITH);
388                 }
389
390                 // sorting flags
391                 //listflags |= SLSF_FAVORITES;
392                 listflags |= SLSF_CATEGORIES;
393                 if(me.currentSortOrder < 0) { listflags |= SLSF_DESCENDING; }
394                 sethostcachesort(me.currentSortField, listflags);
395         }
396
397         resorthostcache();
398         if(mode >= REFRESHSERVERLIST_ASK)
399                 refreshhostcache(mode >= REFRESHSERVERLIST_RESET);
400 }
401 void XonoticServerList_focusEnter(entity me)
402 {
403         SUPER(XonoticServerList).focusEnter(me);
404         if(time < me.nextRefreshTime)
405         {
406                 //print("sorry, no refresh yet\n");
407                 return;
408         }
409         me.nextRefreshTime = time + 10;
410         me.refreshServerList(me, REFRESHSERVERLIST_ASK);
411 }
412
413 void XonoticServerList_draw(entity me)
414 {
415         int i;
416         bool found = false, owned;
417
418         if(_Nex_ExtResponseSystem_BannedServersNeedsRefresh)
419         {
420                 if(!me.needsRefresh)
421                         me.needsRefresh = 2;
422                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 0;
423         }
424
425         if(_Nex_ExtResponseSystem_PromotedServersNeedsRefresh)
426         {
427                 if(!me.needsRefresh)
428                         me.needsRefresh = 3;
429                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 0;
430         }
431
432         if(_Nex_ExtResponseSystem_RecommendedServersNeedsRefresh)
433         {
434                 if(!me.needsRefresh)
435                         me.needsRefresh = 3;
436                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 0;
437         }
438
439         if(me.currentSortField == -1)
440         {
441                 me.setSortOrder(me, SLIST_FIELD_PING, +1);
442                 me.refreshServerList(me, REFRESHSERVERLIST_RESET);
443         }
444         else if(me.needsRefresh == 1)
445         {
446                 me.needsRefresh = 2; // delay by one frame to make sure "slist" has been executed
447         }
448         else if(me.needsRefresh == 2)
449         {
450                 me.needsRefresh = 0;
451                 me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
452         }
453         else if(me.needsRefresh == 3)
454         {
455                 me.needsRefresh = 0;
456                 me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
457         }
458
459         owned = ((me.selectedServer == me.ipAddressBox.text) && (me.ipAddressBox.text != ""));
460
461         for(i = 0; i < category_draw_count; ++i) { category_name[i] = -1; category_item[i] = -1; }
462         category_draw_count = 0;
463
464         if(autocvar_menu_slist_categories >= 0) // if less than 0, don't even draw a category heading for favorites
465         {
466                 float itemcount = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT);
467                 me.nItems = itemcount;
468
469                 //float visible = floor(me.scrollPos / me.itemHeight);
470                 // ^ unfortunately no such optimization can be made-- we must process through the
471                 // entire list, otherwise there is no way to know which item is first in its category.
472
473                 // binary search method suggested by div
474                 float x;
475                 float begin = 0;
476                 for(x = 1; x <= category_ent_count; ++x) {
477                         float first = begin;
478                         float last = (itemcount - 1);
479                         if (first > last) {
480                                 // List is empty.
481                                 break;
482                         }
483                         float catf = gethostcachenumber(SLIST_FIELD_CATEGORY, first);
484                         float catl = gethostcachenumber(SLIST_FIELD_CATEGORY, last);
485                         if (catf > x) {
486                                 // The first one is already > x.
487                                 // Therefore, category x does not exist.
488                                 // Higher numbered categories do exist though.
489                         } else if (catl < x) {
490                                 // The last one is < x.
491                                 // Thus this category - and any following -
492                                 // don't exist.
493                                 break;
494                         } else if (catf == x) {
495                                 // Starts at first. This breaks the loop
496                                 // invariant in the binary search and thus has
497                                 // to be handled separately.
498                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, first) != x)
499                                         error("Category mismatch I");
500                                 if(first > 0)
501                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, first - 1) == x)
502                                                 error("Category mismatch II");
503                                 category_name[category_draw_count] = x;
504                                 category_item[category_draw_count] = first;
505                                 ++category_draw_count;
506                                 begin = first + 1;
507                         } else {
508                                 // At this point, catf <= x < catl, thus
509                                 // catf < catl, thus first < last.
510                                 // INVARIANTS:
511                                 // last - first >= 1
512                                 // catf == gethostcachenumber(SLIST_FIELD_CATEGORY(first)
513                                 // catl == gethostcachenumber(SLIST_FIELD_CATEGORY(last)
514                                 // catf < x
515                                 // catl >= x
516                                 while (last - first > 1) {
517                                         float middle = floor((first + last) / 2);
518                                         // By loop condition, middle != first && middle != last.
519                                         float cat = gethostcachenumber(SLIST_FIELD_CATEGORY, middle);
520                                         if (cat >= x) {
521                                                 last = middle;
522                                                 catl = cat;
523                                         } else {
524                                                 first = middle;
525                                                 catf = cat;
526                                         }
527                                 }
528                                 if (catl == x) {
529                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, last) != x)
530                                                 error("Category mismatch III");
531                                         if(last > 0)
532                                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, last - 1) == x)
533                                                         error("Category mismatch IV");
534                                         category_name[category_draw_count] = x;
535                                         category_item[category_draw_count] = last;
536                                         ++category_draw_count;
537                                         begin = last + 1; // already scanned through these, skip 'em
538                                 }
539                                 else
540                                         begin = last; // already scanned through these, skip 'em
541                         }
542                 }
543                 if(autocvar_menu_slist_categories_onlyifmultiple && (category_draw_count == 1))
544                 {
545                         category_name[0] = -1;
546                         category_item[0] = -1;
547                         category_draw_count = 0;
548                         me.nItems = itemcount;
549                 }
550         }
551         else { me.nItems = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT); }
552
553         me.connectButton.disabled = ((me.nItems == 0) && (me.ipAddressBox.text == ""));
554         me.infoButton.disabled = ((me.nItems == 0) || !owned);
555         me.favoriteButton.disabled = ((me.nItems == 0) && (me.ipAddressBox.text == ""));
556
557         if(me.lockedSelectedItem)
558         {
559                 if(me.nItems > 0)
560                 {
561                         if(gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem) != me.selectedServer)
562                         {
563                                 if(me.selectedServer)
564                                         strunzone(me.selectedServer);
565                                 me.selectedServer = strzone(gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
566                         }
567                         found = true;
568                 }
569         }
570         else if(me.selectedServer)
571         {
572                 for(i = 0; i < me.nItems; ++i)
573                 {
574                         if(gethostcachestring(SLIST_FIELD_CNAME, i) == me.selectedServer)
575                         {
576                                 // don't follow the selected item with SUPER(XonoticServerList).setSelected(me, i);
577                                 me.selectedItem = i;
578                                 found = true;
579                                 break;
580                         }
581                 }
582         }
583         if(!found)
584         {
585                 if(me.nItems > 0)
586                 {
587                         // selected server disappeared, select the last server (scrolling to it)
588                         if(me.selectedItem >= me.nItems)
589                                 SUPER(XonoticServerList).setSelected(me, me.nItems - 1);
590                         if(me.selectedServer)
591                                 strunzone(me.selectedServer);
592                         me.selectedServer = strzone(gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
593                 }
594         }
595
596         if(owned)
597         {
598                 if(me.selectedServer != me.ipAddressBox.text)
599                 {
600                         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
601                         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
602                         me.ipAddressBoxFocused = -1;
603                 }
604         }
605
606         if(me.ipAddressBoxFocused != me.ipAddressBox.focused)
607         {
608                 if(me.ipAddressBox.focused || me.ipAddressBoxFocused < 0)
609                         ServerList_Update_favoriteButton(NULL, me);
610                 me.ipAddressBoxFocused = me.ipAddressBox.focused;
611         }
612
613         SUPER(XonoticServerList).draw(me);
614 }
615 void ServerList_PingSort_Click(entity btn, entity me)
616 {
617         me.setSortOrder(me, SLIST_FIELD_PING, +1);
618 }
619 void ServerList_NameSort_Click(entity btn, entity me)
620 {
621         me.setSortOrder(me, SLIST_FIELD_NAME, -1); // why?
622 }
623 void ServerList_MapSort_Click(entity btn, entity me)
624 {
625         me.setSortOrder(me, SLIST_FIELD_MAP, -1); // why?
626 }
627 void ServerList_PlayerSort_Click(entity btn, entity me)
628 {
629         me.setSortOrder(me, SLIST_FIELD_NUMHUMANS, -1);
630 }
631 void ServerList_TypeSort_Click(entity btn, entity me)
632 {
633         string s = me.filterString;
634         int m = strstrofs(s, ":", 0);
635         if(m >= 0)
636         {
637                 s = substring(s, 0, m);
638                 while(substring(s, m+1, 1) == " ") // skip spaces
639                         ++m;
640         }
641         else
642                 s = "";
643
644         Gametype first = NULL; FOREACH(Gametypes, !first, first = it; break);
645         bool flag = false;
646         FOREACH(Gametypes, s == MapInfo_Type_ToString(it), {
647                 // the type was found
648                 // choose the next one
649                 flag = true;
650                 s = MapInfo_Type_ToString(Gametypes_from(it.m_id + 1));
651                 if (s == "") s = MapInfo_Type_ToString(first);
652                 break;
653         });
654         if (!flag) {
655                 // no type was found
656                 // choose the first one
657                 s = MapInfo_Type_ToString(first);
658         }
659
660         if(s != "") s = strcat(s, ":");
661         s = strcat(s, substring(me.filterString, m+1, strlen(me.filterString) - m - 1));
662
663         me.controlledTextbox.setText(me.controlledTextbox, s);
664         me.controlledTextbox.keyDown(me.controlledTextbox, K_END, 0, 0);
665         me.controlledTextbox.keyUp(me.controlledTextbox, K_END, 0, 0);
666         //ServerList_Filter_Change(me.controlledTextbox, me);
667 }
668 void ServerList_Filter_Change(entity box, entity me)
669 {
670         if(me.filterString)
671                 strunzone(me.filterString);
672         if(box.text != "")
673                 me.filterString = strzone(box.text);
674         else
675                 me.filterString = string_null;
676         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
677
678         me.ipAddressBox.setText(me.ipAddressBox, "");
679         me.ipAddressBox.cursorPos = 0;
680         me.ipAddressBoxFocused = -1;
681 }
682 void ServerList_Categories_Click(entity box, entity me)
683 {
684         box.setChecked(box, autocvar_menu_slist_categories = !autocvar_menu_slist_categories);
685         me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
686
687         me.ipAddressBox.setText(me.ipAddressBox, "");
688         me.ipAddressBox.cursorPos = 0;
689         me.ipAddressBoxFocused = -1;
690 }
691 void ServerList_ShowEmpty_Click(entity box, entity me)
692 {
693         box.setChecked(box, me.filterShowEmpty = !me.filterShowEmpty);
694         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
695
696         me.ipAddressBox.setText(me.ipAddressBox, "");
697         me.ipAddressBox.cursorPos = 0;
698         me.ipAddressBoxFocused = -1;
699 }
700 void ServerList_ShowFull_Click(entity box, entity me)
701 {
702         box.setChecked(box, me.filterShowFull = !me.filterShowFull);
703         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
704
705         me.ipAddressBox.setText(me.ipAddressBox, "");
706         me.ipAddressBox.cursorPos = 0;
707         me.ipAddressBoxFocused = -1;
708 }
709 void XonoticServerList_setSortOrder(entity me, int fld, int direction)
710 {
711         if(me.currentSortField == fld)
712                 direction = -me.currentSortOrder;
713         me.currentSortOrder = direction;
714         me.currentSortField = fld;
715         me.sortButton1.forcePressed = (fld == SLIST_FIELD_PING);
716         me.sortButton2.forcePressed = (fld == SLIST_FIELD_NAME);
717         me.sortButton3.forcePressed = (fld == SLIST_FIELD_MAP);
718         me.sortButton4.forcePressed = 0;
719         me.sortButton5.forcePressed = (fld == SLIST_FIELD_NUMHUMANS);
720         me.selectedItem = 0;
721         if(me.selectedServer)
722                 strunzone(me.selectedServer);
723         me.selectedServer = string_null;
724         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
725 }
726 void XonoticServerList_positionSortButton(entity me, entity btn, float theOrigin, float theSize, string theTitle, void(entity, entity) theFunc)
727 {
728         vector originInLBSpace, sizeInLBSpace;
729         originInLBSpace = eY * (-me.itemHeight);
730         sizeInLBSpace = eY * me.itemHeight + eX * (1 - me.controlWidth);
731
732         vector originInDialogSpace, sizeInDialogSpace;
733         originInDialogSpace = boxToGlobal(originInLBSpace, me.Container_origin, me.Container_size);
734         sizeInDialogSpace = boxToGlobalSize(sizeInLBSpace, me.Container_size);
735
736         btn.Container_origin_x = originInDialogSpace.x + sizeInDialogSpace.x * theOrigin;
737         btn.Container_size_x   =                         sizeInDialogSpace.x * theSize;
738         btn.setText(btn, theTitle);
739         btn.onClick = theFunc;
740         btn.onClickEntity = me;
741         btn.resized = 1;
742 }
743 void XonoticServerList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
744 {
745         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
746
747         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
748         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
749         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
750
751         me.columnIconsOrigin = 0;
752         me.columnIconsSize = me.realFontSize.x * 4 * me.iconsSizeFactor;
753         me.columnPingSize = me.realFontSize.x * 3;
754         me.columnMapSize = me.realFontSize.x * 10;
755         me.columnTypeSize = me.realFontSize.x * 4;
756         me.columnPlayersSize = me.realFontSize.x * 5;
757         me.columnNameSize = 1 - me.columnPlayersSize - me.columnMapSize - me.columnPingSize - me.columnIconsSize - me.columnTypeSize - 5 * me.realFontSize.x;
758         me.columnPingOrigin = me.columnIconsOrigin + me.columnIconsSize + me.realFontSize.x;
759         me.columnNameOrigin = me.columnPingOrigin + me.columnPingSize + me.realFontSize.x;
760         me.columnMapOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
761         me.columnTypeOrigin = me.columnMapOrigin + me.columnMapSize + me.realFontSize.x;
762         me.columnPlayersOrigin = me.columnTypeOrigin + me.columnTypeSize + me.realFontSize.x;
763
764         me.positionSortButton(me, me.sortButton1, me.columnPingOrigin, me.columnPingSize, _("Ping"), ServerList_PingSort_Click);
765         me.positionSortButton(me, me.sortButton2, me.columnNameOrigin, me.columnNameSize, _("Host name"), ServerList_NameSort_Click);
766         me.positionSortButton(me, me.sortButton3, me.columnMapOrigin, me.columnMapSize, _("Map"), ServerList_MapSort_Click);
767         me.positionSortButton(me, me.sortButton4, me.columnTypeOrigin, me.columnTypeSize, _("Type"), ServerList_TypeSort_Click);
768         me.positionSortButton(me, me.sortButton5, me.columnPlayersOrigin, me.columnPlayersSize, _("Players"), ServerList_PlayerSort_Click);
769
770         int f = me.currentSortField;
771         if(f >= 0)
772         {
773                 me.currentSortField = -1;
774                 me.setSortOrder(me, f, me.currentSortOrder); // force resetting the sort order
775         }
776 }
777 void ServerList_Connect_Click(entity btn, entity me)
778 {
779         localcmd(sprintf("connect %s\n",
780                 ((me.ipAddressBox.text != "") ?
781                         me.ipAddressBox.text : me.selectedServer
782                 )
783         ));
784 }
785 void ServerList_Favorite_Click(entity btn, entity this)
786 {
787         string addr = this.ipAddressBox.text;
788         string ipstr = netaddress_resolve(addr, 26000);
789         if (ipstr == "") return;
790         m_play_click_sound(MENU_SOUND_SELECT);
791         this.toggleFavorite(this, addr);
792         this.ipAddressBoxFocused = -1;
793 }
794 void ServerList_Info_Click(entity btn, entity me)
795 {
796         if (me.nItems != 0)
797                 main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
798
799         vector org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
800         vector sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
801         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
802 }
803 void XonoticServerList_doubleClickListBoxItem(entity me, int i, vector where)
804 {
805         ServerList_Connect_Click(NULL, me);
806 }
807 void XonoticServerList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
808 {
809         // layout: Ping, Server name, Map name, NP, TP, MP
810         float p;
811         int q;
812         bool isv4, isv6;
813         vector theColor;
814         float theAlpha;
815         bool pure = false, pure_available = false;
816         int freeslots = -1, sflags = -1, j, m;
817         string s, typestr, versionstr, k, v, modname;
818
819         //printf("time: %f, i: %d, item: %d, nitems: %d\n", time, i, item, me.nItems);
820
821         vector oldscale = draw_scale;
822         vector oldshift = draw_shift;
823 #define SET_YRANGE(start,end) \
824         draw_scale = boxToGlobalSize(eX * 1 + eY * (end - start), oldscale); \
825         draw_shift = boxToGlobal(eY * start, oldshift, oldscale);
826
827         for (j = 0; j < category_draw_count; ++j) {
828                 // Matches exactly the headings with increased height.
829                 if (i == category_item[j])
830                         break;
831         }
832
833         if (j < category_draw_count)
834         {
835                 entity catent = RetrieveCategoryEnt(category_name[j]);
836                 if(catent)
837                 {
838                         SET_YRANGE(
839                                 (me.categoriesHeight - 1) / (me.categoriesHeight + 1),
840                                 me.categoriesHeight / (me.categoriesHeight + 1)
841                         );
842                         draw_Text(
843                                 eY * me.realUpperMargin
844                                 +
845 #if 0
846                                 eX * (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(catent.cat_string, 0, me.realFontSize)) * 0.5),
847                                 catent.cat_string,
848 #else
849                                 eX * (me.columnNameOrigin),
850                                 strcat(catent.cat_string, ":"),
851 #endif
852                                 me.realFontSize,
853                                 SKINCOLOR_SERVERLIST_CATEGORY,
854                                 SKINALPHA_SERVERLIST_CATEGORY,
855                                 0
856                         );
857                         SET_YRANGE(me.categoriesHeight / (me.categoriesHeight + 1), 1);
858                 }
859         }
860
861         if(isSelected)
862                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
863         else if(isFocused)
864         {
865                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
866                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
867         }
868
869         s = gethostcachestring(SLIST_FIELD_QCSTATUS, i);
870         m = tokenizebyseparator(s, ":");
871         typestr = "";
872         if(m >= 2)
873         {
874                 typestr = argv(0);
875                 versionstr = argv(1);
876         }
877         freeslots = -1;
878         modname = "";
879         for(j = 2; j < m; ++j)
880         {
881                 if(argv(j) == "")
882                         break;
883                 k = substring(argv(j), 0, 1);
884                 v = substring(argv(j), 1, -1);
885                 if(k == "P")
886                 {
887                         pure = (stof(v) == 0);
888                         pure_available = true;
889                 }
890                 else if(k == "S")
891                         freeslots = stof(v);
892                 else if(k == "F")
893                         sflags = stoi(v);
894                 else if(k == "M")
895                         modname = v;
896         }
897
898 #ifdef COMPAT_NO_MOD_IS_XONOTIC
899         if(modname == "")
900                 modname = "Xonotic";
901 #endif
902
903         string original_modname = modname;
904         modname = strtolower(modname);
905
906         /*
907         SLIST_FIELD_MOD = gethostcacheindexforkey("mod");
908         s = gethostcachestring(SLIST_FIELD_MOD, i);
909         if(s != "data")
910                 if(modname == "xonotic")
911                         modname = s;
912         */
913
914         // list the mods here on which the pure server check actually works
915         if(modname != "xonotic")
916         if(modname != "instagib" || modname != "minstagib")
917         if(modname != "cts")
918         if(modname != "nix")
919         if(modname != "newtoys")
920                 pure_available = false;
921
922         if(gethostcachenumber(SLIST_FIELD_FREESLOTS, i) <= 0)
923                 theAlpha = SKINALPHA_SERVERLIST_FULL;
924         else if(freeslots == 0)
925                 theAlpha = SKINALPHA_SERVERLIST_FULL; // g_maxplayers support
926         else if (!gethostcachenumber(SLIST_FIELD_NUMHUMANS, i))
927                 theAlpha = SKINALPHA_SERVERLIST_EMPTY;
928         else
929                 theAlpha = 1;
930
931         p = gethostcachenumber(SLIST_FIELD_PING, i);
932         const int PING_LOW = 75;
933         const int PING_MED = 200;
934         const int PING_HIGH = 500;
935         if(p < PING_LOW)
936                 theColor = SKINCOLOR_SERVERLIST_LOWPING + (SKINCOLOR_SERVERLIST_MEDPING - SKINCOLOR_SERVERLIST_LOWPING) * (p / PING_LOW);
937         else if(p < PING_MED)
938                 theColor = SKINCOLOR_SERVERLIST_MEDPING + (SKINCOLOR_SERVERLIST_HIGHPING - SKINCOLOR_SERVERLIST_MEDPING) * ((p - PING_LOW) / (PING_MED - PING_LOW));
939         else if(p < PING_HIGH)
940         {
941                 theColor = SKINCOLOR_SERVERLIST_HIGHPING;
942                 theAlpha *= 1 + (SKINALPHA_SERVERLIST_HIGHPING - 1) * ((p - PING_MED) / (PING_HIGH - PING_MED));
943         }
944         else
945         {
946                 theColor = eX;
947                 theAlpha *= SKINALPHA_SERVERLIST_HIGHPING;
948         }
949
950         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, i))
951         {
952                 theColor = theColor * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINCOLOR_SERVERLIST_FAVORITE * SKINALPHA_SERVERLIST_FAVORITE;
953                 theAlpha = theAlpha * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINALPHA_SERVERLIST_FAVORITE;
954         }
955
956         s = gethostcachestring(SLIST_FIELD_CNAME, i);
957
958         isv4 = isv6 = false;
959         if(substring(s, 0, 1) == "[")
960         {
961                 isv6 = true;
962                 me.seenIPv6 += 1;
963         }
964         else if(strstrofs("0123456789", substring(s, 0, 1), 0) >= 0)
965         {
966                 isv4 = true;
967                 me.seenIPv4 += 1;
968         }
969
970         q = stof(substring(crypto_getencryptlevel(s), 0, 1));
971         if((q <= 0 && cvar("crypto_aeslevel") >= 3) || (q >= 3 && cvar("crypto_aeslevel") <= 0))
972         {
973                 theColor = SKINCOLOR_SERVERLIST_IMPOSSIBLE;
974                 theAlpha = SKINALPHA_SERVERLIST_IMPOSSIBLE;
975         }
976
977         if(q == 1)
978         {
979                 if(cvar("crypto_aeslevel") >= 2)
980                         q |= 4;
981         }
982         if(q == 2)
983         {
984                 if(cvar("crypto_aeslevel") >= 1)
985                         q |= 4;
986         }
987         if(q == 3)
988                 q = 5;
989         else if(q >= 3)
990                 q -= 2;
991         // possible status:
992         // 0: crypto off
993         // 1: AES possible
994         // 2: AES recommended but not available
995         // 3: AES possible and will be used
996         // 4: AES recommended and will be used
997         // 5: AES required
998
999         // --------------
1000         //  RENDER ICONS
1001         // --------------
1002         vector iconSize = '0 0 0';
1003         iconSize_y = me.realFontSize.y * me.iconsSizeFactor;
1004         iconSize_x = me.realFontSize.x * me.iconsSizeFactor;
1005
1006         vector iconPos = '0 0 0';
1007         iconPos_x = (me.columnIconsSize - 3 * iconSize.x) * 0.5;
1008         iconPos_y = (1 - iconSize.y) * 0.5;
1009
1010         // IP
1011         if(me.seenIPv4 && me.seenIPv6)
1012         {
1013                 if(isv6)
1014                         draw_Picture(iconPos, "icon_ipv6", iconSize, '1 1 1', 1);
1015                 else if(isv4)
1016                         draw_Picture(iconPos, "icon_ipv4", iconSize, '1 1 1', 1);
1017         }
1018
1019         iconPos.x += iconSize.x;
1020
1021         // AES
1022         if(q > 0)
1023                 draw_Picture(iconPos, strcat("icon_aeslevel", ftos(q)), iconSize, '1 1 1', 1);
1024
1025         iconPos.x += iconSize.x;
1026
1027         // Mod
1028         if(modname == "xonotic")
1029         {
1030                 // Here, pure_available should always be set. If not, consider
1031                 // it an impurity.
1032                 if(pure_available && pure)
1033                         draw_Picture(iconPos, "icon_pure1", iconSize, '1 1 1', 1);
1034         }
1035         else
1036         {
1037                 string icon = strcat("icon_mod_", modname);
1038                 if(draw_PictureSize(icon) == '0 0 0')
1039                         icon = "icon_mod_";
1040
1041                 // In mods, pure_available not being present indicates
1042                 // non-support of the feature. Just show the mod icon as is
1043                 // then.
1044                 if(pure_available && !pure)
1045                         draw_Picture(iconPos, icon, iconSize, '1 1 1', SKINALPHA_SERVERLIST_ICON_NONPURE);
1046                 else
1047                         draw_Picture(iconPos, icon, iconSize, '1 1 1', 1);
1048         }
1049
1050         iconPos.x += iconSize.x;
1051
1052         // Stats
1053         if(sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS))
1054                 draw_Picture(iconPos, "icon_stats1", iconSize, '1 1 1', 1);
1055
1056         if(isFocused && me.mouseOverIcons && !me.tooltip)
1057         {
1058                 string t = "";
1059                 if(me.seenIPv4 && me.seenIPv6)
1060                         t = strcat(t, (isv6) ? "IPv6, " : "IPv4, ");
1061                 t = strcat(t, _("encryption:"), " ", (q ? sprintf(_("AES level %d"), q) : ZCTX(_("ENC^none"))), ", ");
1062                 t = strcat(t, sprintf(_("mod: %s"), ((modname == "xonotic") ? ZCTX(_("MOD^Default")) : original_modname)));
1063                 if(pure_available)
1064                         t = strcat(t, sprintf(" (%s)", (pure) ? _("official settings") : _("modified settings")));
1065                 t = strcat(t, ", ");
1066                 t = strcat(t, ((sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS)) ? _("stats enabled") : _("stats disabled")));
1067                 setZonedTooltip(me, t, string_null);
1068         }
1069         // --------------
1070         //  RENDER TEXT
1071         // --------------
1072
1073         // ping
1074         s = ftos(p);
1075         draw_Text(me.realUpperMargin * eY + (me.columnPingOrigin + me.columnPingSize - draw_TextWidth(s, 0, me.realFontSize)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1076
1077         // server name
1078         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_NAME, i), me.columnNameSize, 0, me.realFontSize);
1079         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
1080
1081         // server map
1082         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_MAP, i), me.columnMapSize, 0, me.realFontSize);
1083         draw_Text(me.realUpperMargin * eY + (me.columnMapOrigin + (me.columnMapSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1084
1085         // server gametype
1086         s = draw_TextShortenToWidth(typestr, me.columnTypeSize, 0, me.realFontSize);
1087         draw_Text(me.realUpperMargin * eY + (me.columnTypeOrigin + (me.columnTypeSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1088
1089         // server playercount
1090         s = strcat(ftos(gethostcachenumber(SLIST_FIELD_NUMHUMANS, i)), "/", ftos(gethostcachenumber(SLIST_FIELD_MAXPLAYERS, i)));
1091         draw_Text(me.realUpperMargin * eY + (me.columnPlayersOrigin + (me.columnPlayersSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1092 }
1093
1094 void XonoticServerList_focusedItemChangeNotify(entity me)
1095 {
1096         clearTooltip(me);
1097 }
1098
1099 float XonoticServerList_mouseMove(entity me, vector pos)
1100 {
1101         if(!SUPER(XonoticServerList).mouseMove(me, pos))
1102         {
1103                 me.mouseOverIcons = false;
1104                 clearTooltip(me);
1105                 return 1;
1106         }
1107
1108         me.mouseOverIcons = (pos_x <= me.columnIconsSize);
1109         if(!me.mouseOverIcons)
1110                 clearTooltip(me);
1111         return 1;
1112 }
1113
1114 bool XonoticServerList_keyDown(entity me, int scan, bool ascii, bool shift)
1115 {
1116         vector org, sz;
1117
1118         org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
1119         sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
1120
1121         if(scan == K_ENTER || scan == K_KP_ENTER)
1122         {
1123                 ServerList_Connect_Click(NULL, me);
1124                 return true;
1125         }
1126         else if(scan == K_MOUSE2 || scan == K_SPACE)
1127         {
1128                 if(me.nItems != 0)
1129                 {
1130                         m_play_click_sound(MENU_SOUND_OPEN);
1131                         main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
1132                         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
1133                         return true;
1134                 }
1135                 return false;
1136         }
1137         else if(scan == K_INS || scan == K_MOUSE3 || scan == K_KP_INS)
1138         {
1139                 if(me.nItems != 0)
1140                 {
1141                         me.toggleFavorite(me, me.selectedServer);
1142                         me.ipAddressBoxFocused = -1;
1143                         return true;
1144                 }
1145                 return false;
1146         }
1147         else if(SUPER(XonoticServerList).keyDown(me, scan, ascii, shift))
1148                 return true;
1149         else if(!me.controlledTextbox)
1150                 return false;
1151         else
1152                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
1153 }
1154
1155 float XonoticServerList_getTotalHeight(entity me)
1156 {
1157         float num_normal_rows = me.nItems;
1158         int num_headers = category_draw_count;
1159         return me.itemHeight * (num_normal_rows + me.categoriesHeight * num_headers);
1160 }
1161 int XonoticServerList_getItemAtPos(entity me, float pos)
1162 {
1163         pos = pos / me.itemHeight;
1164         int i;
1165         for (i = category_draw_count - 1; i >= 0; --i) {
1166                 int itemidx = category_item[i];
1167                 float itempos = i * me.categoriesHeight + category_item[i];
1168                 if (pos >= itempos + me.categoriesHeight + 1)
1169                         return itemidx + 1 + floor(pos - (itempos + me.categoriesHeight + 1));
1170                 if (pos >= itempos)
1171                         return itemidx;
1172         }
1173         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1174         return floor(pos);
1175 }
1176 float XonoticServerList_getItemStart(entity me, int item)
1177 {
1178         int i;
1179         for (i = category_draw_count - 1; i >= 0; --i) {
1180                 int itemidx = category_item[i];
1181                 float itempos = i * me.categoriesHeight + category_item[i];
1182                 if (item >= itemidx + 1)
1183                         return (itempos + me.categoriesHeight + 1 + item - (itemidx + 1)) * me.itemHeight;
1184                 if (item >= itemidx)
1185                         return itempos * me.itemHeight;
1186         }
1187         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1188         return item * me.itemHeight;
1189 }
1190 float XonoticServerList_getItemHeight(entity me, int item)
1191 {
1192         int i;
1193         for (i = 0; i < category_draw_count; ++i) {
1194                 // Matches exactly the headings with increased height.
1195                 if (item == category_item[i])
1196                         return me.itemHeight * (me.categoriesHeight + 1);
1197         }
1198         return me.itemHeight;
1199 }