qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "dialog.qh"
   3
   4 #include "../item.qh"
   5
   6 #include "../menu.qh"
   7 #include <common/campaign_common.qh>
   8 #include <common/constants.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/util.qh>
  11 #include <common/command/_mod.qh>
  12
  13 float GL_CheckExtension(string ext)
  14 {
  15         return strhasword(cvar_string("gl_info_extensions"), ext);
  16 }
  17
  18 float GL_Have_TextureCompression()
  19 {
  20         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  21 }
  22
  23 .entity parent, firstChild, nextSibling;
  24 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  25 {
  26         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  27 }
  28
  29 .string cvarName;
  30 void SUB_Null_ee(entity e1, entity e2)
  31 {
  32 }
  33
  34 .void(entity) saveCvars;
  35 void saveCvarsOf(entity ignore, entity e)
  36 {
  37         if(e.saveCvars)
  38                 e.saveCvars(e);
  39 }
  40
  41 .void(entity) loadCvars;
  42 void loadCvarsOf(entity ignore, entity e)
  43 {
  44         if(e.loadCvars)
  45                 e.loadCvars(e);
  46 }
  47 void saveAllCvars(entity root)
  48 {
  49         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  50 }
  51 void loadAllCvars(entity root)
  52 {
  53         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  54 }
  55
  56 .string cvarNames_Multi;
  57 .void(entity me) saveCvars_Multi;
  58 string getCvarsMulti(entity me)
  59 {
  60         if (me.cvarNames_Multi)
  61                 return me.cvarNames_Multi;
  62         return string_null;
  63 }
  64 void saveCvarsMulti(entity me)
  65 {
  66         float n, i;
  67         string s, cvarname;
  68
  69         me.saveCvars_Multi(me);
  70         s = cvar_string(me.cvarName);
  71
  72         n = tokenize_console(me.cvarNames_Multi);
  73         for(i = 0; i < n; ++i)
  74         {
  75                 // cvars prefixed with ! get saved with the inverted value
  76                 if(substring(argv(i), 0, 1) == "!")
  77                 {
  78                         cvarname = substring(argv(i), 1, strlen(argv(i)));
  79                         cvar_set(cvarname, ((s == "0") ? "1" : "0"));
  80                 }
  81                 else
  82                 {
  83                         cvarname = argv(i);
  84                         cvar_set(cvarname, s);
  85                 }
  86
  87                 CheckSendCvars(me, cvarname);
  88         }
  89 }
  90 void makeMulti(entity e, string otherCvars)
  91 {
  92         e.cvarNames_Multi = otherCvars;
  93         e.saveCvars_Multi = e.saveCvars;
  94         e.saveCvars = saveCvarsMulti;
  95 }
  96
  97 .void(entity me) saveCvars_Callback;
  98 .entity saveCvars_Callback_ent;
  99 .void(entity me, entity cb) saveCvars_Callback_func;
 100 void saveCvarsCallback(entity me)
 101 {
 102         me.saveCvars_Callback(me);
 103         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 104 }
 105 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 106 {
 107         e.saveCvars_Callback = e.saveCvars;
 108         e.saveCvars = saveCvarsCallback;
 109         e.saveCvars_Callback_ent = cbent;
 110         e.saveCvars_Callback_func = cbfunc;
 111 }
 112
 113 .void(entity) draw_setDependent;
 114 .string cvar_setDependent;
 115 .float cvarMin_setDependent;
 116 .float cvarMax_setDependent;
 117 .string cvar2_setDependent;
 118 .float cvar2Min_setDependent;
 119 .float cvar2Max_setDependent;
 120 .string cvar3_setDependent;
 121 .float cvar3Min_setDependent;
 122 .float cvar3Max_setDependent;
 123 .float op_setDependent;
 124 .string cvarString_setDependent;
 125 .string cvarValue_setDependent;
 126 .float(entity) func_setDependent;
 127 .bool disabled;
 128 void setDependent_Check(entity e)
 129 {
 130         float f;
 131         string s;
 132         if(e.func_setDependent)
 133         {
 134                 e.disabled = !(e.func_setDependent(e));
 135         }
 136         else if(e.cvarString_setDependent)
 137         {
 138                 s = cvar_string(e.cvarString_setDependent);
 139                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 140         }
 141         else
 142         {
 143                 if(e.cvar_setDependent)
 144                 {
 145                         f = cvar(e.cvar_setDependent);
 146                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 147                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 148                         else
 149                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 150                 }
 151                 if(e.cvar2_setDependent)
 152                 {
 153                         f = cvar(e.cvar2_setDependent);
 154                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 155                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 156                         else
 157                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 158                 }
 159                 if(e.cvar3_setDependent)
 160                 {
 161                         f = cvar(e.cvar3_setDependent);
 162                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 163                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 164                         else
 165                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 166                 }
 167         }
 168 }
 169 void setDependent_Draw(entity e)
 170 {
 171         setDependent_Check(e);
 172         e.draw_setDependent(e);
 173 }
 174 .void(entity) draw;
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 255 {
 256         if(theTooltip == "") // no tooltip, use cvar description then
 257         {
 258                 if(theCvar != "" && prvm_language == "en")
 259                 {
 260                         string t = cvar_description(theCvar);
 261                         if(t != "" && t != "custom cvar")
 262                                 theTooltip = t;
 263                 }
 264         }
 265         else if(theTooltip == "-") // no cvar description as tooltip
 266         {
 267                 theTooltip = string_null;
 268         }
 269
 270         strfree(e.tooltip);
 271         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 272 }
 273
 274 void clearTooltip(entity e)
 275 {
 276         setZonedTooltip(e, string_null, string_null);
 277 }
 278
 279 // URI SYSTEM ////////////////////////////////////////////////////////
 280
 281 float _Nex_ExtResponseSystem_Queried;
 282 string _Nex_ExtResponseSystem_UpdateTo;
 283 string _Nex_ExtResponseSystem_UpdateToURL;
 284 string _Nex_ExtResponseSystem_Packs;
 285 float _Nex_ExtResponseSystem_PacksStep;
 286
 287 /** engine callback */
 288 void URI_Get_Callback(float id, float status, string data)
 289 {
 290         if(url_URI_Get_Callback(id, status, data))
 291         {
 292                 // handled
 293         }
 294         else if (id == URI_GET_DISCARD)
 295         {
 296                 // discard
 297         }
 298         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 299         {
 300                 // sv_cmd curl
 301                 Curl_URI_Get_Callback(id, status, data);
 302         }
 303         else if (id == URI_GET_UPDATENOTIFICATION)
 304         {
 305                 UpdateNotification_URI_Get_Callback(id, status, data);
 306         }
 307         else
 308         {
 309                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
 310         }
 311 }
 312
 313 void DisableServerBackwardsCompatibility()
 314 {
 315         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 316 }
 317
 318 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 319 {
 320         float n;
 321
 322         if(_Nex_ExtResponseSystem_UpdateTo)
 323         {
 324                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before");
 325                 return;
 326         }
 327         if(status != 0)
 328         {
 329                 LOG_TRACEF("error receiving update notification: status is %d", status);
 330                 return;
 331         }
 332         if(substring(data, 0, 1) == "<")
 333         {
 334                 LOG_TRACE("error: received HTML instead of an update notification");
 335                 return;
 336         }
 337         if(strstrofs(data, "\r", 0) != -1)
 338         {
 339                 LOG_TRACE("error: received carriage returns from update notification server");
 340                 return;
 341         }
 342
 343         if(data == "")
 344                 n = 0;
 345         else
 346                 n = tokenizebyseparator(data, "\n");
 347
 348         float i;
 349         string s;
 350
 351         string un_version = "";
 352         string un_download = "";
 353         string un_url = "";
 354         string un_bannedservers = "";
 355         string un_emergency_pk3s = "";
 356         string un_promoted = "";
 357         string un_recommended = "";
 358         string un_compatexpire = "";
 359
 360         for(i = 0; i < n; ++i)
 361         {
 362                 s = substring(argv(i), 2, -1);
 363                 if(s == "") { continue; } // ignore empty lines
 364
 365                 switch(substring(argv(i), 0, 1))
 366                 {
 367                         case "V":
 368                         {
 369                                 un_version = s;
 370                                 break;
 371                         }
 372                         case "C":
 373                         {
 374                                 un_compatexpire = s;
 375                                 break;
 376                         }
 377                         case "D":
 378                         {
 379                                 un_download = s;
 380                                 break;
 381                         }
 382                         case "U":
 383                         {
 384                                 un_url = s;
 385                                 break;
 386                         }
 387                         case "B":
 388                         {
 389                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 390                                 break;
 391                         }
 392                         case "E":
 393                         {
 394                                 if(cvar("menu_updatecheck_getpacks"))
 395                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 396                                 break;
 397                         }
 398                         case "P":
 399                         {
 400                                 APPEND_TO_STRING(un_promoted, " ", s);
 401                                 break;
 402                         }
 403                         case "R":
 404                         {
 405                                 APPEND_TO_STRING(un_recommended, " ", s);
 406                                 break;
 407                         }
 408                 }
 409         }
 410
 411         if(un_version != "")
 412         {
 413                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 414                 {
 415                         // update needed
 416                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 417                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s"), un_download); }
 418                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 419                         DisableServerBackwardsCompatibility();
 420                 }
 421                 else if(cvar_string("g_xonoticversion") == un_version)
 422                 {
 423                         if(un_compatexpire != "")
 424                         {
 425                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 426                                 if (strcmp(curdate, un_compatexpire) >= 0)
 427                                         DisableServerBackwardsCompatibility();
 428                         }
 429                 }
 430         }
 431
 432         if(un_bannedservers != "")
 433         {
 434                 _Nex_ExtResponseSystem_BannedServers = strzone(un_bannedservers);
 435                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 436         }
 437
 438         if(un_emergency_pk3s != "")
 439         {
 440                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 441                 _Nex_ExtResponseSystem_PacksStep = 1;
 442         }
 443
 444         if(un_promoted != "")
 445         {
 446                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 447                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 448         }
 449
 450         if(un_recommended != "")
 451         {
 452                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 453                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 454         }
 455 }
 456
 457 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 458
 459 void updateCheck()
 460 {
 461         if(cvar("menu_updatecheck"))
 462         {
 463                 if(!_Nex_ExtResponseSystem_Queried)
 464                 {
 465                         _Nex_ExtResponseSystem_Queried = 1;
 466                         float startcnt;
 467                         string uri;
 468
 469                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 470
 471                         // for privacy, munge the start count a little
 472                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 473                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 474                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 475                 }
 476         }
 477
 478         if(_Nex_ExtResponseSystem_PacksStep > 0)
 479         {
 480                 float n, i;
 481                 float allgood;
 482                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 483                 allgood = true;
 484                 for(i = 0; i+1 < n; i += 2)
 485                 {
 486                         if(fexists(argv(i+1)))
 487                                 continue;
 488                         allgood = false;
 489                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 490                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 491                 }
 492                 if(allgood)
 493                 {
 494                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 495                         {
 496                                 if(!Menu_Active)
 497                                         cvar_set("_menu_initialized", "0");
 498                                         // HACK: cause m_hide call on next start
 499                                 localcmd("\nmenu_restart\n");
 500                         }
 501                         _Nex_ExtResponseSystem_PacksStep = 0;
 502                 }
 503                 else
 504                         _Nex_ExtResponseSystem_PacksStep = 2;
 505         }
 506
 507 }
 508
 509 bool show_propermenu = false;
 510
 511 float preMenuInit()
 512 {
 513         vector sz;
 514         vector boxA, boxB;
 515
 516         if(random() < 0.1)
 517                 show_propermenu = true;
 518
 519         updateCheck();
 520
 521         MapInfo_Cache_Create();
 522         MapInfo_Enumerate();
 523         if(!_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 524         {
 525                 draw_reset_cropped();
 526
 527                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 528                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 529
 530                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 531                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 532                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 533
 534                 boxA += sz * 0.1;
 535                 boxB -= sz * 0.1;
 536                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 537
 538                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 539                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 540
 541                 return false;
 542         }
 543         return true;
 544 }
 545
 546 string campaign_name_previous;
 547 float campaign_won_previous;
 548 #ifdef WATERMARK
 549 string autocvar_menu_watermark = WATERMARK;
 550 #else
 551 string autocvar_menu_watermark = "";
 552 #endif
 553 void postMenuDraw()
 554 {
 555         if(autocvar_menu_watermark != "")
 556         {
 557                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 558         }
 559 }
 560 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 561 .entity winnerDialog;
 562 void preMenuDraw()
 563 {
 564         vector fs, sz = '0 0 0', line, mid;
 565
 566         updateCheck();
 567
 568         if(_Nex_ExtResponseSystem_UpdateTo != "")
 569         {
 570                 // TODO rather turn this into a dialog
 571                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 572                 line = eY * fs.y;
 573                 string l1, l2;
 574                 if(show_propermenu)
 575                         l1 = sprintf("Jeff pay 4 new weapons for %s", _Nex_ExtResponseSystem_UpdateTo);
 576                 else
 577                         l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 578                 l2 = "http://www.xonotic.org/";
 579                 if(_Nex_ExtResponseSystem_UpdateToURL)
 580                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 581
 582                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 583                                 draw_TextWidth(l1, 0, fs),
 584                                 draw_TextWidth(l2, 0, fs)
 585                         );
 586                 sz_y = 3 * fs.y;
 587
 588                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 589                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 590                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 591
 592                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 593                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 594                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 595         }
 596         if (!campaign_name_previous)
 597                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 598         if(campaign_name == campaign_name_previous)
 599         {
 600                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 601                 {
 602                         if(!campaign_won_previous)
 603                         {
 604                                 m_display();
 605                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 606                         }
 607                         campaign_won_previous = 1;
 608                 }
 609                 else
 610                         campaign_won_previous = 0;
 611         }
 612         else
 613         {
 614                 strcpy(campaign_name_previous, campaign_name);
 615                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 616         }
 617 }
 618
 619 string resolvemod(string m)
 620 {
 621         if(m == "=")
 622                 return getcurrentmod();
 623         else
 624                 return m;
 625 }
 626
 627 float updateCompression()
 628 {
 629         float have_dds, have_jpg, have_tga;
 630         float can_dds;
 631         have_dds = (fexists("dds/particles/particlefont.dds"));
 632         have_jpg = (fexists("particles/particlefont.jpg"));
 633         have_tga = (fexists("particles/particlefont.tga"));
 634         can_dds = GL_Have_TextureCompression();
 635         if(have_dds && (have_jpg || have_tga))
 636         {
 637                 // both? Let's only use good quality precompressed files
 638                 // but ONLY if we actually support it!
 639                 if(can_dds)
 640                 {
 641                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 642                         cvar_set("gl_texturecompression", "0");
 643                         return 1;
 644
 645                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 646                         //return 2;
 647                 }
 648                 else
 649                 {
 650                         cvar_set("gl_texturecompression", "0");
 651                         cvar_set("r_texture_dds_load", "0");
 652                         return 0;
 653                 }
 654         }
 655         else if(have_dds)
 656         {
 657                 // DDS only? We probably always want texture compression
 658                 cvar_set("gl_texturecompression", "1");
 659                 cvar_set("r_texture_dds_load", "1");
 660                 if(!can_dds)
 661                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems."));
 662                 return 0;
 663         }
 664         else
 665         {
 666                 // TGA only? Allow runtime compression
 667                 if(can_dds)
 668                 {
 669                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 670                         return 2;
 671                 }
 672                 else
 673                 {
 674                         cvar_set("gl_texturecompression", "0");
 675                         cvar_set("r_texture_dds_load", "0");
 676                         return 0;
 677                 }
 678         }
 679 }
 680
 681 // note: include only those that should be in the menu!
 682 #define GAMETYPES \
 683         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 684         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 685         GAMETYPE(MAPINFO_TYPE_CTF) \
 686         GAMETYPE(MAPINFO_TYPE_CA) \
 687         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 688         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 689         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 690         GAMETYPE(MAPINFO_TYPE_LMS) \
 691         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 692         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 693         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 694         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 695         /* GAMETYPE(MAPINFO_TYPE_INVASION) */ \
 696         /**/
 697
 698 // hidden gametypes come last so indexing always works correctly
 699 #define HIDDEN_GAMETYPES \
 700         GAMETYPE(MAPINFO_TYPE_RACE) \
 701         GAMETYPE(MAPINFO_TYPE_CTS) \
 702         /**/
 703
 704 Gametype GameType_GetID(int cnt)
 705 {
 706         int i = 0;
 707         #define GAMETYPE(it) { if (i++ == cnt) return it; }
 708         GAMETYPES
 709         HIDDEN_GAMETYPES
 710         #undef GAMETYPE
 711         return NULL;
 712 }
 713
 714 int GameType_GetCount()
 715 {
 716         int i = 0;
 717         #define GAMETYPE(id) ++i;
 718         GAMETYPES
 719         #undef GAMETYPE
 720         #define GAMETYPE(it) if (cvar("developer")) ++i;
 721         HIDDEN_GAMETYPES
 722         #undef GAMETYPE
 723         return i;
 724 }
 725
 726 int GameType_GetTotalCount()
 727 {
 728         int i = 0;
 729         #define GAMETYPE(id) ++i;
 730         GAMETYPES
 731         HIDDEN_GAMETYPES
 732         #undef GAMETYPE
 733         return i;
 734 }
 735
 736 string GameType_GetName(int cnt)
 737 {
 738         Gametype i = GameType_GetID(cnt);
 739         return i ? MapInfo_Type_ToText(i) : "";
 740 }
 741
 742 string GameType_GetIcon(int cnt)
 743 {
 744         Gametype i = GameType_GetID(cnt);
 745         return i ? strcat("gametype_", MapInfo_Type_ToString(i)) : "";
 746 }
 747
 748 .void(entity) TR;
 749 .void(entity, float, float, entity) TD;
 750 .void(entity, float) TDempty;
 751 .void(entity, float, float) gotoRC;
 752 entity makeXonoticTextLabel(float theAlign, string theText);
 753 entity makeXonoticTextSlider(string);
 754 .void(entity, string, string) addValue;
 755 .void(entity) configureXonoticTextSliderValues;
 756 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 757 entity makeXonoticCheckBoxString(string, string, string, string);
 758 entity makeXonoticCheckBox(float, string, string);
 759 .bool sendCvars;
 760
 761 void dialog_hudpanel_main_checkbox(entity me, string panelname)
 762 {
 763         entity e;
 764
 765         me.TR(me);
 766                 me.TDempty(me, 1.5);
 767                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, strzone(strcat("hud_panel_", panelname)), _("Enable")));
 768 }
 769
 770 void dialog_hudpanel_main_settings(entity me, string panelname)
 771 {
 772         float i;
 773         entity e;
 774
 775         me.gotoRC(me, me.currentRow + 1.5, 0);
 776                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 777                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 778                                 e.addValue(e, _("Default"), "");
 779                                 e.addValue(e, _("Disable"), "0");
 780                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 781                                 e.configureXonoticTextSliderValues(e);
 782         me.TR(me);
 783                 me.TDempty(me, 0.2);
 784                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 785                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 786                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 787         me.TR(me);
 788                 me.TDempty(me, 0.2);
 789                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 790         me.TR(me);
 791                 me.TDempty(me, 0.2);
 792                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 793                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 794                                 e.addValue(e, _("Default"), "");
 795                                 e.addValue(e, _("Disable"), "0");
 796                                 for(i = 1; i <= 10; ++i)
 797                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 798                                 e.configureXonoticTextSliderValues(e);
 799         me.TR(me);
 800                 me.TDempty(me, 0.2);
 801                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 802                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 803                                 e.addValue(e, _("Default"), "");
 804                                 for(i = 1; i <= 10; ++i)
 805                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 806                                 e.configureXonoticTextSliderValues(e);
 807         me.TR(me);
 808                 me.TDempty(me, 0.2);
 809                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 810                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 811                                 e.addValue(e, _("Default"), "");
 812                                 e.addValue(e, _("Disable"), "0");
 813                                 for(i = 1; i <= 10; ++i)
 814                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 815                                 e.configureXonoticTextSliderValues(e);
 816         me.TR(me);
 817                 me.TDempty(me, 0.4);
 818                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 819         me.TR(me);
 820                 me.TDempty(me, 0.2);
 821                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 822                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 823                                 e.addValue(e, _("Default"), "");
 824                                 for(i = 0; i <= 10; ++i)
 825                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 826                                 e.configureXonoticTextSliderValues(e);
 827 }
 828
 829 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 830 {
 831         if(startAlpha < targetAlpha)
 832                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 833         else
 834                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 835         return currentAlpha;
 836 }
 837
 838 void CheckSendCvars(entity me, string cvarnamestring)
 839 {
 840         if(me.sendCvars)
 841         {
 842                 LOG_INFOF("Sending cvar: %s -> %s", cvarnamestring, cvar_string(cvarnamestring));
 843                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 844                 {
 845                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 846                 }
 847         }
 848 }