qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "dialog.qh"
   3
   4 #include "../item.qh"
   5
   6 #include "../menu.qh"
   7 #include <common/campaign_common.qh>
   8 #include <common/constants.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/util.qh>
  11 #include <common/command/_mod.qh>
  12
  13 float GL_CheckExtension(string ext)
  14 {
  15         return strhasword(cvar_string("gl_info_extensions"), ext);
  16 }
  17
  18 float GL_Have_TextureCompression()
  19 {
  20         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  21 }
  22
  23 .entity parent, firstChild, nextSibling;
  24 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  25 {
  26         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  27 }
  28
  29 .string cvarName;
  30 void SUB_Null_ee(entity e1, entity e2)
  31 {
  32 }
  33
  34 .void(entity) saveCvars;
  35 void saveCvarsOf(entity ignore, entity e)
  36 {
  37         if(e.saveCvars)
  38                 e.saveCvars(e);
  39 }
  40
  41 .void(entity) loadCvars;
  42 void loadCvarsOf(entity ignore, entity e)
  43 {
  44         if(e.loadCvars)
  45                 e.loadCvars(e);
  46 }
  47 void saveAllCvars(entity root)
  48 {
  49         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  50 }
  51 void loadAllCvars(entity root)
  52 {
  53         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  54 }
  55
  56 .string cvarNames_Multi;
  57 .void(entity me) saveCvars_Multi;
  58 string getCvarsMulti(entity me)
  59 {
  60         if (me.cvarNames_Multi)
  61                 return me.cvarNames_Multi;
  62         return string_null;
  63 }
  64 void saveCvarsMulti(entity me)
  65 {
  66         float n, i;
  67         string s, cvarname;
  68
  69         me.saveCvars_Multi(me);
  70         s = cvar_string(me.cvarName);
  71
  72         n = tokenize_console(me.cvarNames_Multi);
  73         for(i = 0; i < n; ++i)
  74         {
  75                 // cvars prefixed with ! get saved with the inverted value
  76                 if(substring(argv(i), 0, 1) == "!")
  77                 {
  78                         cvarname = substring(argv(i), 1, strlen(argv(i)));
  79                         cvar_set(cvarname, ((s == "0") ? "1" : "0"));
  80                 }
  81                 else
  82                 {
  83                         cvarname = argv(i);
  84                         cvar_set(cvarname, s);
  85                 }
  86
  87                 CheckSendCvars(me, cvarname);
  88         }
  89 }
  90 void makeMulti(entity e, string otherCvars)
  91 {
  92         e.cvarNames_Multi = otherCvars;
  93         e.saveCvars_Multi = e.saveCvars;
  94         e.saveCvars = saveCvarsMulti;
  95 }
  96
  97 .void(entity me) saveCvars_Callback;
  98 .entity saveCvars_Callback_ent;
  99 .void(entity me, entity cb) saveCvars_Callback_func;
 100 void saveCvarsCallback(entity me)
 101 {
 102         me.saveCvars_Callback(me);
 103         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 104 }
 105 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 106 {
 107         e.saveCvars_Callback = e.saveCvars;
 108         e.saveCvars = saveCvarsCallback;
 109         e.saveCvars_Callback_ent = cbent;
 110         e.saveCvars_Callback_func = cbfunc;
 111 }
 112
 113 .void(entity) draw_setDependent;
 114 .string cvar_setDependent;
 115 .float cvarMin_setDependent;
 116 .float cvarMax_setDependent;
 117 .string cvar2_setDependent;
 118 .float cvar2Min_setDependent;
 119 .float cvar2Max_setDependent;
 120 .string cvar3_setDependent;
 121 .float cvar3Min_setDependent;
 122 .float cvar3Max_setDependent;
 123 .float op_setDependent;
 124 .string cvarString_setDependent;
 125 .string cvarValue_setDependent;
 126 .float(entity) func_setDependent;
 127 .bool disabled;
 128 void setDependent_Check(entity e)
 129 {
 130         float f;
 131         string s;
 132         if(e.func_setDependent)
 133         {
 134                 e.disabled = !(e.func_setDependent(e));
 135         }
 136         else if(e.cvarString_setDependent)
 137         {
 138                 s = cvar_string(e.cvarString_setDependent);
 139                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 140         }
 141         else
 142         {
 143                 if(e.cvar_setDependent)
 144                 {
 145                         f = cvar(e.cvar_setDependent);
 146                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 147                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 148                         else
 149                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 150                 }
 151                 if(e.cvar2_setDependent)
 152                 {
 153                         f = cvar(e.cvar2_setDependent);
 154                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 155                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 156                         else
 157                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 158                 }
 159                 if(e.cvar3_setDependent)
 160                 {
 161                         f = cvar(e.cvar3_setDependent);
 162                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 163                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 164                         else
 165                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 166                 }
 167         }
 168 }
 169 void setDependent_Draw(entity e)
 170 {
 171         setDependent_Check(e);
 172         e.draw_setDependent(e);
 173 }
 174 .void(entity) draw;
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 255 {
 256         if(theTooltip == "") // no tooltip, use cvar description then
 257         {
 258                 if(theCvar != "" && prvm_language == "en")
 259                 {
 260                         string t = cvar_description(theCvar);
 261                         if(t != "" && t != "custom cvar")
 262                                 theTooltip = t;
 263                 }
 264         }
 265         else if(theTooltip == "-") // no cvar description as tooltip
 266         {
 267                 theTooltip = string_null;
 268         }
 269
 270         strfree(e.tooltip);
 271         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 272 }
 273
 274 void clearTooltip(entity e)
 275 {
 276         setZonedTooltip(e, string_null, string_null);
 277 }
 278
 279 // URI SYSTEM ////////////////////////////////////////////////////////
 280
 281 float _Nex_ExtResponseSystem_Queried;
 282 string _Nex_ExtResponseSystem_UpdateTo;
 283 string _Nex_ExtResponseSystem_UpdateToURL;
 284 string _Nex_ExtResponseSystem_Packs;
 285 float _Nex_ExtResponseSystem_PacksStep;
 286
 287 /** engine callback */
 288 void URI_Get_Callback(float id, float status, string data)
 289 {
 290         if(url_URI_Get_Callback(id, status, data))
 291         {
 292                 // handled
 293         }
 294         else if (id == URI_GET_DISCARD)
 295         {
 296                 // discard
 297         }
 298         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 299         {
 300                 // sv_cmd curl
 301                 Curl_URI_Get_Callback(id, status, data);
 302         }
 303         else if (id == URI_GET_UPDATENOTIFICATION)
 304         {
 305                 UpdateNotification_URI_Get_Callback(id, status, data);
 306         }
 307         else
 308         {
 309                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
 310         }
 311 }
 312
 313 void DisableServerBackwardsCompatibility()
 314 {
 315         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 316 }
 317
 318 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 319 {
 320         float n;
 321
 322         if(_Nex_ExtResponseSystem_UpdateTo)
 323         {
 324                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before");
 325                 return;
 326         }
 327         if(status != 0)
 328         {
 329                 LOG_TRACEF("error receiving update notification: status is %d", status);
 330                 return;
 331         }
 332         if(substring(data, 0, 1) == "<")
 333         {
 334                 LOG_TRACE("error: received HTML instead of an update notification");
 335                 return;
 336         }
 337         if(strstrofs(data, "\r", 0) != -1)
 338         {
 339                 LOG_TRACE("error: received carriage returns from update notification server");
 340                 return;
 341         }
 342
 343         if(data == "")
 344                 n = 0;
 345         else
 346                 n = tokenizebyseparator(data, "\n");
 347
 348         float i;
 349         string s;
 350
 351         string un_version = "";
 352         string un_download = "";
 353         string un_url = "";
 354         string un_bannedservers = "";
 355         string un_emergency_pk3s = "";
 356         string un_promoted = "";
 357         string un_recommended = "";
 358         string un_compatexpire = "";
 359
 360         for(i = 0; i < n; ++i)
 361         {
 362                 s = substring(argv(i), 2, -1);
 363                 if(s == "") { continue; } // ignore empty lines
 364
 365                 switch(substring(argv(i), 0, 1))
 366                 {
 367                         case "V":
 368                         {
 369                                 un_version = s;
 370                                 break;
 371                         }
 372                         case "C":
 373                         {
 374                                 un_compatexpire = s;
 375                                 break;
 376                         }
 377                         case "D":
 378                         {
 379                                 un_download = s;
 380                                 break;
 381                         }
 382                         case "U":
 383                         {
 384                                 un_url = s;
 385                                 break;
 386                         }
 387                         case "B":
 388                         {
 389                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 390                                 break;
 391                         }
 392                         case "E":
 393                         {
 394                                 if(cvar("menu_updatecheck_getpacks"))
 395                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 396                                 break;
 397                         }
 398                         case "P":
 399                         {
 400                                 APPEND_TO_STRING(un_promoted, " ", s);
 401                                 break;
 402                         }
 403                         case "R":
 404                         {
 405                                 APPEND_TO_STRING(un_recommended, " ", s);
 406                                 break;
 407                         }
 408                 }
 409         }
 410
 411         if(un_version != "")
 412         {
 413                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 414                 {
 415                         // update needed
 416                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 417                         if(un_download) { LOG_INFOF(_("Update can be downloaded at:\n%s"), un_download); }
 418                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 419                         DisableServerBackwardsCompatibility();
 420                 }
 421                 else if(cvar_string("g_xonoticversion") == un_version)
 422                 {
 423                         if(un_compatexpire != "")
 424                         {
 425                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 426                                 if (strcmp(curdate, un_compatexpire) >= 0)
 427                                         DisableServerBackwardsCompatibility();
 428                         }
 429                 }
 430         }
 431
 432         if(un_bannedservers != "")
 433         {
 434                 _Nex_ExtResponseSystem_BannedServers = strzone(un_bannedservers);
 435                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 436         }
 437
 438         if(un_emergency_pk3s != "")
 439         {
 440                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 441                 _Nex_ExtResponseSystem_PacksStep = 1;
 442         }
 443
 444         if(un_promoted != "")
 445         {
 446                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 447                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 448         }
 449
 450         if(un_recommended != "")
 451         {
 452                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 453                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 454         }
 455 }
 456
 457 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 458
 459 void updateCheck()
 460 {
 461         if(!_Nex_ExtResponseSystem_Queried)
 462         {
 463                 _Nex_ExtResponseSystem_Queried = 1;
 464                 float startcnt;
 465                 string uri;
 466
 467                 cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 468
 469                 // for privacy, munge the start count a little
 470                 startcnt = floor((floor(startcnt / 10) + random()) * 10);
 471                 uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 472                 uri_get(uri, URI_GET_UPDATENOTIFICATION);
 473         }
 474
 475         if(_Nex_ExtResponseSystem_PacksStep > 0)
 476         {
 477                 float n, i;
 478                 float allgood;
 479                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 480                 allgood = true;
 481                 for(i = 0; i+1 < n; i += 2)
 482                 {
 483                         if(fexists(argv(i+1)))
 484                                 continue;
 485                         allgood = false;
 486                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 487                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 488                 }
 489                 if(allgood)
 490                 {
 491                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 492                         {
 493                                 if(!Menu_Active)
 494                                         cvar_set("_menu_initialized", "0");
 495                                         // HACK: cause m_hide call on next start
 496                                 localcmd("\nmenu_restart\n");
 497                         }
 498                         _Nex_ExtResponseSystem_PacksStep = 0;
 499                 }
 500                 else
 501                         _Nex_ExtResponseSystem_PacksStep = 2;
 502         }
 503
 504 }
 505
 506 bool show_propermenu = false;
 507
 508 float preMenuInit()
 509 {
 510         vector sz;
 511         vector boxA, boxB;
 512
 513         if(random() < 0.1)
 514                 show_propermenu = true;
 515
 516         updateCheck();
 517
 518         MapInfo_Cache_Create();
 519         MapInfo_Enumerate();
 520         if(!_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 521         {
 522                 draw_reset_cropped();
 523
 524                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 525                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 526
 527                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 528                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 529                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 530
 531                 boxA += sz * 0.1;
 532                 boxB -= sz * 0.1;
 533                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 534
 535                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 536                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 537
 538                 return false;
 539         }
 540         return true;
 541 }
 542
 543 string campaign_name_previous;
 544 float campaign_won_previous;
 545 #ifdef WATERMARK
 546 string autocvar_menu_watermark = WATERMARK;
 547 #else
 548 string autocvar_menu_watermark = "";
 549 #endif
 550 void postMenuDraw()
 551 {
 552         if(autocvar_menu_watermark != "")
 553         {
 554                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 555         }
 556 }
 557 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 558 .entity winnerDialog;
 559 void preMenuDraw()
 560 {
 561         vector fs, sz = '0 0 0', line, mid;
 562
 563         updateCheck();
 564
 565         if(_Nex_ExtResponseSystem_UpdateTo != "" && !(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 566         {
 567                 // TODO rather turn this into a dialog
 568                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 569                 line = eY * fs.y;
 570                 string l1, l2;
 571                 if(show_propermenu)
 572                         l1 = sprintf("Jeff pay 4 new weapons for %s", _Nex_ExtResponseSystem_UpdateTo);
 573                 else
 574                         l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 575                 l2 = "http://www.xonotic.org/";
 576                 if(_Nex_ExtResponseSystem_UpdateToURL)
 577                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 578
 579                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 580                                 draw_TextWidth(l1, 0, fs),
 581                                 draw_TextWidth(l2, 0, fs)
 582                         );
 583                 sz_y = 3 * fs.y;
 584
 585                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 586                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 587                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 588
 589                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 590                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 591                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 592         }
 593         if (!campaign_name_previous)
 594                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 595         if(campaign_name == campaign_name_previous)
 596         {
 597                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 598                 {
 599                         if(!campaign_won_previous)
 600                         {
 601                                 m_display();
 602                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 603                         }
 604                         campaign_won_previous = 1;
 605                 }
 606                 else
 607                         campaign_won_previous = 0;
 608         }
 609         else
 610         {
 611                 strcpy(campaign_name_previous, campaign_name);
 612                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 613         }
 614 }
 615
 616 string resolvemod(string m)
 617 {
 618         if(m == "=")
 619                 return getcurrentmod();
 620         else
 621                 return m;
 622 }
 623
 624 float updateCompression()
 625 {
 626         float have_dds, have_jpg, have_tga;
 627         float can_dds;
 628         have_dds = (fexists("dds/particles/particlefont.dds"));
 629         have_jpg = (fexists("particles/particlefont.jpg"));
 630         have_tga = (fexists("particles/particlefont.tga"));
 631         can_dds = GL_Have_TextureCompression();
 632         if(have_dds && (have_jpg || have_tga))
 633         {
 634                 // both? Let's only use good quality precompressed files
 635                 // but ONLY if we actually support it!
 636                 if(can_dds)
 637                 {
 638                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 639                         cvar_set("gl_texturecompression", "0");
 640                         return 1;
 641
 642                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 643                         //return 2;
 644                 }
 645                 else
 646                 {
 647                         cvar_set("gl_texturecompression", "0");
 648                         cvar_set("r_texture_dds_load", "0");
 649                         return 0;
 650                 }
 651         }
 652         else if(have_dds)
 653         {
 654                 // DDS only? We probably always want texture compression
 655                 cvar_set("gl_texturecompression", "1");
 656                 cvar_set("r_texture_dds_load", "1");
 657                 if(!can_dds)
 658                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems."));
 659                 return 0;
 660         }
 661         else
 662         {
 663                 // TGA only? Allow runtime compression
 664                 if(can_dds)
 665                 {
 666                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 667                         return 2;
 668                 }
 669                 else
 670                 {
 671                         cvar_set("gl_texturecompression", "0");
 672                         cvar_set("r_texture_dds_load", "0");
 673                         return 0;
 674                 }
 675         }
 676 }
 677
 678 // note: include only those that should be in the menu!
 679 #define GAMETYPES \
 680         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 681         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 682         GAMETYPE(MAPINFO_TYPE_CTF) \
 683         GAMETYPE(MAPINFO_TYPE_CA) \
 684         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 685         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 686         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 687         GAMETYPE(MAPINFO_TYPE_LMS) \
 688         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 689         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 690         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 691         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 692         /* GAMETYPE(MAPINFO_TYPE_INVASION) */ \
 693         /**/
 694
 695 // hidden gametypes come last so indexing always works correctly
 696 #define HIDDEN_GAMETYPES \
 697         GAMETYPE(MAPINFO_TYPE_RACE) \
 698         GAMETYPE(MAPINFO_TYPE_CTS) \
 699         /**/
 700
 701 Gametype GameType_GetID(int cnt)
 702 {
 703         int i = 0;
 704         #define GAMETYPE(it) { if (i++ == cnt) return it; }
 705         GAMETYPES
 706         HIDDEN_GAMETYPES
 707         #undef GAMETYPE
 708         return NULL;
 709 }
 710
 711 int GameType_GetCount()
 712 {
 713         int i = 0;
 714         #define GAMETYPE(id) ++i;
 715         GAMETYPES
 716         #undef GAMETYPE
 717         #define GAMETYPE(it) if (cvar("developer")) ++i;
 718         HIDDEN_GAMETYPES
 719         #undef GAMETYPE
 720         return i;
 721 }
 722
 723 int GameType_GetTotalCount()
 724 {
 725         int i = 0;
 726         #define GAMETYPE(id) ++i;
 727         GAMETYPES
 728         HIDDEN_GAMETYPES
 729         #undef GAMETYPE
 730         return i;
 731 }
 732
 733 string GameType_GetName(int cnt)
 734 {
 735         Gametype i = GameType_GetID(cnt);
 736         return i ? MapInfo_Type_ToText(i) : "";
 737 }
 738
 739 string GameType_GetIcon(int cnt)
 740 {
 741         Gametype i = GameType_GetID(cnt);
 742         return i ? strcat("gametype_", MapInfo_Type_ToString(i)) : "";
 743 }
 744
 745 .void(entity) TR;
 746 .void(entity, float, float, entity) TD;
 747 .void(entity, float) TDempty;
 748 .void(entity, float, float) gotoRC;
 749 entity makeXonoticTextLabel(float theAlign, string theText);
 750 entity makeXonoticTextSlider(string);
 751 .void(entity, string, string) addValue;
 752 .void(entity) configureXonoticTextSliderValues;
 753 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 754 entity makeXonoticCheckBoxString(string, string, string, string);
 755 entity makeXonoticCheckBox(float, string, string);
 756 .bool sendCvars;
 757
 758 void dialog_hudpanel_main_checkbox(entity me, string panelname)
 759 {
 760         entity e;
 761
 762         me.TR(me);
 763                 me.TDempty(me, 1.5);
 764                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, strzone(strcat("hud_panel_", panelname)), _("Enable")));
 765 }
 766
 767 void dialog_hudpanel_main_settings(entity me, string panelname)
 768 {
 769         float i;
 770         entity e;
 771
 772         me.gotoRC(me, me.currentRow + 1.5, 0);
 773                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 774                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 775                                 e.addValue(e, _("Default"), "");
 776                                 e.addValue(e, _("Disable"), "0");
 777                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 778                                 e.configureXonoticTextSliderValues(e);
 779         me.TR(me);
 780                 me.TDempty(me, 0.2);
 781                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 782                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 783                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 784         me.TR(me);
 785                 me.TDempty(me, 0.2);
 786                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 787         me.TR(me);
 788                 me.TDempty(me, 0.2);
 789                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 790                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 791                                 e.addValue(e, _("Default"), "");
 792                                 e.addValue(e, _("Disable"), "0");
 793                                 for(i = 1; i <= 10; ++i)
 794                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 795                                 e.configureXonoticTextSliderValues(e);
 796         me.TR(me);
 797                 me.TDempty(me, 0.2);
 798                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 799                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 800                                 e.addValue(e, _("Default"), "");
 801                                 for(i = 1; i <= 10; ++i)
 802                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 803                                 e.configureXonoticTextSliderValues(e);
 804         me.TR(me);
 805                 me.TDempty(me, 0.2);
 806                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 807                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 808                                 e.addValue(e, _("Default"), "");
 809                                 e.addValue(e, _("Disable"), "0");
 810                                 for(i = 1; i <= 10; ++i)
 811                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 812                                 e.configureXonoticTextSliderValues(e);
 813         me.TR(me);
 814                 me.TDempty(me, 0.4);
 815                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 816         me.TR(me);
 817                 me.TDempty(me, 0.2);
 818                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 819                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 820                                 e.addValue(e, _("Default"), "");
 821                                 for(i = 0; i <= 10; ++i)
 822                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 823                                 e.configureXonoticTextSliderValues(e);
 824 }
 825
 826 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 827 {
 828         if(startAlpha < targetAlpha)
 829                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 830         else
 831                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 832         return currentAlpha;
 833 }
 834
 835 void CheckSendCvars(entity me, string cvarnamestring)
 836 {
 837         if(me.sendCvars)
 838         {
 839                 LOG_INFOF("Sending cvar: %s -> %s", cvarnamestring, cvar_string(cvarnamestring));
 840                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 841                 {
 842                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 843                 }
 844         }
 845 }