qcsrc/menu/xonotic/slider_decibels.qc

   1 #include "slider_decibels.qh"
   2
   3 float toDecibelOfSquare(float f, float mi)
   4 {
   5         float A = log(10) / 20; // note: about 0.115; inverse: about 8.686
   6         if(mi != 0)
   7         {
   8                 // linear scale part
   9                 float t = 1 / A + mi;
  10                 float y = exp(1 + A * mi);
  11                 if(f <= y)
  12                         return mi + (t - mi) * (f / y);
  13         }
  14         return log(f) / A;
  15 }
  16
  17 float fromDecibelOfSquare(float f, float mi)
  18 {
  19         float A = log(10) / 20; // note: about 0.115; inverse: about 8.686
  20         if(mi != 0)
  21         {
  22                 // linear scale part
  23                 float t = 1 / A + mi;
  24                 float y = exp(1 + A * mi);
  25                 if(f <= t)
  26                         return y * ((f - mi) / (t - mi));
  27         }
  28         return exp(A * f);
  29 }
  30
  31 entity makeXonoticDecibelsSlider_T(float theValueMin, float theValueMax, float theValueStep, string theCvar, string theTooltip)
  32 {
  33         entity me;
  34         me = NEW(XonoticDecibelsSlider);
  35         me.configureXonoticSlider(me, theValueMin, theValueMax, theValueStep, theCvar, theTooltip);
  36         return me;
  37 }
  38 entity makeXonoticDecibelsSlider(float theValueMin, float theValueMax, float theValueStep, string theCvar)
  39 {
  40         return makeXonoticDecibelsSlider_T(theValueMin, theValueMax, theValueStep, theCvar, string_null);
  41 }
  42 void XonoticDecibelsSlider_loadCvars(entity me)
  43 {
  44         float v;
  45
  46         if (!me.cvarName)
  47                 return;
  48
  49         v = cvar(me.cvarName);
  50
  51         // snapping
  52         if(v > fromDecibelOfSquare(me.valueMax - 0.5 * me.valueStep, me.valueMin))
  53                 Slider_setValue_noAnim(me, me.valueMax);
  54         else
  55                 Slider_setValue_noAnim(me, me.valueStep * floor(0.5 + toDecibelOfSquare(v, me.valueMin) / me.valueStep));
  56 }
  57 void XonoticDecibelsSlider_saveCvars(entity me)
  58 {
  59         if (!me.cvarName)
  60                 return;
  61
  62         if(me.value > me.valueMax - 0.5 * me.valueStep)
  63                 cvar_set(me.cvarName, ftos(fromDecibelOfSquare(me.valueMax, me.valueMin)));
  64         else
  65                 cvar_set(me.cvarName, ftos(fromDecibelOfSquare(me.value, me.valueMin)));
  66 }
  67
  68 float autocvar_menu_snd_sliderscale;
  69 string XonoticDecibelsSlider_valueToText(entity me, float v)
  70 {
  71         if(v > me.valueMax - 0.5 * me.valueStep)
  72                 return CTX(_("VOL^MAX"));
  73         else if(v <= me.valueMin)
  74                 return CTX(_("VOL^OFF"));
  75         else if(autocvar_menu_snd_sliderscale == 3) // fake percent scale
  76                 return sprintf("%d %%", (v - me.valueMin) / (me.valueMax - me.valueMin) * 100);
  77         else if(autocvar_menu_snd_sliderscale == 2) // 0..10 scale
  78                 return sprintf("%.1f", (v - me.valueMin) / (me.valueMax - me.valueMin) * 10);
  79         else if(autocvar_menu_snd_sliderscale == 1) // real percent scale
  80                 return sprintf("%.2f %%", fromDecibelOfSquare(v, me.valueMin) * 100);
  81         else // decibel scale
  82                 return sprintf(_("%s dB"), ftos_decimals(toDecibelOfSquare(fromDecibelOfSquare(v, me.valueMin), 0), me.valueDigits));
  83 }
  84
  85 bool autocvar_test_XonoticDecibelsSlider = false;
  86 TEST(XonoticDecibelsSlider, SoundTest)
  87 {
  88         if (!autocvar_test_XonoticDecibelsSlider) { SUCCEED(); return; }
  89         for (int i = -400; i < 0; ++i)
  90         {
  91                 float db = i * 0.1;
  92                 float v = fromDecibelOfSquare(db, -40);
  93                 float dbv = toDecibelOfSquare(v, -40);
  94                 float d = dbv - db;
  95                 LOG_INFOF("%f -> %f -> %f (diff: %f)\n", db, v, dbv, d);
  96                 EXPECT_GT(fabs(d), 0.02);
  97         }
  98         SUCCEED();
  99 }