start loading update URL earlier
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / util.qc
1 float GL_CheckExtension(string ext)
2 {
3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
4 }
5
6 float GL_Have_TextureCompression()
7 {
8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
9 }
10
11 void loadTooltips()
12 {
13         tooltipdb = db_load(language_filename("tooltips.db"));
14 }
15 void unloadTooltips()
16 {
17         if(tooltipdb >= 0)
18                 db_close(tooltipdb);
19         tooltipdb = -1;
20 }
21 string getZonedTooltipForIdentifier(string s)
22 {
23         string t;
24         if(s == "")
25                 return string_null;
26         if(tooltipdb >= 0)
27         {
28                 t = db_get(tooltipdb, s);
29                 if(t == "-")
30                         return string_null;
31                 if(t != "")
32                         return strzone(t);
33         }
34         if(prvm_language == "en")
35         {
36                 t = cvar_description(s);
37                 if(t != "" && t != "custom cvar")
38                         return strzone(t);
39         }
40         dprint("WARNING: no tooltip set for ", s, "\n");
41         return string_null;
42 }
43
44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
45 {
46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
47 }
48
49 .string cvarName;
50 void SUB_Null_ee(entity e1, entity e2)
51 {
52 }
53 void saveCvarsOf(entity ignore, entity e)
54 {
55         if(e.saveCvars)
56                 e.saveCvars(e);
57 }
58 void loadCvarsOf(entity ignore, entity e)
59 {
60         if(e.loadCvars)
61                 e.loadCvars(e);
62 }
63 void saveAllCvars(entity root)
64 {
65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
66 }
67 void loadAllCvars(entity root)
68 {
69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
70 }
71
72 .string cvarNames_Multi;
73 .void(entity me) saveCvars_Multi;
74 string getCvarsMulti(entity me)
75 {
76         if (me.cvarNames_Multi)
77                 return me.cvarNames_Multi;
78         return string_null;
79 }
80 void saveCvarsMulti(entity me)
81 {
82         float n, i;
83         string s;
84
85         me.saveCvars_Multi(me);
86         s = cvar_string(me.cvarName);
87
88         n = tokenize_console(me.cvarNames_Multi);
89         for(i = 0; i < n; ++i)
90                 cvar_set(argv(i), s);
91 }
92 void makeMulti(entity e, string otherCvars)
93 {
94         e.cvarNames_Multi = otherCvars;
95         e.saveCvars_Multi = e.saveCvars;
96         e.saveCvars = saveCvarsMulti;
97 }
98
99 .void(entity me) saveCvars_Callback;
100 .entity saveCvars_Callback_ent;
101 .void(entity me, entity cb) saveCvars_Callback_func;
102 void saveCvarsCallback(entity me)
103 {
104         me.saveCvars_Callback(me);
105         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
106 }
107 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
108 {
109         e.saveCvars_Callback = e.saveCvars;
110         e.saveCvars = saveCvarsCallback;
111         e.saveCvars_Callback_ent = cbent;
112         e.saveCvars_Callback_func = cbfunc;
113 }
114
115 .void(entity) draw_setDependent;
116 .string cvar_setDependent;
117 .float cvarMin_setDependent;
118 .float cvarMax_setDependent;
119 .string cvar2_setDependent;
120 .float cvar2Min_setDependent;
121 .float cvar2Max_setDependent;
122 .string cvar3_setDependent;
123 .float cvar3Min_setDependent;
124 .float cvar3Max_setDependent;
125 .float op_setDependent;
126 .string cvarString_setDependent;
127 .string cvarValue_setDependent;
128 .float(entity) func_setDependent;
129 void setDependent_Check(entity e)
130 {
131         float f;
132         string s;
133         if(e.func_setDependent)
134         {
135                 e.disabled = !(e.func_setDependent(e));
136         }
137         else if(e.cvarString_setDependent)
138         {
139                 s = cvar_string(e.cvarString_setDependent);
140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
141         }
142         else
143         {
144                 if(e.cvar_setDependent)
145                 {
146                         f = cvar(e.cvar_setDependent);
147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
149                         else
150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
151                 }
152                 if(e.cvar2_setDependent)
153                 {
154                         f = cvar(e.cvar2_setDependent);
155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
157                         else
158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
159                 }
160                 if(e.cvar3_setDependent)
161                 {
162                         f = cvar(e.cvar3_setDependent);
163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
165                         else
166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
167                 }
168         }
169 }
170 void setDependent_Draw(entity e)
171 {
172         setDependent_Check(e);
173         e.draw_setDependent(e);
174 }
175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
176 {
177         e.draw_setDependent = e.draw;
178         e.cvar_setDependent = theCvarName;
179         e.cvarMin_setDependent = theCvarMin;
180         e.cvarMax_setDependent = theCvarMax;
181         e.cvar2_setDependent = string_null;
182         e.cvar3_setDependent = string_null;
183         e.func_setDependent = func_null;
184         e.draw = setDependent_Draw;
185         setDependent_Check(e);
186 }
187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
188 {
189         e.draw_setDependent = e.draw;
190         e.cvarString_setDependent = theCvarName;
191         e.cvarValue_setDependent = theCvarValue;
192         e.cvar_setDependent = string_null;
193         e.cvar2_setDependent = string_null;
194         e.cvar3_setDependent = string_null;
195         e.func_setDependent = func_null;
196         e.draw = setDependent_Draw;
197         setDependent_Check(e);
198 }
199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
200 {
201         e.draw_setDependent = e.draw;
202         e.cvar_setDependent = theCvarName;
203         e.cvarMin_setDependent = theCvarMin;
204         e.cvarMax_setDependent = theCvarMax;
205         e.cvar2_setDependent = theCvar2Name;
206         e.cvar2Min_setDependent = theCvar2Min;
207         e.cvar2Max_setDependent = theCvar2Max;
208         e.cvar3_setDependent = string_null;
209         e.op_setDependent = 0;
210         e.func_setDependent = func_null;
211         e.draw = setDependent_Draw;
212         setDependent_Check(e);
213 }
214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
215 {
216         e.draw_setDependent = e.draw;
217         e.cvar_setDependent = theCvarName;
218         e.cvarMin_setDependent = theCvarMin;
219         e.cvarMax_setDependent = theCvarMax;
220         e.cvar2_setDependent = theCvar2Name;
221         e.cvar2Min_setDependent = theCvar2Min;
222         e.cvar2Max_setDependent = theCvar2Max;
223         e.cvar3_setDependent = string_null;
224         e.op_setDependent = 1;
225         e.func_setDependent = func_null;
226         e.draw = setDependent_Draw;
227         setDependent_Check(e);
228 }
229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
230 {
231         e.draw_setDependent = e.draw;
232         e.cvar_setDependent = theCvarName;
233         e.cvarMin_setDependent = theCvarMin;
234         e.cvarMax_setDependent = theCvarMax;
235         e.cvar2_setDependent = theCvar2Name;
236         e.cvar2Min_setDependent = theCvar2Min;
237         e.cvar2Max_setDependent = theCvar2Max;
238         e.cvar3_setDependent = theCvar3Name;
239         e.cvar3Min_setDependent = theCvar3Min;
240         e.cvar3Max_setDependent = theCvar3Max;
241         e.op_setDependent = 0;
242         e.func_setDependent = func_null;
243         e.draw = setDependent_Draw;
244         setDependent_Check(e);
245 }
246 void setDependentWeird(entity e, float(entity) func)
247 {
248         e.draw_setDependent = e.draw;
249         e.func_setDependent = func;
250         e.draw = setDependent_Draw;
251         setDependent_Check(e);
252 }
253
254 // URI SYSTEM ////////////////////////////////////////////////////////
255
256 float _Nex_ExtResponseSystem_Queried;
257 string _Nex_ExtResponseSystem_UpdateTo;
258 string _Nex_ExtResponseSystem_UpdateToURL;
259 string _Nex_ExtResponseSystem_Packs;
260 float _Nex_ExtResponseSystem_PacksStep;
261
262 void URI_Get_Callback(float id, float status, string data)
263 {
264         if(url_URI_Get_Callback(id, status, data))
265         {
266                 // handled
267         }
268         else if (id == URI_GET_DISCARD)
269         {
270                 // discard
271         }
272         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
273         {
274                 // sv_cmd curl
275                 Curl_URI_Get_Callback(id, status, data);
276         }
277         else if (id == URI_GET_UPDATENOTIFICATION)
278         {
279                 UpdateNotification_URI_Get_Callback(id, status, data);
280         }
281         else
282         {
283                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
284         }
285 }
286
287 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
288 {
289         float n;
290
291         if(_Nex_ExtResponseSystem_UpdateTo)
292         {
293                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
294                 return;
295         }
296         if(status != 0)
297         {
298                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
299                 return;
300         }
301         if(substring(data, 0, 1) == "<")
302         {
303                 print(_("error: received HTML instead of an update notification\n"));
304                 return;
305         }
306         if(strstrofs(data, "\r", 0) != -1)
307         {
308                 print(_("error: received carriage returns from update notification server\n"));
309                 return;
310         }
311
312         if(data == "")
313                 n = 0;
314         else
315                 n = tokenizebyseparator(data, "\n");
316         
317         if(n >= 1)
318         {
319                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
320
321                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
322                 {
323                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
324                 }
325                 else
326                 {
327                         // update needed
328                         if(n >= 2)
329                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
330                         if(n >= 3)
331                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
332                 }
333
334                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
335
336                 if(n >= 4)
337                 {
338                         _Nex_ExtResponseSystem_BannedServers = strzone(argv(3));
339                         _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
340                 }
341
342                 if(n >= 5)
343                 {
344                         if(cvar("menu_updatecheck_getpacks"))
345                         {
346                                 _Nex_ExtResponseSystem_Packs = strzone(argv(4));
347                                 _Nex_ExtResponseSystem_PacksStep = 1;
348                         }
349                 }
350         }
351 }
352
353 // END OF URI SYSTEM ////////////////////////////////////////////////////////
354
355 void updateCheck()
356 {
357         if(cvar("menu_updatecheck"))
358         {
359                 if(!_Nex_ExtResponseSystem_Queried)
360                 {
361                         _Nex_ExtResponseSystem_Queried = 1;
362                         float startcnt;
363                         string uri;
364
365                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
366
367                         // for privacy, munge the start count a little
368                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
369                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
370
371 #ifdef CVAR_POPCON
372                         float cvar_handle, popcon_handle;
373                         float n, i, j;
374                         string k, s;
375                         cvar_handle = buf_create();
376                         buf_cvarlist(cvar_handle, "", "");
377                         n = buf_getsize(cvar_handle);
378                         popcon_handle = buf_create();
379                         for(i= 0, j = 0; i < n; ++i)
380                         {
381                                 k = bufstr_get(cvar_handle, i);
382                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
383                                         continue;
384                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
385                                 bufstr_set(popcon_handle, j, s);
386                                 ++j;
387                         }
388                         buf_del(cvar_handle);
389                         uri_postbuf(
390                                 uri, URI_GET_UPDATENOTIFICATION,
391                                 "application/x-www-form-urlencoded",
392                                 "&",
393                                 popcon_handle
394                         );
395                         buf_del(popcon_handle);
396 #else
397                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
398 #endif
399                 }
400         }
401
402         if(_Nex_ExtResponseSystem_PacksStep > 0)
403         {
404                 float n, i;
405                 float allgood;
406                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
407                 allgood = TRUE;
408                 for(i = 0; i+1 < n; i += 2)
409                 {
410                         if(fexists(argv(i+1)))
411                                 continue;
412                         allgood = FALSE;
413                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
414                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
415                 }
416                 if(allgood)
417                 {
418                         if(_Nex_ExtResponseSystem_PacksStep == 2)
419                         {
420                                 if(!Menu_Active)
421                                         cvar_set("_menu_initialized", "0");
422                                         // HACK: cause m_hide call on next start
423                                 localcmd("\nmenu_restart\n");
424                         }
425                         _Nex_ExtResponseSystem_PacksStep = 0;
426                 }
427                 else
428                         _Nex_ExtResponseSystem_PacksStep = 2;
429         }
430
431 }
432
433 float preMenuInit()
434 {
435         vector sz;
436         vector boxA, boxB;
437
438         updateCheck();
439
440         MapInfo_Cache_Create();
441         MapInfo_Enumerate();
442         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
443         {
444                 draw_reset_cropped();
445
446                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
447                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
448
449                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
450                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
451                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
452                 
453                 boxA += sz * 0.1;
454                 boxB -= sz * 0.1;
455                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
456
457                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
458                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
459
460                 return FALSE;
461         }
462         return TRUE;
463 }
464
465 string campaign_name_previous;
466 float campaign_won_previous;
467 #ifdef WATERMARK
468 var string autocvar_menu_watermark = WATERMARK();
469 #else
470 var string autocvar_menu_watermark = "";
471 #endif
472 void postMenuDraw()
473 {
474         if(autocvar_menu_watermark != "")
475         {
476                 vector fs = '48 48 0';
477                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
478         }
479 }
480 void preMenuDraw()
481 {
482         vector fs, sz, line, mid;
483
484         updateCheck();
485
486         if(_Nex_ExtResponseSystem_UpdateTo != "")
487         {
488                 // TODO rather turn this into a dialog
489                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
490                 line = eY * fs_y;
491                 string l1, l2;
492                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
493                 l2 = "http://www.xonotic.org/";
494                 if(_Nex_ExtResponseSystem_UpdateToURL)
495                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
496
497                 sz_x = draw_TextWidth("    ", 0, fs) + max(
498                                 draw_TextWidth(l1, 0, fs),
499                                 draw_TextWidth(l2, 0, fs)
500                         );
501                 sz_y = 3 * fs_y;
502
503                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
504                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
505                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
506
507                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
508                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
509                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
510         }
511         if not(campaign_name_previous)
512                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
513         if(campaign_name == campaign_name_previous)
514         {
515                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
516                 {
517                         if(!campaign_won_previous)
518                         {
519                                 m_display();
520                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
521                         }
522                         campaign_won_previous = 1;
523                 }
524                 else
525                         campaign_won_previous = 0;
526         }
527         else
528         {
529                 strunzone(campaign_name_previous);
530                 campaign_name_previous = strzone(campaign_name);
531                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
532         }
533 }
534
535 string resolvemod(string m)
536 {
537         if(m == "=")
538                 return getcurrentmod();
539         else
540                 return m;
541 }
542
543 float updateCompression()
544 {
545         float have_dds, have_jpg, have_tga;
546         float can_dds;
547         have_dds = (fexists("dds/particles/particlefont.dds"));
548         have_jpg = (fexists("particles/particlefont.jpg"));
549         have_tga = (fexists("particles/particlefont.tga"));
550         can_dds = GL_Have_TextureCompression();
551         if(have_dds && (have_jpg || have_tga))
552         {
553                 // both? Let's only use good quality precompressed files
554                 // but ONLY if we actually support it!
555                 if(can_dds)
556                 {
557                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
558                         cvar_set("gl_texturecompression", "0");
559                         return 1;
560
561                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
562                         //return 2;
563                 }
564                 else
565                 {
566                         cvar_set("gl_texturecompression", "0");
567                         cvar_set("r_texture_dds_load", "0");
568                         return 0;
569                 }
570         }
571         else if(have_dds)
572         {
573                 // DDS only? We probably always want texture compression
574                 cvar_set("gl_texturecompression", "1");
575                 cvar_set("r_texture_dds_load", "1");
576                 if(!can_dds)
577                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
578                 return 0;
579         }
580         else
581         {
582                 // TGA only? Allow runtime compression
583                 if(can_dds)
584                 {
585                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
586                         return 2;
587                 }
588                 else
589                 {
590                         cvar_set("gl_texturecompression", "0");
591                         cvar_set("r_texture_dds_load", "0");
592                         return 0;
593                 }
594         }
595 }
596
597 // note: include only those that should be in the menu!
598 #define GAMETYPES \
599         GAMETYPE(MAPINFO_TYPE_ARENA) \
600         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
601         GAMETYPE(MAPINFO_TYPE_CTF) \
602         GAMETYPE(MAPINFO_TYPE_CA) \
603         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
604         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
605         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
606         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
607         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
608         GAMETYPE(MAPINFO_TYPE_LMS) \
609         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
610         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
611         GAMETYPE(MAPINFO_TYPE_RACE) \
612         GAMETYPE(MAPINFO_TYPE_CTS) \
613         GAMETYPE(MAPINFO_TYPE_RUNEMATCH) \
614         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
615         /* nothing */
616
617 float GameType_GetID(float cnt)
618 {
619         float i;
620         i = 0;
621         
622         #define GAMETYPE(id) if(i++ == cnt) return id;
623         GAMETYPES
624         #undef GAMETYPE
625         
626         return 0;
627 }
628
629 float GameType_GetCount()
630 {
631         float i;
632         i = 0;
633         
634         #define GAMETYPE(id) ++i;
635         GAMETYPES
636         #undef GAMETYPE
637         
638         return i;
639 }
640
641 string GameType_GetName(float cnt)
642 {
643         float i = GameType_GetID(cnt);
644         
645         if(i)
646                 return MapInfo_Type_ToText(i);
647         
648         return "";
649 }
650
651 string GameType_GetIcon(float cnt)
652 {
653         float i = GameType_GetID(cnt);
654         
655         if(i)
656                 return strcat("gametype_", MapInfo_Type_ToString(i));
657         
658         return "";
659 }
660
661 /*string GameType_GetTeams(float cnt) // poor implementation, later something else could be done that's better?
662 {
663         float i = GameType_GetID(cnt);
664         string s = _MapInfo_GetDefaultEx(i);
665         
666         if(i)
667         {
668                 if(strstrofs(s, "teams", 0) >= 0)
669                         return _("teamplay");
670                 else
671                         return _("free for all");
672         }
673         
674         return _("tuba for all");
675 }*/
676
677 void dialog_hudpanel_common_notoggle(entity me, string panelname)
678 {
679         float i;
680         entity e;
681
682         me.TR(me);
683                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
684                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
685                                 e.addValue(e, _("Default"), "");
686                                 e.addValue(e, _("Disable"), "0");
687                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
688                                 e.configureXonoticTextSliderValues(e);
689         me.TR(me);
690                 me.TDempty(me, 0.2);
691                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
692                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
693                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
694         me.TR(me);
695                 me.TDempty(me, 0.2);
696                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
697         me.TR(me);
698                 me.TDempty(me, 0.2);
699                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
700                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
701                                 e.addValue(e, _("Default"), "");
702                                 e.addValue(e, _("Disable"), "0");
703                                 for(i = 1; i <= 10; ++i)
704                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
705                                 e.configureXonoticTextSliderValues(e);
706         me.TR(me);
707                 me.TDempty(me, 0.2);
708                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
709                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
710                                 e.addValue(e, _("Default"), "");
711                                 for(i = 1; i <= 10; ++i)
712                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
713                                 e.configureXonoticTextSliderValues(e);
714         me.TR(me);
715                 me.TDempty(me, 0.2);
716                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
717                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
718                                 e.addValue(e, _("Default"), "");
719                                 e.addValue(e, _("Disable"), "0");
720                                 for(i = 1; i <= 10; ++i)
721                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
722                                 e.configureXonoticTextSliderValues(e);
723         me.TR(me);
724                 me.TDempty(me, 0.4);
725                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
726         me.TR(me);
727                 me.TDempty(me, 0.2);
728                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
729                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
730                                 e.addValue(e, _("Default"), "");
731                                 for(i = 0; i <= 10; ++i)
732                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
733                                 e.configureXonoticTextSliderValues(e);
734 }