qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 void loadTooltips()
  12 {
  13         tooltipdb = db_load(language_filename("tooltips.db"));
  14 }
  15 void unloadTooltips()
  16 {
  17         if(tooltipdb >= 0)
  18                 db_close(tooltipdb);
  19         tooltipdb = -1;
  20 }
  21 string getZonedTooltipForIdentifier(string s)
  22 {
  23         string t;
  24         if(s == "")
  25                 return string_null;
  26         if(tooltipdb >= 0)
  27         {
  28                 t = db_get(tooltipdb, s);
  29                 if(t == "-")
  30                         return string_null;
  31                 if(t != "")
  32                         return strzone(t);
  33         }
  34         if(prvm_language == "en")
  35         {
  36                 t = cvar_description(s);
  37                 if(t != "" && t != "custom cvar")
  38                         return strzone(t);
  39         }
  40         dprint("WARNING: no tooltip set for ", s, "\n");
  41         return string_null;
  42 }
  43
  44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  45 {
  46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  47 }
  48
  49 .string cvarName;
  50 void SUB_Null_ee(entity e1, entity e2)
  51 {
  52 }
  53 void saveCvarsOf(entity ignore, entity e)
  54 {
  55         if(e.saveCvars)
  56                 e.saveCvars(e);
  57 }
  58 void loadCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.loadCvars)
  61                 e.loadCvars(e);
  62 }
  63 void saveAllCvars(entity root)
  64 {
  65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  66 }
  67 void loadAllCvars(entity root)
  68 {
  69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  70 }
  71
  72 .string cvarNames_Multi;
  73 .void(entity me) saveCvars_Multi;
  74 string getCvarsMulti(entity me)
  75 {
  76         if (me.cvarNames_Multi)
  77                 return me.cvarNames_Multi;
  78         return string_null;
  79 }
  80 void saveCvarsMulti(entity me)
  81 {
  82         float n, i;
  83         string s;
  84
  85         me.saveCvars_Multi(me);
  86         s = cvar_string(me.cvarName);
  87
  88         n = tokenize_console(me.cvarNames_Multi);
  89         for(i = 0; i < n; ++i)
  90                 cvar_set(argv(i), s);
  91 }
  92 void makeMulti(entity e, string otherCvars)
  93 {
  94         e.cvarNames_Multi = otherCvars;
  95         e.saveCvars_Multi = e.saveCvars;
  96         e.saveCvars = saveCvarsMulti;
  97 }
  98
  99 .void(entity me) saveCvars_Callback;
 100 .entity saveCvars_Callback_ent;
 101 .void(entity me, entity cb) saveCvars_Callback_func;
 102 void saveCvarsCallback(entity me)
 103 {
 104         me.saveCvars_Callback(me);
 105         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 106 }
 107 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 108 {
 109         e.saveCvars_Callback = e.saveCvars;
 110         e.saveCvars = saveCvarsCallback;
 111         e.saveCvars_Callback_ent = cbent;
 112         e.saveCvars_Callback_func = cbfunc;
 113 }
 114
 115 .void(entity) draw_setDependent;
 116 .string cvar_setDependent;
 117 .float cvarMin_setDependent;
 118 .float cvarMax_setDependent;
 119 .string cvar2_setDependent;
 120 .float cvar2Min_setDependent;
 121 .float cvar2Max_setDependent;
 122 .string cvar3_setDependent;
 123 .float cvar3Min_setDependent;
 124 .float cvar3Max_setDependent;
 125 .float op_setDependent;
 126 .string cvarString_setDependent;
 127 .string cvarValue_setDependent;
 128 .float(entity) func_setDependent;
 129 void setDependent_Check(entity e)
 130 {
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169 }
 170 void setDependent_Draw(entity e)
 171 {
 172         setDependent_Check(e);
 173         e.draw_setDependent(e);
 174 }
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 // URI SYSTEM ////////////////////////////////////////////////////////
 255
 256 float _Nex_ExtResponseSystem_Queried;
 257 string _Nex_ExtResponseSystem_UpdateTo;
 258 string _Nex_ExtResponseSystem_UpdateToURL;
 259
 260 void URI_Get_Callback(float id, float status, string data)
 261 {
 262         if(url_URI_Get_Callback(id, status, data))
 263         {
 264                 // handled
 265         }
 266         else if (id == URI_GET_DISCARD)
 267         {
 268                 // discard
 269         }
 270         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 271         {
 272                 // sv_cmd curl
 273                 Curl_URI_Get_Callback(id, status, data);
 274         }
 275         else if (id == URI_GET_UPDATENOTIFICATION)
 276         {
 277                 UpdateNotification_URI_Get_Callback(id, status, data);
 278         }
 279         else
 280         {
 281                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
 282         }
 283 }
 284
 285 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 286 {
 287         float n;
 288
 289         if(_Nex_ExtResponseSystem_UpdateTo)
 290         {
 291                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 292                 return;
 293         }
 294         if(status != 0)
 295         {
 296                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 297                 return;
 298         }
 299         if(substring(data, 0, 1) == "<")
 300         {
 301                 print(_("error: received HTML instead of an update notification\n"));
 302                 return;
 303         }
 304         if(strstrofs(data, "\r", 0) != -1)
 305         {
 306                 print(_("error: received carriage returns from update notification server\n"));
 307                 return;
 308         }
 309
 310         if(data == "")
 311                 n = 0;
 312         else
 313                 n = tokenizebyseparator(data, "\n");
 314
 315         if(n >= 1)
 316         {
 317                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 318
 319                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 320                 {
 321                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 322                 }
 323                 else
 324                 {
 325                         // update needed
 326                         if(n >= 2)
 327                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 328                         if(n >= 3)
 329                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
 330                 }
 331
 332                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 333
 334                 if(n >= 4)
 335                 {
 336                         _Nex_ExtResponseSystem_BannedServers = strzone(argv(3));
 337                         _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 338                 }
 339         }
 340 }
 341
 342 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 343
 344 float preMenuInit()
 345 {
 346         vector sz;
 347         vector boxA, boxB;
 348
 349         MapInfo_Cache_Create();
 350         MapInfo_Enumerate();
 351         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 352         {
 353                 draw_reset_cropped();
 354
 355                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 356                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 357
 358                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 359                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 360                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 361
 362                 boxA += sz * 0.1;
 363                 boxB -= sz * 0.1;
 364                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 365
 366                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 367                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 368
 369                 return FALSE;
 370         }
 371         return TRUE;
 372 }
 373
 374 string campaign_name_previous;
 375 float campaign_won_previous;
 376 #ifdef WATERMARK
 377 var string autocvar_menu_watermark = WATERMARK();
 378 #else
 379 var string autocvar_menu_watermark = "";
 380 #endif
 381 void postMenuDraw()
 382 {
 383         if(autocvar_menu_watermark != "")
 384         {
 385                 vector fs = '48 48 0';
 386                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 387         }
 388 }
 389 void preMenuDraw()
 390 {
 391         vector fs, sz, line, mid;
 392
 393         if(cvar("menu_updatecheck"))
 394         {
 395                 if(!_Nex_ExtResponseSystem_Queried)
 396                 {
 397                         _Nex_ExtResponseSystem_Queried = 1;
 398                         float startcnt;
 399                         string uri;
 400
 401                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 402
 403                         // for privacy, munge the start count a little
 404                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 405                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 406
 407 #ifdef CVAR_POPCON
 408                         float cvar_handle, popcon_handle;
 409                         float n, i, j;
 410                         string k, s;
 411                         cvar_handle = buf_create();
 412                         buf_cvarlist(cvar_handle, "", "");
 413                         n = buf_getsize(cvar_handle);
 414                         popcon_handle = buf_create();
 415                         for(i= 0, j = 0; i < n; ++i)
 416                         {
 417                                 k = bufstr_get(cvar_handle, i);
 418                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 419                                         continue;
 420                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 421                                 bufstr_set(popcon_handle, j, s);
 422                                 ++j;
 423                         }
 424                         buf_del(cvar_handle);
 425                         uri_postbuf(
 426                                 uri, URI_GET_UPDATENOTIFICATION,
 427                                 "application/x-www-form-urlencoded",
 428                                 "&",
 429                                 popcon_handle
 430                         );
 431                         buf_del(popcon_handle);
 432 #else
 433                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 434 #endif
 435                 }
 436         }
 437
 438         if(_Nex_ExtResponseSystem_UpdateTo != "")
 439         {
 440                 // TODO rather turn this into a dialog
 441                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 442                 line = eY * fs_y;
 443                 string l1, l2;
 444                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 445                 l2 = "http://www.xonotic.org/";
 446                 if(_Nex_ExtResponseSystem_UpdateToURL)
 447                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 448
 449                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 450                                 draw_TextWidth(l1, 0, fs),
 451                                 draw_TextWidth(l2, 0, fs)
 452                         );
 453                 sz_y = 3 * fs_y;
 454
 455                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 456                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 457                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 458
 459                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 460                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 461                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 462         }
 463         if not(campaign_name_previous)
 464                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 465         if(campaign_name == campaign_name_previous)
 466         {
 467                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 468                 {
 469                         if(!campaign_won_previous)
 470                         {
 471                                 m_display();
 472                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 473                         }
 474                         campaign_won_previous = 1;
 475                 }
 476                 else
 477                         campaign_won_previous = 0;
 478         }
 479         else
 480         {
 481                 strunzone(campaign_name_previous);
 482                 campaign_name_previous = strzone(campaign_name);
 483                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 484         }
 485 }
 486
 487 string resolvemod(string m)
 488 {
 489         if(m == "=")
 490                 return getcurrentmod();
 491         else
 492                 return m;
 493 }
 494
 495 float updateCompression()
 496 {
 497         float have_dds, have_jpg, have_tga;
 498         float can_dds;
 499         have_dds = (fexists("dds/particles/particlefont.dds"));
 500         have_jpg = (fexists("particles/particlefont.jpg"));
 501         have_tga = (fexists("particles/particlefont.tga"));
 502         can_dds = GL_Have_TextureCompression();
 503         if(have_dds && (have_jpg || have_tga))
 504         {
 505                 // both? Let's only use good quality precompressed files
 506                 // but ONLY if we actually support it!
 507                 if(can_dds)
 508                 {
 509                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 510                         cvar_set("gl_texturecompression", "0");
 511                         return 1;
 512
 513                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 514                         //return 2;
 515                 }
 516                 else
 517                 {
 518                         cvar_set("gl_texturecompression", "0");
 519                         cvar_set("r_texture_dds_load", "0");
 520                         return 0;
 521                 }
 522         }
 523         else if(have_dds)
 524         {
 525                 // DDS only? We probably always want texture compression
 526                 cvar_set("gl_texturecompression", "1");
 527                 cvar_set("r_texture_dds_load", "1");
 528                 if(!can_dds)
 529                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 530                 return 0;
 531         }
 532         else
 533         {
 534                 // TGA only? Allow runtime compression
 535                 if(can_dds)
 536                 {
 537                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 538                         return 2;
 539                 }
 540                 else
 541                 {
 542                         cvar_set("gl_texturecompression", "0");
 543                         cvar_set("r_texture_dds_load", "0");
 544                         return 0;
 545                 }
 546         }
 547 }
 548
 549 // note: include only those that should be in the menu!
 550 #define GAMETYPES \
 551         GAMETYPE(MAPINFO_TYPE_ARENA) \
 552         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 553         GAMETYPE(MAPINFO_TYPE_CTF) \
 554         GAMETYPE(MAPINFO_TYPE_CA) \
 555         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 556         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 557         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 558         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 559         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 560         GAMETYPE(MAPINFO_TYPE_LMS) \
 561         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 562         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 563         GAMETYPE(MAPINFO_TYPE_RACE) \
 564         GAMETYPE(MAPINFO_TYPE_CTS) \
 565         GAMETYPE(MAPINFO_TYPE_RUNEMATCH) \
 566         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 567         /* nothing */
 568
 569 float GameType_GetID(float cnt)
 570 {
 571         float i;
 572         i = 0;
 573
 574         #define GAMETYPE(id) if(i++ == cnt) return id;
 575         GAMETYPES
 576         #undef GAMETYPE
 577
 578         return 0;
 579 }
 580
 581 float GameType_GetCount()
 582 {
 583         float i;
 584         i = 0;
 585
 586         #define GAMETYPE(id) ++i;
 587         GAMETYPES
 588         #undef GAMETYPE
 589
 590         return i;
 591 }
 592
 593 string GameType_GetName(float cnt)
 594 {
 595         float i = GameType_GetID(cnt);
 596
 597         if(i)
 598                 return MapInfo_Type_ToText(i);
 599
 600         return "";
 601 }
 602
 603 string GameType_GetIcon(float cnt)
 604 {
 605         float i = GameType_GetID(cnt);
 606
 607         if(i)
 608                 return strcat("gametype_", MapInfo_Type_ToString(i));
 609
 610         return "";
 611 }
 612
 613 /*string GameType_GetTeams(float cnt) // poor implementation, later something else could be done that's better?
 614 {
 615         float i = GameType_GetID(cnt);
 616         string s = _MapInfo_GetDefaultEx(i);
 617
 618         if(i)
 619         {
 620                 if(strstrofs(s, "teams", 0) >= 0)
 621                         return _("teamplay");
 622                 else
 623                         return _("free for all");
 624         }
 625
 626         return _("tuba for all");
 627 }*/
 628
 629 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 630 {
 631         float i;
 632         entity e;
 633
 634         me.TR(me);
 635                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 636                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 637                                 e.addValue(e, _("Default"), "");
 638                                 e.addValue(e, _("Disable"), "0");
 639                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 640                                 e.configureXonoticTextSliderValues(e);
 641         me.TR(me);
 642                 me.TDempty(me, 0.2);
 643                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 644                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 645                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 646         me.TR(me);
 647                 me.TDempty(me, 0.2);
 648                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 649         me.TR(me);
 650                 me.TDempty(me, 0.2);
 651                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 652                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 653                                 e.addValue(e, _("Default"), "");
 654                                 e.addValue(e, _("Disable"), "0");
 655                                 for(i = 1; i <= 10; ++i)
 656                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 657                                 e.configureXonoticTextSliderValues(e);
 658         me.TR(me);
 659                 me.TDempty(me, 0.2);
 660                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 661                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 662                                 e.addValue(e, _("Default"), "");
 663                                 for(i = 1; i <= 10; ++i)
 664                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 665                                 e.configureXonoticTextSliderValues(e);
 666         me.TR(me);
 667                 me.TDempty(me, 0.2);
 668                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 669                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 670                                 e.addValue(e, _("Default"), "");
 671                                 e.addValue(e, _("Disable"), "0");
 672                                 for(i = 1; i <= 10; ++i)
 673                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 674                                 e.configureXonoticTextSliderValues(e);
 675         me.TR(me);
 676                 me.TDempty(me, 0.4);
 677                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 678         me.TR(me);
 679                 me.TDempty(me, 0.2);
 680                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 681                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 682                                 e.addValue(e, _("Default"), "");
 683                                 for(i = 0; i <= 10; ++i)
 684                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 685                                 e.configureXonoticTextSliderValues(e);
 686 }