qcsrc/menu/xonotic/skinlist.qc

   1 #ifndef SKINLIST_H
   2 #define SKINLIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticSkinList, XonoticListBox)
   5         METHOD(XonoticSkinList, configureXonoticSkinList, void(entity))
   6         ATTRIB(XonoticSkinList, rowsPerItem, float, 4)
   7         METHOD(XonoticSkinList, resizeNotify, void(entity, vector, vector, vector, vector))
   8         METHOD(XonoticSkinList, drawListBoxItem, void(entity, int, vector, bool, bool))
   9         METHOD(XonoticSkinList, getSkins, void(entity))
  10         METHOD(XonoticSkinList, setSkin, void(entity))
  11         METHOD(XonoticSkinList, loadCvars, void(entity))
  12         METHOD(XonoticSkinList, saveCvars, void(entity))
  13         METHOD(XonoticSkinList, skinParameter, string(entity, float, float))
  14         METHOD(XonoticSkinList, doubleClickListBoxItem, void(entity, float, vector))
  15         METHOD(XonoticSkinList, keyDown, float(entity, float, float, float))
  16         METHOD(XonoticSkinList, destroy, void(entity))
  17
  18         ATTRIB(XonoticSkinList, skinlist, float, -1)
  19         ATTRIB(XonoticSkinList, realFontSize, vector, '0 0 0')
  20         ATTRIB(XonoticSkinList, columnPreviewOrigin, float, 0)
  21         ATTRIB(XonoticSkinList, columnPreviewSize, float, 0)
  22         ATTRIB(XonoticSkinList, columnNameOrigin, float, 0)
  23         ATTRIB(XonoticSkinList, columnNameSize, float, 0)
  24         ATTRIB(XonoticSkinList, realUpperMargin1, float, 0)
  25         ATTRIB(XonoticSkinList, realUpperMargin2, float, 0)
  26         ATTRIB(XonoticSkinList, origin, vector, '0 0 0')
  27         ATTRIB(XonoticSkinList, itemAbsSize, vector, '0 0 0')
  28
  29         ATTRIB(XonoticSkinList, name, string, "skinselector")
  30 ENDCLASS(XonoticSkinList)
  31
  32 entity makeXonoticSkinList();
  33 void SetSkin_Click(entity btn, entity me);
  34 #endif
  35
  36 #ifdef IMPLEMENTATION
  37
  38 const float SKINPARM_NAME = 0;
  39 const float SKINPARM_TITLE = 1;
  40 const float SKINPARM_AUTHOR = 2;
  41 const float SKINPARM_PREVIEW = 3;
  42 const float SKINPARM_COUNT = 4;
  43
  44 entity makeXonoticSkinList()
  45 {
  46         entity me;
  47         me = NEW(XonoticSkinList);
  48         me.configureXonoticSkinList(me);
  49         return me;
  50 }
  51
  52 void XonoticSkinList_configureXonoticSkinList(entity me)
  53 {
  54         me.configureXonoticListBox(me);
  55         me.getSkins(me);
  56         me.loadCvars(me);
  57 }
  58
  59 void XonoticSkinList_loadCvars(entity me)
  60 {
  61         string s;
  62         float i, n;
  63         s = cvar_string("menu_skin");
  64         n = me.nItems;
  65         for(i = 0; i < n; ++i)
  66         {
  67                 if(me.skinParameter(me, i, SKINPARM_NAME) == s)
  68                 {
  69                         me.selectedItem = i;
  70                         break;
  71                 }
  72         }
  73 }
  74
  75 void XonoticSkinList_saveCvars(entity me)
  76 {
  77         cvar_set("menu_skin", me.skinParameter(me, me.selectedItem, SKINPARM_NAME));
  78 }
  79
  80 string XonoticSkinList_skinParameter(entity me, float i, float key)
  81 {
  82         return bufstr_get(me.skinlist, i * SKINPARM_COUNT + key);
  83 }
  84
  85 void XonoticSkinList_getSkins(entity me)
  86 {
  87         float glob, buf, i, n, fh;
  88         string s;
  89
  90         buf = buf_create();
  91         glob = search_begin("gfx/menu/*/skinvalues.txt", true, true);
  92         if(glob < 0)
  93         {
  94                 me.skinlist = buf;
  95                 me.nItems = 0;
  96                 return;
  97         }
  98
  99         n = search_getsize(glob);
 100         for(i = 0; i < n; ++i)
 101         {
 102                 s = search_getfilename(glob, i);
 103                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_NAME, substring(s, 9, strlen(s) - 24)); // the * part
 104                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, _("<TITLE>"));
 105                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, _("<AUTHOR>"));
 106                 if(draw_PictureSize(strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview")) == '0 0 0')
 107                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, "nopreview_menuskin");
 108                 else
 109                         bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_PREVIEW, strcat("/gfx/menu/", substring(s, 9, strlen(s) - 24), "/skinpreview"));
 110                 fh = fopen(language_filename(s), FILE_READ);
 111                 if(fh < 0)
 112                 {
 113                         print("Warning: can't open skinvalues.txt file\n");
 114                         continue;
 115                 }
 116                 while((s = fgets(fh)))
 117                 {
 118                         // these two are handled by skinlist.qc
 119                         if(substring(s, 0, 6) == "title ")
 120                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_TITLE, substring(s, 6, strlen(s) - 6));
 121                         else if(substring(s, 0, 7) == "author ")
 122                                 bufstr_set(buf, i * SKINPARM_COUNT + SKINPARM_AUTHOR, substring(s, 7, strlen(s) - 7));
 123                 }
 124                 fclose(fh);
 125         }
 126
 127         search_end(glob);
 128
 129         me.skinlist = buf;
 130         me.nItems = n;
 131 }
 132
 133 void XonoticSkinList_destroy(entity me)
 134 {
 135         buf_del(me.skinlist);
 136 }
 137
 138 void XonoticSkinList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 139 {
 140         me.itemAbsSize = '0 0 0';
 141         SUPER(XonoticSkinList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 142
 143         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 144         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 145         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
 146         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
 147
 148         me.columnPreviewOrigin = 0;
 149         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 150         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 151         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
 152 }
 153
 154 void XonoticSkinList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 155 {
 156         string s;
 157
 158         if(isSelected)
 159                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 160         else if(isFocused)
 161         {
 162                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 163                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 164         }
 165
 166         s = me.skinParameter(me, i, SKINPARM_PREVIEW);
 167         draw_Picture(me.columnPreviewOrigin * eX, s, me.columnPreviewSize * eX + eY, '1 1 1', 1);
 168
 169         s = me.skinParameter(me, i, SKINPARM_TITLE);
 170         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 171         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_TITLE, SKINALPHA_TEXT, 0);
 172
 173         s = me.skinParameter(me, i, SKINPARM_AUTHOR);
 174         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 175         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_SKINLIST_AUTHOR, SKINALPHA_TEXT, 0);
 176 }
 177
 178 void XonoticSkinList_setSkin(entity me)
 179 {
 180         me.saveCvars(me);
 181         localcmd("\nmenu_restart\nmenu_cmd skinselect\n");
 182 }
 183
 184 void SetSkin_Click(entity btn, entity me)
 185 {
 186         me.setSkin(me);
 187 }
 188
 189 void XonoticSkinList_doubleClickListBoxItem(entity me, float i, vector where)
 190 {
 191         m_play_click_sound(MENU_SOUND_EXECUTE);
 192         me.setSkin(me);
 193 }
 194
 195 float XonoticSkinList_keyDown(entity me, float scan, float ascii, float shift)
 196 {
 197         if(scan == K_ENTER || scan == K_KP_ENTER)
 198         {
 199                 m_play_click_sound(MENU_SOUND_EXECUTE);
 200                 me.setSkin(me);
 201                 return 1;
 202         }
 203         else
 204                 return SUPER(XonoticSkinList).keyDown(me, scan, ascii, shift);
 205 }
 206 #endif