qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 void loadTooltips()
  12 {
  13         tooltipdb = db_load(language_filename("tooltips.db"));
  14 }
  15 void unloadTooltips()
  16 {
  17         if(tooltipdb >= 0)
  18                 db_close(tooltipdb);
  19         tooltipdb = -1;
  20 }
  21 string getZonedTooltipForIdentifier(string s)
  22 {
  23         string t;
  24         if(s == "")
  25                 return string_null;
  26         if(tooltipdb >= 0)
  27         {
  28                 t = db_get(tooltipdb, s);
  29                 if(t == "-")
  30                         return string_null;
  31                 if(t != "")
  32                         return strzone(t);
  33         }
  34         if(prvm_language == "en")
  35         {
  36                 t = cvar_description(s);
  37                 if(t != "" && t != "custom cvar")
  38                         return strzone(t);
  39         }
  40         dprint("WARNING: no tooltip set for ", s, "\n");
  41         return string_null;
  42 }
  43
  44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  45 {
  46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  47 }
  48
  49 .string cvarName;
  50 void SUB_Null_ee(entity e1, entity e2)
  51 {
  52 }
  53 void saveCvarsOf(entity ignore, entity e)
  54 {
  55         if(e.saveCvars)
  56                 e.saveCvars(e);
  57 }
  58 void loadCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.loadCvars)
  61                 e.loadCvars(e);
  62 }
  63 void saveAllCvars(entity root)
  64 {
  65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  66 }
  67 void loadAllCvars(entity root)
  68 {
  69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  70 }
  71
  72 .string cvarNames_Multi;
  73 .void(entity me) saveCvars_Multi;
  74 string getCvarsMulti(entity me)
  75 {
  76         if (me.cvarNames_Multi)
  77                 return me.cvarNames_Multi;
  78         return string_null;
  79 }
  80 void saveCvarsMulti(entity me)
  81 {
  82         float n, i;
  83         string s;
  84
  85         me.saveCvars_Multi(me);
  86         s = cvar_string(me.cvarName);
  87
  88         n = tokenize_console(me.cvarNames_Multi);
  89         for(i = 0; i < n; ++i)
  90         {
  91                 if(substring(argv(i), 0, 1) == "!")
  92                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
  93                 else
  94                         cvar_set(argv(i), s);
  95
  96                 CheckSendCvars(me, argv(i));
  97         }
  98 }
  99 void makeMulti(entity e, string otherCvars)
 100 {
 101         e.cvarNames_Multi = otherCvars;
 102         e.saveCvars_Multi = e.saveCvars;
 103         e.saveCvars = saveCvarsMulti;
 104 }
 105
 106 .void(entity me) saveCvars_Callback;
 107 .entity saveCvars_Callback_ent;
 108 .void(entity me, entity cb) saveCvars_Callback_func;
 109 void saveCvarsCallback(entity me)
 110 {
 111         me.saveCvars_Callback(me);
 112         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 113 }
 114 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 115 {
 116         e.saveCvars_Callback = e.saveCvars;
 117         e.saveCvars = saveCvarsCallback;
 118         e.saveCvars_Callback_ent = cbent;
 119         e.saveCvars_Callback_func = cbfunc;
 120 }
 121
 122 .void(entity) draw_setDependent;
 123 .string cvar_setDependent;
 124 .float cvarMin_setDependent;
 125 .float cvarMax_setDependent;
 126 .string cvar2_setDependent;
 127 .float cvar2Min_setDependent;
 128 .float cvar2Max_setDependent;
 129 .string cvar3_setDependent;
 130 .float cvar3Min_setDependent;
 131 .float cvar3Max_setDependent;
 132 .float op_setDependent;
 133 .string cvarString_setDependent;
 134 .string cvarValue_setDependent;
 135 .float(entity) func_setDependent;
 136 void setDependent_Check(entity e)
 137 {
 138         float f;
 139         string s;
 140         if(e.func_setDependent)
 141         {
 142                 e.disabled = !(e.func_setDependent(e));
 143         }
 144         else if(e.cvarString_setDependent)
 145         {
 146                 s = cvar_string(e.cvarString_setDependent);
 147                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 148         }
 149         else
 150         {
 151                 if(e.cvar_setDependent)
 152                 {
 153                         f = cvar(e.cvar_setDependent);
 154                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 155                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 156                         else
 157                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 158                 }
 159                 if(e.cvar2_setDependent)
 160                 {
 161                         f = cvar(e.cvar2_setDependent);
 162                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 163                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 164                         else
 165                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 166                 }
 167                 if(e.cvar3_setDependent)
 168                 {
 169                         f = cvar(e.cvar3_setDependent);
 170                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 171                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 172                         else
 173                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 174                 }
 175         }
 176 }
 177 void setDependent_Draw(entity e)
 178 {
 179         setDependent_Check(e);
 180         e.draw_setDependent(e);
 181 }
 182 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 183 {
 184         e.draw_setDependent = e.draw;
 185         e.cvar_setDependent = theCvarName;
 186         e.cvarMin_setDependent = theCvarMin;
 187         e.cvarMax_setDependent = theCvarMax;
 188         e.cvar2_setDependent = string_null;
 189         e.cvar3_setDependent = string_null;
 190         e.func_setDependent = func_null;
 191         e.draw = setDependent_Draw;
 192         setDependent_Check(e);
 193 }
 194 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 195 {
 196         e.draw_setDependent = e.draw;
 197         e.cvarString_setDependent = theCvarName;
 198         e.cvarValue_setDependent = theCvarValue;
 199         e.cvar_setDependent = string_null;
 200         e.cvar2_setDependent = string_null;
 201         e.cvar3_setDependent = string_null;
 202         e.func_setDependent = func_null;
 203         e.draw = setDependent_Draw;
 204         setDependent_Check(e);
 205 }
 206 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 207 {
 208         e.draw_setDependent = e.draw;
 209         e.cvar_setDependent = theCvarName;
 210         e.cvarMin_setDependent = theCvarMin;
 211         e.cvarMax_setDependent = theCvarMax;
 212         e.cvar2_setDependent = theCvar2Name;
 213         e.cvar2Min_setDependent = theCvar2Min;
 214         e.cvar2Max_setDependent = theCvar2Max;
 215         e.cvar3_setDependent = string_null;
 216         e.op_setDependent = 0;
 217         e.func_setDependent = func_null;
 218         e.draw = setDependent_Draw;
 219         setDependent_Check(e);
 220 }
 221 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 222 {
 223         e.draw_setDependent = e.draw;
 224         e.cvar_setDependent = theCvarName;
 225         e.cvarMin_setDependent = theCvarMin;
 226         e.cvarMax_setDependent = theCvarMax;
 227         e.cvar2_setDependent = theCvar2Name;
 228         e.cvar2Min_setDependent = theCvar2Min;
 229         e.cvar2Max_setDependent = theCvar2Max;
 230         e.cvar3_setDependent = string_null;
 231         e.op_setDependent = 1;
 232         e.func_setDependent = func_null;
 233         e.draw = setDependent_Draw;
 234         setDependent_Check(e);
 235 }
 236 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 237 {
 238         e.draw_setDependent = e.draw;
 239         e.cvar_setDependent = theCvarName;
 240         e.cvarMin_setDependent = theCvarMin;
 241         e.cvarMax_setDependent = theCvarMax;
 242         e.cvar2_setDependent = theCvar2Name;
 243         e.cvar2Min_setDependent = theCvar2Min;
 244         e.cvar2Max_setDependent = theCvar2Max;
 245         e.cvar3_setDependent = theCvar3Name;
 246         e.cvar3Min_setDependent = theCvar3Min;
 247         e.cvar3Max_setDependent = theCvar3Max;
 248         e.op_setDependent = 0;
 249         e.func_setDependent = func_null;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253 void setDependentWeird(entity e, float(entity) func)
 254 {
 255         e.draw_setDependent = e.draw;
 256         e.func_setDependent = func;
 257         e.draw = setDependent_Draw;
 258         setDependent_Check(e);
 259 }
 260
 261 // URI SYSTEM ////////////////////////////////////////////////////////
 262
 263 float _Nex_ExtResponseSystem_Queried;
 264 string _Nex_ExtResponseSystem_UpdateTo;
 265 string _Nex_ExtResponseSystem_UpdateToURL;
 266 string _Nex_ExtResponseSystem_Packs;
 267 float _Nex_ExtResponseSystem_PacksStep;
 268
 269 void URI_Get_Callback(float id, float status, string data)
 270 {
 271         if(url_URI_Get_Callback(id, status, data))
 272         {
 273                 // handled
 274         }
 275         else if (id == URI_GET_DISCARD)
 276         {
 277                 // discard
 278         }
 279         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 280         {
 281                 // sv_cmd curl
 282                 Curl_URI_Get_Callback(id, status, data);
 283         }
 284         else if (id == URI_GET_UPDATENOTIFICATION)
 285         {
 286                 UpdateNotification_URI_Get_Callback(id, status, data);
 287         }
 288         else
 289         {
 290                 printf("Received HTTP request data for an invalid id %d.\n", id);
 291         }
 292 }
 293
 294 void DisableServerBackwardsCompatibility()
 295 {
 296         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 297 }
 298
 299 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 300 {
 301         float n;
 302
 303         if(_Nex_ExtResponseSystem_UpdateTo)
 304         {
 305                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 306                 return;
 307         }
 308         if(status != 0)
 309         {
 310                 dprintf("error receiving update notification: status is %d\n", status);
 311                 return;
 312         }
 313         if(substring(data, 0, 1) == "<")
 314         {
 315                 dprint("error: received HTML instead of an update notification\n");
 316                 return;
 317         }
 318         if(strstrofs(data, "\r", 0) != -1)
 319         {
 320                 dprint("error: received carriage returns from update notification server\n");
 321                 return;
 322         }
 323
 324         if(data == "")
 325                 n = 0;
 326         else
 327                 n = tokenizebyseparator(data, "\n");
 328
 329         float i;
 330         string s;
 331
 332         string un_version = "";
 333         string un_download = "";
 334         string un_url = "";
 335         string un_bannedservers = "";
 336         string un_emergency_pk3s = "";
 337         string un_promoted = "";
 338         string un_recommended = "";
 339         string un_compatexpire = "";
 340
 341         for(i = 0; i < n; ++i)
 342         {
 343                 s = substring(argv(i), 2, -1);
 344                 if(s == "") { continue; } // ignore empty lines
 345
 346                 switch(substring(argv(i), 0, 1))
 347                 {
 348                         case "V":
 349                         {
 350                                 un_version = s;
 351                                 break;
 352                         }
 353                         case "C":
 354                         {
 355                                 un_compatexpire = s;
 356                                 break;
 357                         }
 358                         case "D":
 359                         {
 360                                 un_download = s;
 361                                 break;
 362                         }
 363                         case "U":
 364                         {
 365                                 un_url = s;
 366                                 break;
 367                         }
 368                         case "B":
 369                         {
 370                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 371                                 break;
 372                         }
 373                         case "E":
 374                         {
 375                                 if(cvar("menu_updatecheck_getpacks"))
 376                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 377                                 break;
 378                         }
 379                         case "P":
 380                         {
 381                                 APPEND_TO_STRING(un_promoted, " ", s);
 382                                 break;
 383                         }
 384                         case "R":
 385                         {
 386                                 APPEND_TO_STRING(un_recommended, " ", s);
 387                                 break;
 388                         }
 389                 }
 390         }
 391
 392         if(un_version != "")
 393         {
 394                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 395                 {
 396                         // update needed
 397                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 398                         if(un_download) { printf(_("Update can be downloaded at:\n%s\n"), un_download); }
 399                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 400                         DisableServerBackwardsCompatibility();
 401                 }
 402                 else if(cvar_string("g_xonoticversion") == un_version)
 403                 {
 404                         if(un_compatexpire != "")
 405                         {
 406                                 string curdate = strftime(FALSE, "%Y%m%d%H%M%S");
 407                                 if (strcmp(curdate, un_compatexpire) >= 0)
 408                                         DisableServerBackwardsCompatibility();
 409                         }
 410                 }
 411         }
 412
 413         if(un_emergency_pk3s != "")
 414         {
 415                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 416                 _Nex_ExtResponseSystem_PacksStep = 1;
 417         }
 418
 419         if(un_promoted != "")
 420         {
 421                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 422                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 423         }
 424
 425         if(un_recommended != "")
 426         {
 427                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 428                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 429         }
 430 }
 431
 432 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 433
 434 void updateCheck()
 435 {
 436         if(cvar("menu_updatecheck"))
 437         {
 438                 if(!_Nex_ExtResponseSystem_Queried)
 439                 {
 440                         _Nex_ExtResponseSystem_Queried = 1;
 441                         float startcnt;
 442                         string uri;
 443
 444                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 445
 446                         // for privacy, munge the start count a little
 447                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 448                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 449                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 450                 }
 451         }
 452
 453         if(_Nex_ExtResponseSystem_PacksStep > 0)
 454         {
 455                 float n, i;
 456                 float allgood;
 457                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 458                 allgood = TRUE;
 459                 for(i = 0; i+1 < n; i += 2)
 460                 {
 461                         if(fexists(argv(i+1)))
 462                                 continue;
 463                         allgood = FALSE;
 464                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 465                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 466                 }
 467                 if(allgood)
 468                 {
 469                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 470                         {
 471                                 if(!Menu_Active)
 472                                         cvar_set("_menu_initialized", "0");
 473                                         // HACK: cause m_hide call on next start
 474                                 localcmd("\nmenu_restart\n");
 475                         }
 476                         _Nex_ExtResponseSystem_PacksStep = 0;
 477                 }
 478                 else
 479                         _Nex_ExtResponseSystem_PacksStep = 2;
 480         }
 481
 482 }
 483
 484 float preMenuInit()
 485 {
 486         vector sz;
 487         vector boxA, boxB;
 488
 489         updateCheck();
 490
 491         MapInfo_Cache_Create();
 492         MapInfo_Enumerate();
 493         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 494         {
 495                 draw_reset_cropped();
 496
 497                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 498                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 499
 500                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 501                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 502                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 503
 504                 boxA += sz * 0.1;
 505                 boxB -= sz * 0.1;
 506                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 507
 508                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 509                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 510
 511                 return FALSE;
 512         }
 513         return TRUE;
 514 }
 515
 516 string campaign_name_previous;
 517 float campaign_won_previous;
 518 #ifdef WATERMARK
 519 var string autocvar_menu_watermark = WATERMARK;
 520 #else
 521 var string autocvar_menu_watermark = "";
 522 #endif
 523 void postMenuDraw()
 524 {
 525         if(autocvar_menu_watermark != "")
 526         {
 527                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 528         }
 529 }
 530 void preMenuDraw()
 531 {
 532         vector fs, sz = '0 0 0', line, mid;
 533
 534         updateCheck();
 535
 536         if(_Nex_ExtResponseSystem_UpdateTo != "")
 537         {
 538                 // TODO rather turn this into a dialog
 539                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 540                 line = eY * fs_y;
 541                 string l1, l2;
 542                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 543                 l2 = "http://www.xonotic.org/";
 544                 if(_Nex_ExtResponseSystem_UpdateToURL)
 545                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 546
 547                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 548                                 draw_TextWidth(l1, 0, fs),
 549                                 draw_TextWidth(l2, 0, fs)
 550                         );
 551                 sz_y = 3 * fs_y;
 552
 553                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 554                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 555                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 556
 557                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 558                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 559                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 560         }
 561         if (!campaign_name_previous)
 562                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 563         if(campaign_name == campaign_name_previous)
 564         {
 565                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 566                 {
 567                         if(!campaign_won_previous)
 568                         {
 569                                 m_display();
 570                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 571                         }
 572                         campaign_won_previous = 1;
 573                 }
 574                 else
 575                         campaign_won_previous = 0;
 576         }
 577         else
 578         {
 579                 strunzone(campaign_name_previous);
 580                 campaign_name_previous = strzone(campaign_name);
 581                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 582         }
 583 }
 584
 585 string resolvemod(string m)
 586 {
 587         if(m == "=")
 588                 return getcurrentmod();
 589         else
 590                 return m;
 591 }
 592
 593 float updateCompression()
 594 {
 595         float have_dds, have_jpg, have_tga;
 596         float can_dds;
 597         have_dds = (fexists("dds/particles/particlefont.dds"));
 598         have_jpg = (fexists("particles/particlefont.jpg"));
 599         have_tga = (fexists("particles/particlefont.tga"));
 600         can_dds = GL_Have_TextureCompression();
 601         if(have_dds && (have_jpg || have_tga))
 602         {
 603                 // both? Let's only use good quality precompressed files
 604                 // but ONLY if we actually support it!
 605                 if(can_dds)
 606                 {
 607                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 608                         cvar_set("gl_texturecompression", "0");
 609                         return 1;
 610
 611                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 612                         //return 2;
 613                 }
 614                 else
 615                 {
 616                         cvar_set("gl_texturecompression", "0");
 617                         cvar_set("r_texture_dds_load", "0");
 618                         return 0;
 619                 }
 620         }
 621         else if(have_dds)
 622         {
 623                 // DDS only? We probably always want texture compression
 624                 cvar_set("gl_texturecompression", "1");
 625                 cvar_set("r_texture_dds_load", "1");
 626                 if(!can_dds)
 627                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 628                 return 0;
 629         }
 630         else
 631         {
 632                 // TGA only? Allow runtime compression
 633                 if(can_dds)
 634                 {
 635                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 636                         return 2;
 637                 }
 638                 else
 639                 {
 640                         cvar_set("gl_texturecompression", "0");
 641                         cvar_set("r_texture_dds_load", "0");
 642                         return 0;
 643                 }
 644         }
 645 }
 646
 647 // note: include only those that should be in the menu!
 648 #define GAMETYPES \
 649         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 650         GAMETYPE(MAPINFO_TYPE_CTF) \
 651         GAMETYPE(MAPINFO_TYPE_CA) \
 652         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 653         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 654         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 655         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 656         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 657         GAMETYPE(MAPINFO_TYPE_LMS) \
 658         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 659         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 660         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 661         GAMETYPE(MAPINFO_TYPE_CTS) \
 662         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 663         //GAMETYPE(MAPINFO_TYPE_INVASION) \
 664         /* nothing */
 665
 666 float GameType_GetID(float cnt)
 667 {
 668         float i;
 669         i = 0;
 670
 671         #define GAMETYPE(id) { if(i++ == cnt) return id; }
 672         GAMETYPES
 673         #undef GAMETYPE
 674
 675         unused_float = i;
 676
 677         return 0;
 678 }
 679
 680 float GameType_GetCount()
 681 {
 682         float i;
 683         i = 0;
 684
 685         #define GAMETYPE(id) ++i;
 686         GAMETYPES
 687         #undef GAMETYPE
 688
 689         return i;
 690 }
 691
 692 string GameType_GetName(float cnt)
 693 {
 694         float i = GameType_GetID(cnt);
 695
 696         if(i)
 697                 return MapInfo_Type_ToText(i);
 698
 699         return "";
 700 }
 701
 702 string GameType_GetIcon(float cnt)
 703 {
 704         float i = GameType_GetID(cnt);
 705
 706         if(i)
 707                 return strcat("gametype_", MapInfo_Type_ToString(i));
 708
 709         return "";
 710 }
 711
 712 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 713 {
 714         float i;
 715         entity e;
 716
 717         me.TR(me);
 718                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 719                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 720                                 e.addValue(e, _("Default"), "");
 721                                 e.addValue(e, _("Disable"), "0");
 722                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 723                                 e.configureXonoticTextSliderValues(e);
 724         me.TR(me);
 725                 me.TDempty(me, 0.2);
 726                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 727                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 728                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 729         me.TR(me);
 730                 me.TDempty(me, 0.2);
 731                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 732         me.TR(me);
 733                 me.TDempty(me, 0.2);
 734                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 735                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 736                                 e.addValue(e, _("Default"), "");
 737                                 e.addValue(e, _("Disable"), "0");
 738                                 for(i = 1; i <= 10; ++i)
 739                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 740                                 e.configureXonoticTextSliderValues(e);
 741         me.TR(me);
 742                 me.TDempty(me, 0.2);
 743                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 744                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 745                                 e.addValue(e, _("Default"), "");
 746                                 for(i = 1; i <= 10; ++i)
 747                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 748                                 e.configureXonoticTextSliderValues(e);
 749         me.TR(me);
 750                 me.TDempty(me, 0.2);
 751                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 752                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 753                                 e.addValue(e, _("Default"), "");
 754                                 e.addValue(e, _("Disable"), "0");
 755                                 for(i = 1; i <= 10; ++i)
 756                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 757                                 e.configureXonoticTextSliderValues(e);
 758         me.TR(me);
 759                 me.TDempty(me, 0.4);
 760                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 761         me.TR(me);
 762                 me.TDempty(me, 0.2);
 763                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 764                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 765                                 e.addValue(e, _("Default"), "");
 766                                 for(i = 0; i <= 10; ++i)
 767                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 768                                 e.configureXonoticTextSliderValues(e);
 769 }
 770
 771 void CheckSendCvars(entity me, string cvarnamestring)
 772 {
 773         if(me.sendCvars)
 774         {
 775                 printf("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 776                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 777                 {
 778                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 779                 }
 780         }
 781 }