qcsrc/menu/xonotic/slider_resolution.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticResolutionSlider) EXTENDS(XonoticTextSlider)
   3         METHOD(XonoticResolutionSlider, configureXonoticResolutionSlider, void(entity))
   4         METHOD(XonoticResolutionSlider, addResolution, void(entity, float, float, float))
   5         METHOD(XonoticResolutionSlider, loadCvars, void(entity))
   6         METHOD(XonoticResolutionSlider, saveCvars, void(entity))
   7 ENDCLASS(XonoticResolutionSlider)
   8 entity makeXonoticResolutionSlider();
   9 void updateConwidths();
  10 #endif
  11
  12 #ifdef IMPLEMENTATION
  13 void updateConwidths()
  14 {
  15         vector r, c;
  16         float minfactor, maxfactor;
  17         float sz, f;
  18         r_x = cvar("menu_vid_width");
  19         r_y = cvar("menu_vid_height");
  20         r_z = cvar("menu_vid_pixelheight");
  21         sz = cvar("menu_vid_scale");
  22
  23         // calculate the base resolution
  24         c_z = 0;
  25         c_x = 800;
  26         c_y = c_x * r_y * r_z / r_x;
  27         if(c_y < 600)
  28         {
  29                 c_y = 600;
  30                 c_x = c_y * r_x / (r_y * r_z);
  31         }
  32
  33         f = min(r_x / c_x, r_y / c_y);
  34         if(f < 1)
  35                 c = c * f; // ensures that c_x <= r_x and c_y <= r_y
  36
  37         minfactor = min(1, 640 / c_x);            // can be > 1 only if c_x is <640
  38         maxfactor = max(1, r_x / c_x, r_y / c_y); // can be < 1 only if r_x < c_x and r_y < c_y
  39         dprint("min factor: ", ftos(minfactor), "\n");
  40         dprint("max factor: ", ftos(maxfactor), "\n");
  41
  42         if(sz < 0)
  43                 f = 1 - (maxfactor - 1) * sz;
  44         else if(sz > 0)
  45                 f = 1 + (minfactor - 1) * sz;
  46         else
  47                 f = 1;
  48         c = c * f; // fteqcc fail
  49
  50         cvar_set("vid_width", ftos(rint(r_x)));
  51         cvar_set("vid_height", ftos(rint(r_y)));
  52         cvar_set("vid_pixelheight", ftos(rint(r_z)));
  53         cvar_set("vid_conwidth", ftos(rint(c_x)));
  54         cvar_set("vid_conheight", ftos(rint(c_y)));
  55 }
  56 entity makeXonoticResolutionSlider()
  57 {
  58         entity me;
  59         me = spawnXonoticResolutionSlider();
  60         me.configureXonoticResolutionSlider(me);
  61         return me;
  62 }
  63 void XonoticResolutionSlider_addResolution(entity me, float w, float h, float pixelheight)
  64 {
  65         me.addValue(me, strzone(sprintf(_("%dx%d"), w, h)), strzone(strcat(ftos(w), " ", ftos(h), " ", ftos(pixelheight))));
  66         // FIXME (in case you ever want to dynamically instantiate this): THIS IS NEVER FREED
  67 }
  68 void XonoticResolutionSlider_configureXonoticResolutionSlider(entity me)
  69 {
  70         float i;
  71         vector r0, r;
  72
  73         me.configureXonoticTextSlider(me, "menu_vid_width");
  74
  75         r0 = '0 0 0';
  76         for(i = 0;; ++i)
  77         {
  78                 r = getresolution(i);
  79                 if(r_x == 0 && r_y == 0)
  80                         break;
  81                 if(r_z == 0)
  82                         r_z = 1; // compat
  83                 if(r == r0)
  84                         continue;
  85                 r0 = r;
  86                 if(r_x < 640 || r_y < 480)
  87                         continue;
  88                 if(r_x > 2 * r_y) // likely dualscreen resolution, skip this one
  89                         continue;
  90                 me.addResolution(me, r_x, r_y, r_z);
  91         }
  92
  93         if(me.nValues == 0)
  94         {
  95                 me.addResolution(me, 640, 480, 1);
  96                 me.addResolution(me, 800, 600, 1);
  97                 me.addResolution(me, 1024, 768, 1);
  98                 me.addResolution(me, 1280, 960, 1);
  99                 me.addResolution(me, 1280, 1024, 1);
 100                 me.addResolution(me, 1650, 1080, 1);
 101                 me.addResolution(me, 1920, 1080, 1);
 102         }
 103
 104         me.configureXonoticTextSliderValues(me);
 105 }
 106 void XonoticResolutionSlider_loadCvars(entity me)
 107 {
 108         me.setValueFromIdentifier(me, strcat(cvar_string("menu_vid_width"), " ", cvar_string("menu_vid_height"), " ", cvar_string("menu_vid_pixelheight")));
 109 }
 110 void XonoticResolutionSlider_saveCvars(entity me)
 111 {
 112         if(me.value >= 0 || me.value < me.nValues)
 113         {
 114                 tokenize_console(me.getIdentifier(me));
 115                 cvar_set("menu_vid_width", argv(0));
 116                 cvar_set("menu_vid_height", argv(1));
 117                 cvar_set("menu_vid_pixelheight", argv(2));
 118         }
 119 }
 120 #endif