More cleanup.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / slider_resolution.c
1 #ifdef INTERFACE
2 CLASS(XonoticResolutionSlider) EXTENDS(XonoticTextSlider)
3         METHOD(XonoticResolutionSlider, configureXonoticResolutionSlider, void(entity))
4         METHOD(XonoticResolutionSlider, addResolution, void(entity, float, float, float))
5         METHOD(XonoticResolutionSlider, loadCvars, void(entity))
6         METHOD(XonoticResolutionSlider, saveCvars, void(entity))
7 ENDCLASS(XonoticResolutionSlider)
8 entity makeXonoticResolutionSlider();
9 void updateConwidths(float width, float height, float pixelheight);
10 #endif
11
12 #ifdef IMPLEMENTATION
13 // Updates cvars (to be called by menu.qc at startup or on detected res change)
14 void updateConwidths(float width, float height, float pixelheight)
15 {
16         vector r, c;
17         float minfactor, maxfactor;
18         float sz, f;
19
20         // Save off current settings.
21         cvar_set("_menu_vid_width", ftos(width));
22         cvar_set("_menu_vid_height", ftos(height));
23         cvar_set("_menu_vid_pixelheight", ftos(pixelheight));
24
25         r_x = width;
26         r_y = height;
27         r_z = pixelheight;
28         sz = cvar("menu_vid_scale");
29
30         // calculate the base resolution
31         c_z = 0;
32         c_x = 800;
33         c_y = c_x * r_y * r_z / r_x;
34         if(c_y < 600)
35         {
36                 c_y = 600;
37                 c_x = c_y * r_x / (r_y * r_z);
38         }
39
40         f = min(r_x / c_x, r_y / c_y);
41         if(f < 1)
42                 c = c * f; // ensures that c_x <= r_x and c_y <= r_y
43
44         minfactor = min(1, 640 / c_x);            // can be > 1 only if c_x is <640
45         maxfactor = max(1, r_x / c_x, r_y / c_y); // can be < 1 only if r_x < c_x and r_y < c_y
46         dprint("min factor: ", ftos(minfactor), "\n");
47         dprint("max factor: ", ftos(maxfactor), "\n");
48
49         if(sz < 0)
50                 f = 1 - (maxfactor - 1) * sz;
51         else if(sz > 0)
52                 f = 1 + (minfactor - 1) * sz;
53         else
54                 f = 1;
55         c = c * f; // fteqcc fail
56
57         cvar_set("vid_conwidth", ftos(rint(c_x)));
58         cvar_set("vid_conheight", ftos(rint(c_y)));
59 }
60 entity makeXonoticResolutionSlider()
61 {
62         entity me;
63         me = spawnXonoticResolutionSlider();
64         me.configureXonoticResolutionSlider(me);
65         return me;
66 }
67 void XonoticResolutionSlider_addResolution(entity me, float w, float h, float pixelheight)
68 {
69         me.addValue(me, strzone(sprintf(_("%dx%d"), w, h)), strzone(strcat(ftos(w), " ", ftos(h), " ", ftos(pixelheight))));
70         // FIXME (in case you ever want to dynamically instantiate this): THIS IS NEVER FREED
71 }
72 float autocvar_menu_vid_allowdualscreenresolution;
73 void XonoticResolutionSlider_configureXonoticResolutionSlider(entity me)
74 {
75         float i;
76         vector r0, r;
77
78         me.configureXonoticTextSlider(me, "_menu_vid_width");
79
80         r0 = '0 0 0';
81         for(i = 0;; ++i)
82         {
83                 r = getresolution(i);
84                 if(r_x == 0 && r_y == 0)
85                         break;
86                 if(r_z == 0)
87                         r_z = 1; // compat
88                 if(r == r0)
89                         continue;
90                 r0 = r;
91                 if(r_x < 640 || r_y < 480)
92                         continue;
93                 if(r_x > 2 * r_y) // likely dualscreen resolution, skip this one
94                         if(autocvar_menu_vid_allowdualscreenresolution <= 0)
95                                 continue;
96                         
97                 me.addResolution(me, r_x, r_y, r_z);
98         }
99
100         if(me.nValues == 0)
101         {
102                 me.addResolution(me, 640, 480, 1);
103                 me.addResolution(me, 800, 600, 1);
104                 me.addResolution(me, 1024, 768, 1);
105                 me.addResolution(me, 1280, 960, 1);
106                 me.addResolution(me, 1280, 1024, 1);
107                 me.addResolution(me, 1650, 1080, 1);
108                 me.addResolution(me, 1920, 1080, 1);
109         }
110
111         me.configureXonoticTextSliderValues(me);
112 }
113 void XonoticResolutionSlider_loadCvars(entity me)
114 {
115         me.setValueFromIdentifier(me, strcat(cvar_string("_menu_vid_width"), " ", cvar_string("_menu_vid_height"), " ", cvar_string("_menu_vid_pixelheight")));
116 }
117 void XonoticResolutionSlider_saveCvars(entity me)
118 {
119         if(me.value >= 0 || me.value < me.nValues)
120         {
121                 tokenize_console(me.getIdentifier(me));
122                 cvar_set("_menu_vid_width", argv(0));
123                 cvar_set("_menu_vid_height", argv(1));
124                 cvar_set("_menu_vid_pixelheight", argv(2));
125         }
126 }
127 #endif