qcsrc/menu/xonotic/skinlist.qc

   1 #ifndef SKINLIST_H
   2 #define SKINLIST_H
   3 CLASS(XonoticSkinList, XonoticListBox)
   4         METHOD(XonoticSkinList, configureXonoticSkinList, void(entity))
   5         ATTRIB(XonoticSkinList, rowsPerItem, float, 4)
   6         METHOD(XonoticSkinList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticSkinList, drawListBoxItem, void(entity, float, vector, float))
   8         METHOD(XonoticSkinList, getSkins, void(entity))
   9         METHOD(XonoticSkinList, setSkin, void(entity))
  10         METHOD(XonoticSkinList, loadCvars, void(entity))
  11         METHOD(XonoticSkinList, saveCvars, void(entity))
  12         METHOD(XonoticSkinList, skinParameter, string(entity, float, float))
  13         METHOD(XonoticSkinList, doubleClickListBoxItem, void(entity, float, vector))
  14         METHOD(XonoticSkinList, keyDown, float(entity, float, float, float))
  15         METHOD(XonoticSkinList, destroy, void(entity))
  16
  17         ATTRIB(XonoticSkinList, skinlist, float, -1)
  18         ATTRIB(XonoticSkinList, realFontSize, vector, '0 0 0')
  19         ATTRIB(XonoticSkinList, columnPreviewOrigin, float, 0)
  20         ATTRIB(XonoticSkinList, columnPreviewSize, float, 0)
  21         ATTRIB(XonoticSkinList, columnNameOrigin, float, 0)
  22         ATTRIB(XonoticSkinList, columnNameSize, float, 0)
  23         ATTRIB(XonoticSkinList, realUpperMargin1, float, 0)
  24         ATTRIB(XonoticSkinList, realUpperMargin2, float, 0)
  25         ATTRIB(XonoticSkinList, origin, vector, '0 0 0')
  26         ATTRIB(XonoticSkinList, itemAbsSize, vector, '0 0 0')
  27
  28         ATTRIB(XonoticSkinList, name, string, "skinselector")
  29 ENDCLASS(XonoticSkinList)
  30
  31 entity makeXonoticSkinList();
  32 void SetSkin_Click(entity btn, entity me);
  33 #endif
  34
  35 #ifdef IMPLEMENTATION
  36
  37 const float SKINPARM_NAME = 0;
  38 const float SKINPARM_TITLE = 1;
  39 const float SKINPARM_AUTHOR = 2;
  40 const float SKINPARM_PREVIEW = 3;
  41 const float SKINPARM_COUNT = 4;
  42
  43 entity makeXonoticSkinList()
  44 {
  45         entity me;
  46         me = NEW(XonoticSkinList);
  47         me.configureXonoticSkinList(me);
  48         return me;
  49 }
  50
  51 void XonoticSkinList_configureXonoticSkinList(entity me)
  52 {
  53         me.configureXonoticListBox(me);
  54         me.getSkins(me);
  55         me.loadCvars(me);
  56 }
  57
  58 void XonoticSkinList_loadCvars(entity me)
  59 {
  60         string s;
  61         float i, n;
  62         s = cvar_string("menu_skin");
  63         n = me.nItems;
  64         for(i = 0; i < n; ++i)
  65         {
  66                 if(me.skinParameter(me, i, SKINPARM_NAME) == s)
  67                 {
  68                         me.selectedItem = i;
  69                         break;
  70                 }
  71         }
  72 }
  73
  74 void XonoticSkinList_saveCvars(entity me)
  75 {
  76         cvar_set("menu_skin", me.skinParameter(me, me.selectedItem, SKINPARM_NAME));
  77 }
  78
  79 string XonoticSkinList_skinParameter(entity me, float i, float key)
  80 {
  81         return bufstr_get(me.skinlist, i * SKINPARM_COUNT + key);
  82 }
  83
  84 void XonoticSkinList_getSkins(entity me)
  85 {
  86         float glob, buf, i, n, fh;
  87         string s;
  88
  89         buf = buf_create();
  90         glob = search_begin("gfx/menu/*/skinvalues.txt", true, true);
  91         if(glob < 0)
  92         {
  93                 me.skinlist = buf;
  94                 me.nItems = 0;
  95                 return;
  96         }
  97
  98         n = search_getsize(glob);
  99         for(i = 0; i < n; ++i)
 100         {
 101                 s = search_getfilename(glob, i);
 102                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_NAME, substring(s, 9, strlen(s) - 24)); // the * part
 103                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, _("<TITLE>"));
 104                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, _("<AUTHOR>"));
 105                 if(draw_PictureSize(strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview")) == '0 0 0')
 106                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, "nopreview_menuskin");
 107                 else
 108                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview"));
 109                 fh = fopen(language_filename(s), FILE_READ);
 110                 if(fh < 0)
 111                 {
 112                         print("Warning: can't open skinvalues.txt file\n");
 113                         continue;
 114                 }
 115                 while((s = fgets(fh)))
 116                 {
 117                         // these two are handled by skinlist.qc
 118                         if(substring(s, 0, 6) == "title ")
 119                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, substring(s, 6, strlen(s) - 6));
 120                         else if(substring(s, 0, 7) == "author ")
 121                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, substring(s, 7, strlen(s) - 7));
 122                 }
 123                 fclose(fh);
 124         }
 125
 126         search_end(glob);
 127
 128         me.skinlist = buf;
 129         me.nItems = n;
 130 }
 131
 132 void XonoticSkinList_destroy(entity me)
 133 {
 134         buf_del(me.skinlist);
 135 }
 136
 137 void XonoticSkinList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 138 {
 139         me.itemAbsSize = '0 0 0';
 140         SUPER(XonoticSkinList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 141
 142         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 143         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 144         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
 145         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
 146
 147         me.columnPreviewOrigin = 0;
 148         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 149         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 150         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
 151 }
 152
 153 void XonoticSkinList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 154 {
 155         string s;
 156
 157         if(isSelected)
 158                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 159
 160         s = me.skinParameter(me, i, SKINPARM_PREVIEW);
 161         draw_Picture(me.columnPreviewOrigin * eX, s, me.columnPreviewSize * eX + eY, '1 1 1', 1);
 162
 163         s = me.skinParameter(me, i, SKINPARM_TITLE);
 164         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 165         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_TITLE, SKINALPHA_TEXT, 0);
 166
 167         s = me.skinParameter(me, i, SKINPARM_AUTHOR);
 168         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 169         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_AUTHOR, SKINALPHA_TEXT, 0);
 170 }
 171
 172 void XonoticSkinList_setSkin(entity me)
 173 {
 174         me.saveCvars(me);
 175         localcmd("\nmenu_restart\nmenu_cmd skinselect\n");
 176 }
 177
 178 void SetSkin_Click(entity btn, entity me)
 179 {
 180         me.setSkin(me);
 181 }
 182
 183 void XonoticSkinList_doubleClickListBoxItem(entity me, float i, vector where)
 184 {
 185         m_play_click_sound(MENU_SOUND_EXECUTE);
 186         me.setSkin(me);
 187 }
 188
 189 float XonoticSkinList_keyDown(entity me, float scan, float ascii, float shift)
 190 {
 191         if(scan == K_ENTER || scan == K_KP_ENTER)
 192         {
 193                 m_play_click_sound(MENU_SOUND_EXECUTE);
 194                 me.setSkin(me);
 195                 return 1;
 196         }
 197         else
 198                 return SUPER(XonoticSkinList).keyDown(me, scan, ascii, shift);
 199 }
 200 #endif