qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 float tooltipdb;
  12 void loadTooltips()
  13 {
  14         tooltipdb = db_load(language_filename("tooltips.db"));
  15 }
  16 void unloadTooltips()
  17 {
  18         if(tooltipdb >= 0)
  19                 db_close(tooltipdb);
  20         tooltipdb = -1;
  21 }
  22 string getZonedTooltipForIdentifier(string s)
  23 {
  24         string t;
  25         if(s == "")
  26                 return string_null;
  27         if(tooltipdb >= 0)
  28         {
  29                 t = db_get(tooltipdb, s);
  30                 if(t == "-")
  31                         return string_null;
  32                 if(t != "")
  33                         return strzone(t);
  34         }
  35         if(prvm_language == "en" || prvm_language == "")
  36         {
  37                 t = cvar_description(s);
  38                 if(t != "" && t != "custom cvar")
  39                         return strzone(t);
  40         }
  41         dprint("WARNING: no tooltip set for ", s, "\n");
  42         return string_null;
  43 }
  44
  45 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  46 {
  47         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  48 }
  49
  50 .string cvarName;
  51 void SUB_Null_ee(entity e1, entity e2)
  52 {
  53 }
  54 void saveCvarsOf(entity ignore, entity e)
  55 {
  56         if(e.saveCvars)
  57                 e.saveCvars(e);
  58 }
  59 void loadCvarsOf(entity ignore, entity e)
  60 {
  61         if(e.loadCvars)
  62                 e.loadCvars(e);
  63 }
  64 void saveAllCvars(entity root)
  65 {
  66         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  67 }
  68 void loadAllCvars(entity root)
  69 {
  70         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  71 }
  72
  73 .string cvarNames_Multi;
  74 .void(entity me) saveCvars_Multi;
  75 void saveCvarsMulti(entity me)
  76 {
  77         float n, i;
  78         string s;
  79
  80         me.saveCvars_Multi(me);
  81         s = cvar_string(me.cvarName);
  82
  83         n = tokenize_console(me.cvarNames_Multi);
  84         for(i = 0; i < n; ++i)
  85                 cvar_set(argv(i), s);
  86 }
  87 void makeMulti(entity e, string otherCvars)
  88 {
  89         e.cvarNames_Multi = otherCvars;
  90         e.saveCvars_Multi = e.saveCvars;
  91         e.saveCvars = saveCvarsMulti;
  92 }
  93
  94 .void(entity me) saveCvars_Callback;
  95 .entity saveCvars_Callback_ent;
  96 .void(entity me, entity cb) saveCvars_Callback_func;
  97 void saveCvarsCallback(entity me)
  98 {
  99         me.saveCvars_Callback(me);
 100         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 101 }
 102 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 103 {
 104         e.saveCvars_Callback = e.saveCvars;
 105         e.saveCvars = saveCvarsCallback;
 106         e.saveCvars_Callback_ent = cbent;
 107         e.saveCvars_Callback_func = cbfunc;
 108 }
 109
 110 .void(entity) draw_setDependent;
 111 .string cvar_setDependent;
 112 .float cvarMin_setDependent;
 113 .float cvarMax_setDependent;
 114 .string cvar2_setDependent;
 115 .float cvar2Min_setDependent;
 116 .float cvar2Max_setDependent;
 117 .string cvar3_setDependent;
 118 .float cvar3Min_setDependent;
 119 .float cvar3Max_setDependent;
 120 .float op_setDependent;
 121 .string cvarString_setDependent;
 122 .string cvarValue_setDependent;
 123 .float(entity) func_setDependent;
 124 void setDependent_Check(entity e)
 125 {
 126         float f;
 127         string s;
 128         if(e.func_setDependent)
 129         {
 130                 e.disabled = !(e.func_setDependent(e));
 131         }
 132         else if(e.cvarString_setDependent)
 133         {
 134                 s = cvar_string(e.cvarString_setDependent);
 135                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 136         }
 137         else
 138         {
 139                 if(e.cvar_setDependent)
 140                 {
 141                         f = cvar(e.cvar_setDependent);
 142                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 143                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 144                         else
 145                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 146                 }
 147                 if(e.cvar2_setDependent)
 148                 {
 149                         f = cvar(e.cvar2_setDependent);
 150                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 151                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 152                         else
 153                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 154                 }
 155                 if(e.cvar3_setDependent)
 156                 {
 157                         f = cvar(e.cvar3_setDependent);
 158                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 159                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 160                         else
 161                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 162                 }
 163         }
 164 }
 165 void setDependent_Draw(entity e)
 166 {
 167         setDependent_Check(e);
 168         e.draw_setDependent(e);
 169 }
 170 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 171 {
 172         e.draw_setDependent = e.draw;
 173         e.cvar_setDependent = theCvarName;
 174         e.cvarMin_setDependent = theCvarMin;
 175         e.cvarMax_setDependent = theCvarMax;
 176         e.cvar2_setDependent = string_null;
 177         e.cvar3_setDependent = string_null;
 178         e.func_setDependent = func_null;
 179         e.draw = setDependent_Draw;
 180         setDependent_Check(e);
 181 }
 182 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 183 {
 184         e.draw_setDependent = e.draw;
 185         e.cvarString_setDependent = theCvarName;
 186         e.cvarValue_setDependent = theCvarValue;
 187         e.cvar_setDependent = string_null;
 188         e.cvar2_setDependent = string_null;
 189         e.cvar3_setDependent = string_null;
 190         e.func_setDependent = func_null;
 191         e.draw = setDependent_Draw;
 192         setDependent_Check(e);
 193 }
 194 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 195 {
 196         e.draw_setDependent = e.draw;
 197         e.cvar_setDependent = theCvarName;
 198         e.cvarMin_setDependent = theCvarMin;
 199         e.cvarMax_setDependent = theCvarMax;
 200         e.cvar2_setDependent = theCvar2Name;
 201         e.cvar2Min_setDependent = theCvar2Min;
 202         e.cvar2Max_setDependent = theCvar2Max;
 203         e.cvar3_setDependent = string_null;
 204         e.op_setDependent = 0;
 205         e.func_setDependent = func_null;
 206         e.draw = setDependent_Draw;
 207         setDependent_Check(e);
 208 }
 209 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 210 {
 211         e.draw_setDependent = e.draw;
 212         e.cvar_setDependent = theCvarName;
 213         e.cvarMin_setDependent = theCvarMin;
 214         e.cvarMax_setDependent = theCvarMax;
 215         e.cvar2_setDependent = theCvar2Name;
 216         e.cvar2Min_setDependent = theCvar2Min;
 217         e.cvar2Max_setDependent = theCvar2Max;
 218         e.cvar3_setDependent = string_null;
 219         e.op_setDependent = 1;
 220         e.func_setDependent = func_null;
 221         e.draw = setDependent_Draw;
 222         setDependent_Check(e);
 223 }
 224 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 225 {
 226         e.draw_setDependent = e.draw;
 227         e.cvar_setDependent = theCvarName;
 228         e.cvarMin_setDependent = theCvarMin;
 229         e.cvarMax_setDependent = theCvarMax;
 230         e.cvar2_setDependent = theCvar2Name;
 231         e.cvar2Min_setDependent = theCvar2Min;
 232         e.cvar2Max_setDependent = theCvar2Max;
 233         e.cvar3_setDependent = theCvar3Name;
 234         e.cvar3Min_setDependent = theCvar3Min;
 235         e.cvar3Max_setDependent = theCvar3Max;
 236         e.op_setDependent = 0;
 237         e.func_setDependent = func_null;
 238         e.draw = setDependent_Draw;
 239         setDependent_Check(e);
 240 }
 241 void setDependentWeird(entity e, float(entity) func)
 242 {
 243         e.draw_setDependent = e.draw;
 244         e.func_setDependent = func;
 245         e.draw = setDependent_Draw;
 246         setDependent_Check(e);
 247 }
 248
 249 // URI SYSTEM ////////////////////////////////////////////////////////
 250
 251 float _Nex_ExtResponseSystem_Queried;
 252 string _Nex_ExtResponseSystem_UpdateTo;
 253
 254 void URI_Get_Callback(float id, float status, string data)
 255 {
 256         if (id == URI_GET_DISCARD)
 257         {
 258                 // discard
 259         }
 260         else if(id == URI_GET_UPDATENOTIFICATION)
 261         {
 262                 UpdateNotification_URI_Get_Callback(id, status, data);
 263         }
 264         else if(id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 265         {
 266                 Curl_URI_Get_Callback(id, status, data);
 267         }
 268         else
 269         {
 270                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
 271         }
 272 }
 273
 274 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 275 {
 276         float n;
 277
 278         if(_Nex_ExtResponseSystem_UpdateTo)
 279         {
 280                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 281                 return;
 282         }
 283         if(status != 0)
 284         {
 285                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 286                 return;
 287         }
 288         if(substring(data, 0, 1) == "<")
 289         {
 290                 print(_("error: received HTML instead of an update notification\n"));
 291                 return;
 292         }
 293         if(strstrofs(data, "\r", 0) != -1)
 294         {
 295                 print(_("error: received carriage returns from update notification server\n"));
 296                 return;
 297         }
 298
 299         if(data == "")
 300                 n = 0;
 301         else
 302                 n = tokenizebyseparator(data, "\n");
 303
 304         if(n >= 1)
 305         {
 306                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 307
 308                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 309                 {
 310                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 311                 }
 312                 else
 313                 {
 314                         // update needed
 315                         if(n >= 2)
 316                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 317                 }
 318
 319                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 320         }
 321 }
 322
 323 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 324
 325 float preMenuInit()
 326 {
 327         vector sz;
 328         vector boxA, boxB;
 329
 330         MapInfo_Cache_Create();
 331         MapInfo_Enumerate();
 332         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 333         {
 334                 draw_reset_cropped();
 335
 336                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 337                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 338
 339                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 340                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 341                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 342
 343                 boxA += sz * 0.1;
 344                 boxB -= sz * 0.1;
 345                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 346
 347                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 348                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 349
 350                 return FALSE;
 351         }
 352         return TRUE;
 353 }
 354
 355 string campaign_name_previous;
 356 float campaign_won_previous;
 357 #ifdef WATERMARK
 358 var string autocvar_menu_watermark = WATERMARK();
 359 #else
 360 var string autocvar_menu_watermark = "";
 361 #endif
 362 void postMenuDraw()
 363 {
 364         if(autocvar_menu_watermark != "")
 365         {
 366                 vector fs = '48 48 0';
 367                 draw_CenterText('0.5 0.1 0', autocvar_menu_watermark, globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 368         }
 369 }
 370 void preMenuDraw()
 371 {
 372         vector fs, sz, line, mid;
 373
 374         if(cvar("menu_updatecheck"))
 375         {
 376                 if(!_Nex_ExtResponseSystem_Queried)
 377                 {
 378                         _Nex_ExtResponseSystem_Queried = 1;
 379                         float startcnt;
 380                         string uri;
 381
 382                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 383
 384                         // for privacy, munge the start count a little
 385                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 386                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 387
 388 #ifdef CVAR_POPCON
 389                         float cvar_handle, popcon_handle;
 390                         float n, i, j;
 391                         string k, s;
 392                         cvar_handle = buf_create();
 393                         buf_cvarlist(cvar_handle, "", "");
 394                         n = buf_getsize(cvar_handle);
 395                         popcon_handle = buf_create();
 396                         for(i= 0, j = 0; i < n; ++i)
 397                         {
 398                                 k = bufstr_get(cvar_handle, i);
 399                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 400                                         continue;
 401                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 402                                 bufstr_set(popcon_handle, j, s);
 403                                 ++j;
 404                         }
 405                         buf_del(cvar_handle);
 406                         uri_postbuf(
 407                                 uri, URI_GET_UPDATENOTIFICATION,
 408                                 "application/x-www-form-urlencoded",
 409                                 "&",
 410                                 popcon_handle
 411                         );
 412                         buf_del(popcon_handle);
 413 #else
 414                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 415 #endif
 416                 }
 417         }
 418
 419         if(_Nex_ExtResponseSystem_UpdateTo != "")
 420         {
 421                 // TODO rather turn this into a dialog
 422                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 423                 line = eY * fs_y;
 424                 sz_x = draw_TextWidth("  http://www.xonotic.org/  ", 0, fs);
 425                 sz_y = 3 * fs_y;
 426
 427                 draw_alpha = sin(time * 0.112 - 0.3) * 10;
 428                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 429                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 430
 431                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 432                 draw_CenterText(mid - 1 * line, sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo), fs, '1 0 0', 1, 0);
 433                 draw_CenterText(mid - 0 * line, "http://www.xonotic.org/", fs, '0 0 1', 1, 0);
 434         }
 435         if not(campaign_name_previous)
 436                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 437         if(campaign_name == campaign_name_previous)
 438         {
 439                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 440                 {
 441                         if(!campaign_won_previous)
 442                         {
 443                                 m_display();
 444                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 445                         }
 446                         campaign_won_previous = 1;
 447                 }
 448                 else
 449                         campaign_won_previous = 0;
 450         }
 451         else
 452         {
 453                 strunzone(campaign_name_previous);
 454                 campaign_name_previous = strzone(campaign_name);
 455                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 456         }
 457 }
 458
 459 string resolvemod(string m)
 460 {
 461         if(m == "=")
 462                 return getcurrentmod();
 463         else
 464                 return m;
 465 }
 466
 467 string HUD_Panel_GetSettingName(float theSetting)
 468 {
 469         switch(theSetting) {
 470                 case HUD_MENU_ENABLE: return ""; break;
 471                 default: return "";
 472         }
 473 }
 474
 475 float updateCompression()
 476 {
 477         float fh;
 478         float have_dds, have_jpg, have_tga;
 479         float can_dds;
 480         if((have_dds = ((fh = fopen("dds/particles/particlefont.dds", FILE_READ)) >= 0)))
 481                 fclose(fh);
 482         if((have_jpg = ((fh = fopen("particles/particlefont.jpg", FILE_READ)) >= 0)))
 483                 fclose(fh);
 484         if((have_tga = ((fh = fopen("particles/particlefont.tga", FILE_READ)) >= 0)))
 485                 fclose(fh);
 486         can_dds = GL_Have_TextureCompression();
 487         if(have_dds && (have_jpg || have_tga))
 488         {
 489                 // both? Let's only use good quality precompressed files
 490                 // but ONLY if we actually support it!
 491                 if(can_dds)
 492                 {
 493                         cvar_set("gl_texturecompression", "0");
 494                         return 1;
 495                 }
 496                 else
 497                 {
 498                         cvar_set("gl_texturecompression", "0");
 499                         cvar_set("r_texture_dds_load", "0");
 500                         return 0;
 501                 }
 502         }
 503         else if(have_dds)
 504         {
 505                 // DDS only? We probably always want texture compression
 506                 cvar_set("gl_texturecompression", "1");
 507                 cvar_set("r_texture_dds_load", "1");
 508                 if(!can_dds)
 509                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 510                 return 0;
 511         }
 512         else
 513         {
 514                 // TGA only? Allow runtime compression
 515                 if(can_dds)
 516                 {
 517                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 518                         return 2;
 519                 }
 520                 else
 521                 {
 522                         cvar_set("gl_texturecompression", "0");
 523                         cvar_set("r_texture_dds_load", "0");
 524                         return 0;
 525                 }
 526         }
 527 }
 528
 529 // note: include only those that should be in the menu!
 530 #define GAMETYPES \
 531         GAMETYPE(MAPINFO_TYPE_ARENA, _("Arena")) \
 532         GAMETYPE(MAPINFO_TYPE_ASSAULT, _("Assault")) \
 533         GAMETYPE(MAPINFO_TYPE_CTF, _("Capture The Flag")) \
 534         GAMETYPE(MAPINFO_TYPE_CA, _("Clan Arena")) \
 535         GAMETYPE(MAPINFO_TYPE_DEATHMATCH, _("Deathmatch")) \
 536         GAMETYPE(MAPINFO_TYPE_DOMINATION, _("Domination")) \
 537         GAMETYPE(MAPINFO_TYPE_FREEZETAG, _("Freeze Tag")) \
 538         GAMETYPE(MAPINFO_TYPE_KEEPAWAY, _("Keepaway")) \
 539         GAMETYPE(MAPINFO_TYPE_KEYHUNT, _("Key Hunt")) \
 540         GAMETYPE(MAPINFO_TYPE_LMS, _("Last Man Standing")) \
 541         GAMETYPE(MAPINFO_TYPE_NEXBALL, _("Nexball")) \
 542         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT, _("Onslaught")) \
 543         GAMETYPE(MAPINFO_TYPE_RACE, _("Race")) \
 544         GAMETYPE(MAPINFO_TYPE_CTS, _("Race CTS")) \
 545         GAMETYPE(MAPINFO_TYPE_RUNEMATCH, _("Runematch")) \
 546         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH, _("Team Deathmatch")) \
 547         /* nothing */
 548
 549 float GameType_GetID(float cnt)
 550 {
 551         float i;
 552         i = 0;
 553 #define GAMETYPE(id,name) if(i++ == cnt) return id;
 554         GAMETYPES
 555 #undef GAMETYPE
 556         return 0;
 557 }
 558 string GameType_GetName(float cnt)
 559 {
 560         float i;
 561         i = 0;
 562 #define GAMETYPE(id,name) if(i++ == cnt) return name;
 563         GAMETYPES
 564 #undef GAMETYPE
 565         return _("@!#%'n Tuba Throwing");
 566 }
 567 float GameType_GetCount()
 568 {
 569         float i;
 570         i = 0;
 571 #define GAMETYPE(id,name) ++i;
 572         GAMETYPES
 573 #undef GAMETYPE
 574         return i;
 575 }
 576
 577 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 578 {
 579         float i;
 580         entity e;
 581
 582         me.TR(me);
 583                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 584                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 585                                 e.addValue(e, _("Default"), "");
 586                                 e.addValue(e, _("Disable"), "0");
 587                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 588                                 e.configureXonoticTextSliderValues(e);
 589         me.TR(me);
 590                 me.TDempty(me, 0.2);
 591                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 592                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 593                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 594         me.TR(me);
 595                 me.TDempty(me, 0.2);
 596                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 597         me.TR(me);
 598                 me.TDempty(me, 0.2);
 599                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 600                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 601                                 e.addValue(e, _("Default"), "");
 602                                 e.addValue(e, _("Disable"), "0");
 603                                 for(i = 1; i <= 10; ++i)
 604                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 605                                 e.configureXonoticTextSliderValues(e);
 606         me.TR(me);
 607                 me.TDempty(me, 0.2);
 608                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 609                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 610                                 e.addValue(e, _("Default"), "");
 611                                 for(i = 1; i <= 10; ++i)
 612                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 613                                 e.configureXonoticTextSliderValues(e);
 614         me.TR(me);
 615                 me.TDempty(me, 0.2);
 616                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 617                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 618                                 e.addValue(e, _("Default"), "");
 619                                 e.addValue(e, _("Disable"), "0");
 620                                 for(i = 1; i <= 10; ++i)
 621                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 622                                 e.configureXonoticTextSliderValues(e);
 623         me.TR(me);
 624                 me.TDempty(me, 0.4);
 625                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 626         me.TR(me);
 627                 me.TDempty(me, 0.2);
 628                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 629                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 630                                 e.addValue(e, _("Default"), "");
 631                                 for(i = 0; i <= 10; ++i)
 632                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 633                                 e.configureXonoticTextSliderValues(e);
 634 }